вы делали примерно вот так:

Код:
TR_Load         ld   c,5
                ld   de,(#5CF4)
 	        im 1
                di
                ld   (Trdos_HL+1),hl
                ld   (Trdos_DE+1),de
                ld   (Trdos_BC+1),bc
                ld   (Trdos_A+1),a
                im   1
                ld   a,#3F
                ld   i,a
                ld   (Trdos_Ret+1),sp

TR_L1           ld   hl,Trdos_Ret
                push hl
                ld   (#5C3D),sp
                ld   a,#C3
                ld   hl,Trdos_INT
                ld   (#5CC2),a
                ld   (#5CC3),hl
                ld   hl,0
                ld   (#5D0F),hl
                ld   iy,#5C3A
                ld   (iy),#FF
Trdos_HL	ld   hl,0
Trdos_DE        ld   de,0
Trdos_BC        ld   bc,0
Trdos_A         ld   a,0
                call #3D13
                xor  a

Trdos_R1        di
                ld   sp,(Trdos_Ret+1)
                ei
                ret

Trdos_Ret       ld   sp,0
                jr   TR_L1

Trdos_INT       ex   (sp),hl
                push hl
                push de
                push af
                ex   de,hl
                or   a
                ld   hl,#0D6B
                sbc  hl,de
                jr   z,Trdos_B1
                or   a
                ld   hl,#1F54
                sbc  hl,de
                jr   z,Trdos_B2
                pop  af
                pop  de
                pop  hl
                ex   (sp),hl
                ret

Trdos_B1        ld   a,01
                jr   Trdos_R1

Trdos_B2        pop  af
                pop  de
                pop  hl
                ex   (sp),hl
                inc  sp
                inc  sp
                scf
                ret
А то думаю кому-нибудь точно понадобится.