rr=Array[offset]

[NovaStorm]

Как выгоднее всего получать в 8-ми и 16-ти битных регистрах значения массива(смещение 8 бит)?

[Advertiser]

[goblinish]

Как выгоднее всего получать в 8-ми и 16-ти битных регистрах значения массива(смещение 8 бит)?

зависит от цели.
можешь по 8-битному регистру брать по табличному принципу. например:
array=#6000

ld h,#60
ld l,a;a=индекс
ld a,(hl); тут и значение.

ну и 16-битное аналогично по #61,#60

другие подскажут..

[SAM style]

разместить массив по адресу #xx00
для 8-битных данных:

LD H,xx
LD L,index
LD A,(HL)

Для 16-битных будет 2 таких массива один за другим, в одном - младший байт, в другом - старший

LD H,xx
LD L,index
LD E,(HL)
INC H
LD D,(HL)

---------- Post added at 21:51 ---------- Previous post was at 21:50 ----------

Опередил...

[NovaStorm]

А ежели массивов много, но по несколько элементов, и памяти на кратное 256 расположение не напасёшься?
Я сейчас делаю так(для 16-бит - inc ix или +1 для второй половинки регистра назначения):

    macro ld_ixa_r label,r
        ld ixh,label/256+1*((label%256)/128)
        ld ixl,a
        ld r,(ix+label%256-256*((label%256)/128))
    endm

Можно ли как-то ещё более удобно?

[goblinish]

Можно ли как-то ещё более удобно?

ld l,index
ld h,0
ld de,array
;теперь двухбитное
add hl,hl
add hl,de
ld r1,(hl)
inc hl;inc l
ld r2,(hl)

не помогает?
IX просто, конечно, но прожорлив в памяти, да и с тактами, наверное.

[NovaStorm]

В твоём варианте 63, в моём для 16-бит - 57 тактов =)
И 12 против 11 байт соответственно.
Ладно, спасибо, видать мой вариант не самый плохой, да и одним регистром меньше задействуется.

[goblinish]

NovaStorm, а со стэком не пробовал? популярный EI вариант.

[NovaStorm]

Не пробовал, но так ли сильно он будет отличаться от этих? Да и загружать/восстанавливать SP тоже придётся.

[goblinish]

Не пробовал, но так ли сильно он будет отличаться от этих? Да и загружать/восстанавливать SP тоже придётся.

смотря то, что ты мучаешь.

[Vitamin]

ld a,high addr
adc 0
ld h,a

Обычно меняется на

adc a,high addr
sub l
ld h,a

-1 байт, -3 такта.