Использование стека и прерывания

[drbars]

Почитав замечательную статью в журнале DeJa Vu #0A "Программирование - быстрая процедура печати спрайтов через стек от WoodlandStudio." - решил попробовать реализовать. В итоге получаю видеоэффекты и зависание после секунд работы.

Суть моей задачи такова. Для примера на прерываниях висит музыка и кое какой вывод графики стеком. Всё работает.

Eсть необходимость "читать" через стек данные из памяти в регистр DE во время прерывания... И тут наступают грабли.

Для примера соорудил код:

INT_VECTOR=#BE00
INT_HANDLER=#BFBF
STACK_MAIN=#7FFF
STACK_IM2=INT_HANDLER-1

	ORG 	#8000
START:
	DI
	LD SP,STACK_MAIN

           LD HL,INT_VECTOR
           LD BC,#00BF
           LD (HL),C
           INC HL
           DJNZ $-2
           LD (HL),C

	LD A,INT_VECTOR/256
	LD I,A
	IM 2
	EI

MAIN_LOOP:
; тут читаем стеком данные из памяти и кидаем на экран для примера
; EI:HALT тут нет, т.к прерывание должно приходить во время работы чтения стеком.
;Если LD SP,SPR1 закоментить зависать перестает, но ясно что выводит мусор :)

	LD (STK1+1),SP
	LD SP,SPR1
	LD HL,#4000
	DUP 16
	POP DE
	LD (HL),E
	INC HL
	LD (HL),D
	INC HL
	EDUP
STK1	LD SP,#0000
	JP MAIN_LOOP

SPR1	DS #20,#FF

MAIN_ISR:
	PUSH IX
	PUSH HL
	PUSH DE
	PUSH BC
	PUSH AF
	EXX
	EX AF,AF'
	PUSH IY
	PUSH HL
	PUSH DE
	PUSH BC
	PUSH AF
; тут музыка и графика стеком выводится

	POP AF
	POP BC
	POP DE
	POP HL
	POP IY
	EX AF,AF'
	EXX
	POP AF
	POP BC
	POP DE
	POP HL
	POP IX
	RET

; Обработчик прерываний
	ORG INT_HANDLER
           EX DE,HL
           EX (SP),HL
           LD (SaveRET+1),HL
           EX DE,HL
           POP DE
           LD (SaveSP+1),sp
           LD SP,STACK_IM2
           CALL MAIN_ISR
SaveSP LD SP,#0000
           EI
SaveRET JP #0000

В чём же может быть проблема? Что-то к вечеру совсем не соображу...

[Advertiser]

[drbars]

Вроде помогло...)) Шо это было?)))

[TomCaT]

Если прерывания разрешены (EI перед Main Loop), и SP не имеет свободной области под указываемым им адресом - то гайки. Если читаемый буфер SPR1 односторонний или постоянно обновляемый в тех же прерываниях, то достаточно освободить немного места перед его началом, как сказал krt17. Кстати, там точно нужны 2 команды EX DE,HL ?

[drbars]

Как я понял, у каждого спрайта, который будет выводиться таким способом первые два байта нужно резервировать. так?

[drbars]

Т.к. прерывание может подпортить любые его четыре байта во время вывода на экран.

В моём случае вроде ничего не портится, полоска выводится непрерывно. Глюков в ней нет. Два байта в начале запарываются, но там можно всегда нули держать на такой случай.

krt17,
Не догнал, что там это даст?

ld hl,spr1
ld e,(hl)
inc hl
ld d,(hl)
inc hl
ld sp,hl
ld hl,#4000

[TomCaT]

Да, я поправил свое сообщение, но написал все в общих словах, интересно все равно - не совсем понял задачу, которая была поставлена. Перечитал все еще раз - выводятся НЕ 32 байта #FF, а то, что при каждом прерывании обработчик записывает в буфер SPR1?

И нужны ли EX DE,HL ?

[drbars]

Да, я поправил свое сообщение, но написал все в общих словах, интересно все равно - не совсем понял задачу, которая была поставлена. Перечитал все еще раз - выводятся НЕ 32 байта #FF, а то, что при каждом прерывании обработчик записывает в буфер SPR1?

И нужны ли EX DE,HL ?

Пример в топике - отладка алгоритма. В Main_loop будет цикл задач. Одна из которых должна рисовать локации на экране таким способом.

И нужны ли EX DE,HL ?

Да, нужны. Без них не работает

[Titus]

При разрешенных прерываниях будут портится спрайты, если только не сделать синхронизацию с прерываниями так, чтобы на момент прихода прерывания, спрайты уже все были напечатаны.

А... все понятно, у вас как бы восстановление в обработчике INT'a )

[drbars]

для понимания процесса рекомендую разобраться самому, думать это же приятно .

Сколько уже напридумывал, сам в шоке Суть в общем-то ясна

Чудненько работает:

ld hl,SPR1
ld e,(hl)
inc hl
ld d,(hl)
inc hl
ld sp,hl
ld hl,#4000

DUP 16
LD (HL),E
INC HL
LD (HL),D
INC HL
POP DE
EDUP

Этот способ хорош, чтобы дергать расчитанные адреса экрана из таблиц циклом)

[jerri]

drbars,

interrupt
            di
            ex (sp),hl   ;забираем со стека адрес возврата
            ld (imret),hl ;сохраняем адрес возврата
            pop hl        ;забираем hl 
            ld (imstek),sp ;сохраняем стек 
            push bc ;либо push de в зависимости от того каким регистром берем спрайты
            ld sp,int_sp
            call proc_int
            
            ld sp,$
imstek   equ $-2
            ei
            jp $
imret     equ $-2


;процедура вывода спрайта

;hl откуда 
;de куда
;в bc будут данные 

        ld (retsp),sp        
;забираем первое слово
        ld c,(hl)
        inc hl
        ld b,(hl)
        inc hl
        ld sp,hl
;---------------
;манипулируем
;---------------
        ld sp,$
retsp equ $-2
        ret

как то так