Быстрый вывод картинки 88*88

**Andrew771** · 30.03.2011, 12:33

Лови процедуру масштабирования спрайта в 4 раза. Выводит сразу на экран без всяких промежуточных буферов и таблиц, чтобы максимально сэкономить память. Проверок на выход за пределы экрана нет, так что координаты знакомест в спрайте должны иметь значения: вертикальная = 0..5, горизонтальная = 0..7.

Код:

		; тестовая программа
		ORG	60000
		LD	HL,SPRITE
		LD	D,0
		LD	E,0
		CALL	ZOOM
		RET


; подпрограмма масштабирования в 4 раза спрайта
; входные параметры: HL=адрес спрайта, DE=координаты знакоместа для вывода на экране (D-вертик., E-гориз.)

ZOOM		LD	A,(HL)				; HL = адрес нахождения в спрайте
		AND	A
		RET	Z				; выход, если пустой спрайт

		LD	B,A
ZOOML1		PUSH	BC				; B = количество знакомест в спрайте
		PUSH	DE				; DE = координаты знакоместа для вывода

		INC	HL
		LD	A,(HL)
		RLCA
		RLCA
		ADD	A,D
		LD	B,A
		INC	HL
		LD	A,(HL)
		RLCA
		RLCA
		ADD	A,E
		LD	C,A				; BC = реальные координаты левого верхнего знакоместа на экране

		INC	HL
		EX	DE,HL				; DE = адрес нахождения в спрайте, HL = свободно

		LD	(TMP_BC),BC			; запоминаем BC

                LD	A,B				; расчет адреса атрибутов знакоместа в HL
                RRCA
                RRCA
                RRCA
                LD	L,A
                AND	31
                OR	88
                LD	H,A
                LD	A,L
                AND	252
                OR	C
                LD	L,A				; HL = адрес атрибутов левого верхнего знакоместа


		; заполняем квадрат 4х4 знакоместа змейкой байтом атрибутов
		LD	BC,32
		LD      A,(DE)                          ; читаем байт атрибутов знакоместа в спрайте
                LD      (HL),A                          ; заносим атрибуты знакоместа на экран
		INC	HL
		LD	(HL),A
		INC	HL
		LD	(HL),A
		INC	HL
		LD	(HL),A
		ADD	HL,BC
                LD      (HL),A
		DEC	HL
		LD	(HL),A
		DEC	HL
		LD	(HL),A
		DEC	HL
		LD	(HL),A
		ADD	HL,BC
                LD      (HL),A
		INC	HL
		LD	(HL),A
		INC	HL
		LD	(HL),A
		INC	HL
		LD	(HL),A
		ADD	HL,BC
                LD      (HL),A
		DEC	HL
		LD	(HL),A
		DEC	HL
		LD	(HL),A
		DEC	HL
		LD	(HL),A


		; масштабируем по паре байтов знакоместа (4 пары), заполняем прямоугольник 4х1 знакоместа
		LD	B,4
ZOOML2		PUSH	BC				; B = номер пары байтов изображения

		LD	BC,(TMP_BC)			; BC = реальные координаты левого верхнего знакоместа для пары
		INC	B
		LD	(TMP_BC),BC			; сразу запоминаем BC для следующей пары байтов
		DEC	B

		INC	DE				; DE = адрес нахождения в спрайте

                LD      A,B				; расчет адреса первого байта знакоместа в HL
                LD      H,A
                RRCA
                RRCA
                RRCA
                AND	A,224
		ADD	A,C
                LD	L,A
                LD	A,H
                AND	24
                OR	64
                LD	H,A				; HL = адрес вывода знакоместа на экране, DE = адрес изображения в спрайте

		PUSH	DE
		CALL	ZBYTES				; выводим масштабированный первый байт пары
		POP	DE

		INC	DE
		PUSH	DE
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный второй байт пары
		POP	DE

		POP	BC
		DJNZ	ZOOML2				; на следующую пару	

		EX	DE,HL				; HL = адрес нахождения в спрайте, DE = свободно

		POP	DE				; DE = координаты спрайта на экране
		POP	BC				; B = цикл по количеству знакомест в спрайте
		DJNZ	ZOOML1
		RET


		; масштабирование байта изображения
		; DE = адрес в спрайте, HL = адрес первого байта знакоместа на экране
ZBYTES		LD	A,(DE)
		LD	B,A				; B = байт изображения
		XOR	A
		LD	C,A
		LD	D,A
		LD	E,A				; в регистры C,D,E,A будем кидать масштабированные по горизонтали биты по два

ZOOM7           RL      B				; загоняем во флаг CY 7-й бит байта изображения
		JP	NC,ZOOM6			; если CY=0, переходим на следующий
		OR	#F0				; устанавливаем %1111 для бита

ZOOM6		RL	B
		JP	NC,ZOOM5
		OR	#0F

ZOOM5		LD	C,A
		XOR	A
		RL	B
		JP	NC,ZOOM4
		OR	#F0

ZOOM4		RL	B
		JP	NC,ZOOM3
		OR	#0F

ZOOM3		LD	D,A
		XOR	A
		RL	B
		JP	NC,ZOOM2
		OR	#F0

ZOOM2		RL	B
		JP	NC,ZOOM1
		OR	#0F

ZOOM1		LD	E,A
		XOR	A
		RL	B
		JP	NC,ZOOM0
		OR	#F0

ZOOM0		RL	B
		JP	NC,ZOOM8
		OR	#0F

		; выводим на экран содержимое регистров C,D,E,A змейкой в прямоугольник 4х0.5 знакоместа
ZOOM8		LD	(HL),C
		INC	HL
		LD	(HL),D
		INC	HL
		LD	(HL),E
		INC	HL
		LD	(HL),A

		INC	H
		LD	(HL),A
		DEC	HL
		LD	(HL),E
		DEC	HL
		LD	(HL),D
		DEC	HL
		LD	(HL),C

		INC	H
		LD	(HL),C
		INC	HL
		LD	(HL),D
		INC	HL
		LD	(HL),E
		INC	HL
		LD	(HL),A

		INC	H
		LD	(HL),A
		DEC	HL
		LD	(HL),E
		DEC	HL
		LD	(HL),D
		DEC	HL
		LD	(HL),C

		RET


TMP_BC		DEFW	0				; буфер для хранения значений в BC

SPRITE							; тестовый спрайт
DEFB 16
DEFB 0,0,33, 128,0,0,24,24,0,8,255
DEFB 1,0,34, 192,48,192,48,192,48,192,48
DEFB 1,1,33, 12,3,12,3,12,3,12,3
DEFB 1,2,33, 0,0,0,0,128,192,64,192
DEFB 2,0,2, 254,159,129,224,254,31,24,248
DEFB 2,1,2, 7,230,254,223,193,240,255,15
DEFB 2,2,2, 192,64,64,192,192,64,64,192
DEFB 3,0,2, 255,159,128,224,255,31,24,248
DEFB 3,1,2, 6,254,255,195,192,254,63,6
DEFB 3,2,2, 64,64,192,192,64,64,192,192
DEFB 4,0,3, 255,143,128,224,255,31,24,248
DEFB 4,1,3, 230,255,207,192,248,255,6,6
DEFB 4,2,3, 64,192,192,64,64,192,192,64
DEFB 5,0,3, 255,131,128,224,255,24,24,248
DEFB 5,1,3, 255,255,192,192,255,31,6,6
DEFB 5,2,3, 192,192,64,64,192,192,64,64

**ALKO** · 30.03.2011, 13:07

Сообщение от NovaStorm

Вообще имелось в виду общее направление файтинга, школа и стиль игры. Планируется ли он быстрым/агрессивным с "рывками" и блоками в воздухе, а-ля ГГ, или футсис тягомотиной на земле а-ля СФ? А может это вообще симулятор? =)
Ну или вообще (с учётом платформы-то, да =)), комбы будут?
<troll-mode/>список знаком же?
http://ru.wiktionary.org/wiki/Прилож...йтинг-терминов

это врят ли,сложно сделать динамичную игру на машине с ограниченой памятью и вычислительными способностями (хотя очень хотелось бы).
Тут должно присутствовать мастерство кодинга.

**NovaStorm** · 30.03.2011, 15:09

Но можно менять концепт, и сделать например одинаковых бойцов, взамен разнообразив им движения. Тем более что с ростом джвижений, кол-во анимаций расти будет не так существенно, тк много спрайтов будет повторяться.
Да и по поводу маски, если ещё не отказался, то наверное можно сделать на экране снизу пол, сверху какую-нибудь фигню как на скрине, а поле оставить пустым, визуально это не сильно скажется, но сэкономить и память и такты на маске поможет.
Такие спрайты как на мокапе, можно наверное хорошо сжимать RLE+START/(STEP)/STOP кодами. А декодировать таблично - получится почти Хаффман.
ЗЫ: Если уж делать файтинг, надо побить по играбельности хотя бы Yie Ar Kung-Fu =)

**ALKO** · 30.03.2011, 15:22

Сообщение от NovaStorm

ЗЫ: Если уж делать файтинг, надо побить по играбельности хотя бы Yie Ar Kung-Fu =)

Ну или хотя бы Mortal Kombat 3

**NovaStorm** · 30.03.2011, 15:53

Сообщение от ALKO

Ну или хотя бы Mortal Kombat 3

Это который из них? А то на спеке я играбельных МК не помню, все делались как технодемы =\

**Andrew771** · 30.03.2011, 19:38

Сообщение от Andrew771

Лови процедуру масштабирования спрайта в 4 раза.

Кстати, если тебе не нужны атрибуты, то процедуру можно сократить.

**Advertiser** · 30.03.2011, 19:38

**ALKO** · 30.03.2011, 21:09

атрибуты не нужны,а увеличение бы в 2 раза сделать

**Andrew771** · 30.03.2011, 21:49

Сообщение от ALKO

атрибуты не нужны,а увеличение бы в 2 раза сделать

хорошо, завтра сделаю

**Robus** · 31.03.2011, 03:34

Привет !

Очень немаловажно это то, какая будет графика. От этого будет зависеть степень сжатия графики. Я по-быстрому набросал примеры вывода графики. Данная графика, что была выложена как пример, была, конечно большая. И ко всему этому прогнанная через конвертер, а значит уже не идеальна. Как бы то ни было, я сделал три вида вывода графики, с разными параметрами объёмов и скорости. И так, в примере высвечивается спрайт 80х88 пикселей, и если нажать:

"1" - Вывод с максимальной скоростью, размер одного спрайта примерно 2200 байт.
"2" - Вывод с упаковкой, размер одного спрайта примерно 800 байт.
"3" - Вывод без упаковки с оптимальной скоростью, размер одного спрайта ТОЧНО 960 байт.

Цветом на бордюре ты можешь определить занятость процессора и примерно оценить сколько ты успеешь сделать кадров за секунду. Второй вариант должен был упаковать данный спрайт, но спрайт не простой из-за чего сжатие не сильное.

Хочу обратить внимание, что совсем не ясен весь процесс вывода спрайта. Вывод квадратика(спрайта) не так сложно, сложен комплекс. В первую очередь нужно чётко спланировать желаемый результат. Графику поле вывода нужно стереть(наверное), скорее всего спрайты должны налазить друг на друга(наверное). В общем, в итоге получится "движок". Хочу сразу привести пример на написанный мной движок вот по этой ссылке: http://zx.pk.ru/showthread.php?t=2513

Этот "движок" вряд-ли можно подружить с бейсиком, и собственно, не вижу смысла. Однако в этом "движке" реализована возможность отображать героев высотой в 1/2 экрана с наложением и регенерацией всего экрана. Мало того, графика именно упакованная, и реализована возможность поворачивать героев. Плюс возможность отображать только маску, что можно использовать как эффект мерцания героя. Расчёт игры был именно для Mortal Kombat. И оба персонажа со всеми ударами влазили в 128к, без фаталитей, конечно.

В общем, если заинтересуешься, я дам способ вывода спрайтов, и конвертеры графики. Сейчас я выложу пример вывода по клавише "3":

Код:

        LD HL,18432+8

ShowSSPR
        LD (SSSx1+1),SP
        EXX
        LD SP,SSPRTDT
        POP DE
        LD YL,D
        LD A,E
        RRCA
        LD C,A
        RLCA
        RLCA
        ADD A,C
        LD B,0
        LD C,A
        LD HL,SSSxEN
        SBC HL,BC
        LD (SSSxJ0+1),HL
        LD (SSSxJ1+1),HL
        LD (SSSxJ2+1),HL
        LD A,E
        NEG
        INC A
        EXX
        LD B,0
        LD C,A
        JR SSSxJ2
SSSxST  DUB 16
         POP DE     ;10
         LD (HL),E  ;7
         INC L      ;4
         LD (HL),D  ;7
         INC L      ;4
        EDUB
SSSxEN  EQU $
        ORG $-1
        DEC YL
        JR Z,SSSx1
        ADD HL,BC
        LD A,H
        AND 7
SSSxJ0  JP NZ,0
        LD A,L
        ADD A,32
        LD L,A
SSSxJ1  JP C,0
        LD A,H
        SUB 8
        LD H,A
SSSxJ2  JP 0
SSSx1   LD SP,0
        RET

SSPRTDT DB 10,88
        IncBIN "gfx_00.bin"

Остальные способы не привожу, поскольку они адаптированы под мой язык ASAM. Если нужно будет, скажи я и их упрощу(распишу) под стандартные ассемблеры.

Да ... И ... Это ... Маленький совет ... Выкинь ВАСИК !

**Andrew771** · 31.03.2011, 11:33

Наверное, не стоит делать компрессию спрайтов, лучше масштабирование.
А стирать область экрана тоже асмовской процедурой.

Вот процедура для увеличения спрайта в 2 раза, без атрибутов:

Код:

		; тестовая программа
		ORG	60000
		LD	HL,SPRITE
		LD	D,0
		LD	E,0
		CALL	ZOOM
		RET


; подпрограмма масштабирования в 2 раза и вывода спрайта
; входные параметры: HL=адрес спрайта, DE=координаты знакоместа для вывода на экране (D-вертик., E-гориз.)

ZOOM		LD	A,(HL)				; HL = адрес нахождения в спрайте
		AND	A
		RET	Z				; выход, если пустой спрайт

		LD	B,A
ZOOML1		PUSH	BC				; B = количество знакомест в спрайте
		PUSH	DE				; DE = координаты знакоместа для вывода

		INC	HL
		LD	A,(HL)
		RLCA
		ADD	A,D
		LD	B,A
		INC	HL
		LD	A,(HL)
		RLCA
		ADD	A,E
		LD	C,A				; BC = реальные координаты левого верхнего знакоместа на экране

		INC	HL
		EX	DE,HL				; DE = адрес нахождения в спрайте, HL = свободно

                LD      A,B				; расчет адреса первого байта знакоместа в HL для 1-4 байтов изображения
                LD      H,A
                RRCA
                RRCA
                RRCA
                AND	A,224
		ADD	A,C
                LD	L,A
                LD	A,H
                AND	24
                OR	64
                LD	H,A				; HL = адрес вывода знакоместа на экране, DE = адрес изображения в спрайте

		PUSH	BC

		CALL	ZBYTES				; выводим масштабированный первый байт

		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт


		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт


		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт

		POP	BC

		INC	B				; второе знакоместо ниже для 5-8 байтов изображения

                LD      A,B				; расчет адреса первого байта знакоместа в HL для 5-8 байтов изображения
                LD      H,A
                RRCA
                RRCA
                RRCA
                AND	A,224
		ADD	A,C
                LD	L,A
                LD	A,H
                AND	24
                OR	64
                LD	H,A				; HL = адрес вывода знакоместа на экране, DE = адрес изображения в спрайте

		INC	DE				; следующий байт изображения в спрайте
		CALL	ZBYTES				; выводим масштабированный байт


		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт


		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт


		INC	DE				; следующий байт изображения в спрайте
		INC	H				; следующая строка в знакоместе
		CALL	ZBYTES				; выводим масштабированный байт


		EX	DE,HL				; HL = адрес нахождения в спрайте, DE = свободно

		POP	DE				; DE = координаты знакоместа для вывода
		POP	BC				; B = цикл по количеству знакомест в спрайте
		DJNZ	ZOOML1

		RET


		; масштабирование байта изображения
		; DE = адрес в спрайте, HL = адрес первого байта знакоместа на экране
ZBYTES		LD	A,(DE)
		LD	B,A				; B = байт изображения
		XOR	A
		LD	C,A				; в регистры C и A будем кидать масштабированные по горизонтали биты по четыре

ZOOM7           RL      B				; загоняем во флаг CY 7-й бит байта изображения
		JP	NC,ZOOM6			; если CY=0, переходим на следующий
		OR	%11000000			; устанавливаем %11 для бита

ZOOM6		RL	B
		JP	NC,ZOOM5
		OR	%00110000

ZOOM5		RL	B
		JP	NC,ZOOM4
		OR	%00001100

ZOOM4		RL	B
		JP	NC,ZOOM3
		OR	%00000011

ZOOM3		LD	C,A
		XOR	A
		RL	B
		JP	NC,ZOOM2
		OR	%11000000

ZOOM2		RL	B
		JP	NC,ZOOM1
		OR	%00110000

ZOOM1		RL	B
		JP	NC,ZOOM0
		OR	%00001100

ZOOM0		RL	B
		JP	NC,ZOOM8
		OR	%00000011

		; выводим на экран содержимое регистров C и A змейкой в 2 байта по 2 строки
ZOOM8		LD	(HL),C
		INC	HL
		LD	(HL),A
		INC	H
		LD	(HL),A
		DEC	HL
		LD	(HL),C

		RET


SPRITE							; тестовый спрайт
DEFB 16
DEFB 0,0, 255,0,0,24,24,0,0,255
DEFB 1,0, 192,48,192,48,192,48,192,48
DEFB 1,1, 12,3,12,3,12,3,12,3
DEFB 1,2, 0,0,0,0,128,192,64,192
DEFB 2,0, 254,159,129,224,254,31,24,248
DEFB 2,1, 7,230,254,223,193,240,255,15
DEFB 2,2, 192,64,64,192,192,64,64,192
DEFB 3,0, 255,159,128,224,255,31,24,248
DEFB 3,1, 6,254,255,195,192,254,63,6
DEFB 3,2, 64,64,192,192,64,64,192,192
DEFB 4,0, 255,143,128,224,255,31,24,248
DEFB 4,1, 230,255,207,192,248,255,6,6
DEFB 4,2, 64,192,192,64,64,192,192,64
DEFB 5,0, 255,131,128,224,255,24,24,248
DEFB 5,1, 255,255,192,192,255,31,6,6
DEFB 5,2, 192,192,64,64,192,192,64,64

User Tag List

Тема: Быстрый вывод картинки 88*88

Опции темы

Отображение

Вывод графики ...

Информация о теме

Пользователи, просматривающие эту тему

Похожие темы

Быстрый проигрыватель AY-музыки (980-1300t)

Вывод картинки на экран

Нужен быстрый поиск аналога отечественной логики

Куплю проц Z84C0006PEC или более быстрый.

Метки этой темы

Ваши права