Программирование на УКНЦ как?

[form]

шаблончик

        .TITLE  TEST
        .MCALL  .EXIT,.PRINT

START:: MOV     #DATA,R5
        CALL    PRDAT
        .EXIT

PRDAT:: CALL    @PC                     ;PROPAGATE CODE TWO TIMES
        MOV     #BUFF,R0                ;BUFFER ADDRESS
        MOV     @R5,R1                  ;VALUE
        MOV     #16.,R2                 ;BIT COUNT
10$:    CLR     -(SP)                   ;INIT CHAR
        ROL     R1                      ;SHIFT OUT
        ROL     @SP                     ;SHIFT IN
        BIS     #'0,@SP                 ;CONVERT TO ASCII
        MOVB    (SP)+,(R0)+             ;PUT INTO BUFFER
        SOB     R2,10$                  ;TO NEXT BIT
        MOVB    #<' >,(R0)+             ;SPACE
        MOV     (R5)+,R1                ;VALUE
        CLR     R2                      ;SUPPRESS LEADING ZEROS
        CALL    $CBOMG                  ;CONVERT TO ASCII
        CLRB    @R0                     ;MAKE ASCIZ
        .PRINT  #BUFF                   ;PRINT
        RETURN                          ;RETURN

DATA:   .WORD   64152,164377
BUFF:   .BLKB   80.

        .END    START

.EX TEST
0110100001101010 64152
1110100011111111 164377

.

Подпрограмма $CBOMG есть в родном SYSLIB от RT-11. Если вместо CLR R2 сделать перед вызовом MOV PC,R2, то ведущие нули подавляться не будут.

[gfd71]

есть в родном SYSLIB от RT-11

в какой книге они описаны?

[form]

в какой книге они описаны?

В RTшном руководстве по системной библиотеке $CBOMG не описан. Он просто есть как минимум начиная с RT-11 V5.0. Описание есть в RSXовском руководстве по SYSLIB. Для простоты вот хелп по нему - больше по сути и не нужно ничего:

>HELP SYSL CBOMG
 
 Convert binary to octal magnitude
 
 Input:                                 Output:
 
 R0 = Address of output buffer          R0 = Points to next byte in output
                                             buffer after converted string
 R1 = Binary value to be converted
 R2 = Zero suppression flag:
        R2 = 0 => Suppress leading zeros
        R2 = 1 => Do not suppress leading zeros
 
 Call:
        CALL    $CBOMG
>

Здесь написано про R2=0 или 1, но на самом деле 0 и не 0

- - - Добавлено - - -

Если что, я портировал в свое время самые интересные подпрограммы из RSX, в теме софта можно поискать RSXLIB. Там много полезного уже готового

- - - Добавлено - - -

Небольшое упрощение:

PRDAT:: CALL    @PC                     ;PROPAGATE CODE TWO TIMES
        MOV     #BUFF,R0                ;BUFFER ADDRESS
        MOV     @R5,R1                  ;VALUE
        MOV     #16.,R2                 ;BIT COUNT
10$:    MOVB    #'0,@R0                 ;INIT CHAR
        ROL     R1                      ;GET BIT
        ADCB    (R0)+                   ;CONVERT TO ASCII
        SOB     R2,10$                  ;TO NEXT BIT
        MOVB    #<' >,(R0)+             ;SPACE
        MOV     (R5)+,R1                ;VALUE
        CLR     R2                      ;SUPPRESS LEADING ZEROS
        CALL    $CBOMG                  ;CONVERT TO ASCII
        CLRB    @R0                     ;MAKE ASCIZ
        .PRINT  #BUFF                   ;PRINT
        RETURN                          ;RETURN

[gfd71]

Если что, я портировал в свое время самые интересные подпрограммы из RSX, в теме софта можно поискать RSXLIB. Там много полезного уже готового

спасибо

[hobot]

Если что, я портировал в свое время самые интересные подпрограммы из RSX, в теме софта можно поискать RSXLIB. Там много полезного уже готового

http://archive.pdp-11.org.ru/ukdwk_a.../form_rsxlib2/

[gfd71]

осталось найти

Описание работы с лексическим разбором
можно найти в
RSX-11M/M+/MicroRSX/IAS I/O
Operations Reference Manual.

и по идее счастье должно наступить

[form]

осталось найти

RSX-11M-PLUS and Micro/RSX I/O Operations Reference Manual
7 глава

[gfd71]

добрый вечер.
сегодня разбирался с программой

.TITLE TEST

вроде всё понятно, но.....

CALL @PC ;PROPAGATE CODE TWO TIMES

если убрать то выведет одну строку
а вот добавить третью четвёртую у меня не получилось
сильно чайника не пинайте ну не понял

[Hunta]

После строчки CALL @PC ещё строчка CALL @PC

Только срабатывать будет степень двойки количество раз - 1, 2, 4, 8 и т.д.

Вроде не ошибся

[form]

если убрать то выведет одну строку
а вот добавить третью четвёртую у меня не получилось

Если 4 строки, то просто два раза CALL @PC. В любом случае всегда можно убрать его в принципе и в цикле вызывать столько раз сколько адресов нужно