Важная информация

User Tag List

Страница 1 из 16 12345 ... ПоследняяПоследняя
Показано с 1 по 10 из 156

Тема: Читабельный ФАПЧ

  1. #1
    ZEK
    Гость

    По умолчанию Читабельный ФАПЧ

    На углепати подымали вопрос про читаемость и легкость для понимания ФАПЧ по сыркам.
    Ясен пень что табличные или перенесеным с схем на сумматорах с перетусоваными битами фапчи малопонятны.

    Решил восполнить пробел и написать простенький фапч (коментов гораздо больше чем кода) на более менее читаемом языке

    Код:
    // синтезируемый
    module phase_sync(
        input   wire        clk,   // 8mhz
        input   wire        rddat,
        output  reg         rclk,
        output  reg         rawr
        );
        
    // *******************************************************
    // формирование RAWR 
    // *******************************************************
        
    // защелка где храним предыдущее состояние сигнала rddat с дисковода
    // нужно для определния момента отрицательного фронта
    reg oldrd;
    
    // формируем rawr 125нс
    always @ (posedge clk)
    begin               
        // запоминаем текущее значение
        oldrd <= rddat; 
        // формируем rawr если на предыдущем такте rddat =1 а на текущем =0
        rawr <= !(oldrd == 1'b1 && rddat == 1'b0); // тут oldrd еще содержит старое значение
    end
    
    
    // *******************************************************
    // формирование RCLK
    // *******************************************************
    
    // счетчик для формирования меандра RCLK, один оборот счетчика это полуволна RCLK
    reg [3:0] counter = 0;                     
    // дельта в тактах от оптимальной точки расположения RAWR относительно RCLK 
    // RAWR в идельном случае долен находиться в середине полуволны RCLK
    wire[3:0] delta = (8 - counter) +1; 
    // 8 середина полуволны, 
    // +1 для того что бы при совпадении фаз счетик инкреметировался а не стоял на месте
    // можно полюдски написать 9-counter что то же самое
    
    // знаково делим смещение пополам, будем приближаться к оптимальной точке на полшага перекоса фаз.
    wire[3:0] shift = { delta[3], delta[3], delta[2:1] };
    
    always @ (posedge clk)
    begin                 
        // RAWR = 0, значит сравниваем его положение с оптимальным 
        // и если надо (delta >= 2 или delta =< 2) корректируем фазу RCLK
        if (rawr == 0)                          
            counter[3:0] <= counter + shift;
        else
            counter <= counter + 1;  // иначе просто инкрементируем счетчик
            
        // закончилась полуволна генерируем меандр
        if (counter == 15) rclk = ~rclk; 
    end
    
    initial 
    begin
        rclk = 1'b0; 
    end
    
    endmodule
    Можно колво кода как уменьшить понизив читабельность, так и увеличив, выбрал нечто среднее

    Где то так...
    Последний раз редактировалось ZEK; 22.02.2014 в 19:03.

  2. Эти 6 пользователя(ей) поблагодарили ZEK за это полезное сообщение:
    Ewgeny7 (17.08.2011), fifan (16.08.2011), Keeper (17.08.2011), lisica (16.08.2011), SoftFelix (17.08.2011), Дмитрий (16.08.2011)

  3. #1
    С любовью к вам, Yandex.Direct
    Размещение рекламы на форуме способствует его дальнейшему развитию

  4. #2
    Пользователь Специалиста Аватар для fifan
    Регистрация
    30.05.2007
    Адрес
    г. Лянтор, Сургутского р-на, ХМАО
    Сообщений
    2,966
    Благодарностей: 645
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    Где будем испытывать? На Скорпионе?
    http://nick-name.ru/forum/Fifan.gif
    Сайт про ПК "Специалист" и его клоны http://www.spetsialist-mx.ru/
    Web site about computer Spetsialist and its clones http://www.spetsialist-mx.ru/ (yet only in Russian)

  5. #3
    Veteran Аватар для lisica
    Регистрация
    19.12.2008
    Адрес
    Черкассы
    Сообщений
    1,504
    Благодарностей: 390
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    А кто это переведёт в VHDL?
    Робик 1024(пентагоновские тайминги),+ 7Мц+, 2AY(TS),+ контроллер дисковода,+ 3.5,+ 5.25 флоп,+CMOS,+ mouse(caro),+ Flash.
    Pentagon 128(1991г.)+YМ
    программатор 2732-27512.


  6. #4
    Guru Аватар для Дмитрий
    Регистрация
    01.01.2009
    Адрес
    Донецк, Украина
    Сообщений
    3,234
    Благодарностей: 715
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    fifan, где-где... там где ее ну ооооочень не хватает - на Пентэве

  7. #5
    ZEK
    Гость

    По умолчанию фапч 28мгц

    пересчитал и пофиксил под 28мгц

    Код:
    // синтезируемый
    module phase_sync28(
        input   wire        clk,   // 28mhz
        input   wire        rddat,
        output  reg         rclk,
        output  reg         rawr
        );
        
    // *******************************************************
    // формирование RAWR 
    // *******************************************************
        
    // защелка где храним предыдущее состояние сигнала rddat с дисковода
    // нужно для определния момента отрицательного фронта
    reg oldrd;  
    // сдвиговый регистр для формирования raclk 150нс
    reg [3:0] rawr0;
    
    // формируем rawr 150нс
    always @ (posedge clk)
    begin               
        // запоминаем текущее значение
        oldrd <= rddat; 
        // формируем rawr если на предыдущем такте rddat =1 а на текущем =0
        // пишем в сдвиговый регистр, заодно сдвигаем его
        rawr0 <= { rawr0[2:0], !(oldrd == 1'b1 && rddat == 1'b0) };
        
        // если хоть один бит в сдвиговом регистре 0 тогда rawr =0, что при клоке свдига 28мгц, примерно 150нс
        rawr = !(rawr0 != 4'hF);
    end
    
    
    // *******************************************************
    // формирование RCLK
    // *******************************************************
    
    // счетчик для формирования меандра RCLK, один оборот счетчика это полуволна RCLK
    reg [5:0] counter = 0;                     
    // дельта в тактах от оптимальной точки расположения RAWR относительно RCLK 
    // RAWR в идельном случае долен находиться в середине полуволны RCLK
    wire[5:0] delta = (24 - counter) +1; 
    // 24 середина полуволны -4 (на столкьо тактов удлинили RAWR)
    // +1 для того что бы при совпадении фаз счетик инкреметировался а не стоял на месте
    // можно полюдски написать 25-counter что то же самое
    
    // знаково делим смещение пополам, будем приближаться к оптимальной точке на полшага перекоса фаз.
    wire[5:0] shift = { delta[5], delta[5], delta[4:1] };
    
    always @ (posedge clk)
    begin                 
        // RAWR = 0, значит сравниваем его положение с оптимальным 
        // и если надо (delta > 2 или delta < 2) корректируем фазу RCLK
        if (rawr0[0] == 0)                          
            counter <= counter + shift;
        else  
            // проверяем дошли ли мы до длины полуволны примерно в 2мкс
            // rclk тут что бы компенсировть хоть немного отклонение от 2мкс
            if (counter < (54+rclk))
                counter <= counter + 1; // есил 
            else           
            begin             
                counter <= 0;
                rclk = ~rclk;  
            end
    
    end
    
    initial 
    begin
        rclk = 1'b0; 
    end
    
    endmodule
    И диаграмка сравнивающая 2 фапча на одних входных данных
    Последний раз редактировалось ZEK; 22.02.2014 в 19:03.

  8. Эти 3 пользователя(ей) поблагодарили ZEK за это полезное сообщение:
    balu_dark (18.08.2011), doorsfan (17.08.2011), Дмитрий (17.08.2011)

  9. #6
    Пользователь Специалиста Аватар для fifan
    Регистрация
    30.05.2007
    Адрес
    г. Лянтор, Сургутского р-на, ХМАО
    Сообщений
    2,966
    Благодарностей: 645
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    В какую ПЛИС предполагается запихнуть данное творение?
    http://nick-name.ru/forum/Fifan.gif
    Сайт про ПК "Специалист" и его клоны http://www.spetsialist-mx.ru/
    Web site about computer Spetsialist and its clones http://www.spetsialist-mx.ru/ (yet only in Russian)

  10. #7
    Guru Аватар для Дмитрий
    Регистрация
    01.01.2009
    Адрес
    Донецк, Украина
    Сообщений
    3,234
    Благодарностей: 715
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    fifan, я вкорячиваю это в EP1K50, а вообще, как Дима говорит - творение занимает 8 макроячеек, так что влезет в любую, даже EPM3032.

  11. Этот пользователь поблагодарил Дмитрий за это полезное сообщение:
    fifan (17.08.2011)

  12. #8
    Guru
    Регистрация
    16.12.2009
    Адрес
    Харьков
    Сообщений
    3,605
    Благодарностей: 1752
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    Цитата Сообщение от Дмитрий Посмотреть сообщение
    fifan, где-где... там где ее ну ооооочень не хватает - на Пентэве
    Если ФАПЧ заработает на Эве, мож я таки её себе и прикуплю!
    Profi must live!

    Моё железо...

    1. Profi 5.06/1Mb(DRAM)+Profi5.06(UP)/HDD/3`5FDD/CF512Mb/SD-CARD
    2. Profi 3.2/1Mb/3`5FDD/HDD6.4Gb/Pentagon_Fix
    3. Profi 6.2 Rev. B/1Mb/3`5FDD/HDD3.2Gb
    4. Profi 5.05(down)/1Mb+Profi 5.03(UP)/Pentagon_Fix
    Все укомплектованы:
    Profi_ZX-BUS/ZXMC2/NemoIDE/SounDrive
    [свернуть]

  13. #9
    Super Moderator Аватар для Ewgeny7
    Регистрация
    03.07.2005
    Адрес
    Санкт-Петербург
    Сообщений
    9,451
    Благодарностей: 3797
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    А что, на Эве дисковод плохо работает? Я просто не в курсе, использовал там дисковод всего пару раз, год назад
    Scorpion ZS 1024 turbo+/ZXMC 2.6/SD-HDD/FDD/AT-Keyb/Mouse/SMUC 2.0/ProfROMse/VGA 3.0/NeoGS
    ZX-Evolution 4096 rev.B

    Сайт с документацией к "Scorpion ZS 256"

  14. #10
    Guru Аватар для Дмитрий
    Регистрация
    01.01.2009
    Адрес
    Донецк, Украина
    Сообщений
    3,234
    Благодарностей: 715
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    По умолчанию

    Цитата Сообщение от Ewgeny7 Посмотреть сообщение
    А что, на Эве дисковод плохо работает?
    есть пачка дискет, которые Эва не хавает, хотя тот же Кай даже не поперхнулся (с одним и тем же дисководом).

    ---------- Post added at 11:16 ---------- Previous post was at 10:44 ----------

    Собрал прошиву, если седни не нажрусь, то попробую

  15. Эти 2 пользователя(ей) поблагодарили Дмитрий за это полезное сообщение:
    Ewgeny7 (17.08.2011), psb (17.08.2011)

Страница 1 из 16 12345 ... ПоследняяПоследняя

Информация о теме

Пользователи, просматривающие эту тему

Эту тему просматривают: 1 (пользователей: 0 , гостей: 1)

Похожие темы

  1. ищу схему ФАПЧ
    от zorel в разделе Внешние накопители
    Ответов: 3
    Последнее: 28.07.2011, 22:20
  2. ФАПЧ
    от Sayman в разделе Unsorted
    Ответов: 2
    Последнее: 26.02.2009, 10:26

Ваши права

  • Вы не можете создавать новые темы
  • Вы не можете отвечать в темах
  • Вы не можете прикреплять вложения
  • Вы не можете редактировать свои сообщения
  •