C чего начать геймдэв для горбатыша?

**jerri** · 16.01.2012, 09:03

ALKO, ТехЗадание же
с него родного все начинается
можешь даже сюда писать

но нежелательно - закидаю(т)

**Andrew771** · 16.01.2012, 10:14

Сообщение от ALKO

На асме же можно сделать вывод спрайтов (опять таки тут меня интересует вывод спрайта с маской), но игровую логику на асме просто нереально для меня создать, это куча cmp, jmp nz ,call-ов, ret-ов и т.д.

Ну для начала можно писать "быдло-код", но на ассемблере. Примерно так:

Для каждой переменной заводим байты памяти и метку:

Код:

var_i         defb 0         ; однобайтовая переменная
var_j         defb 0        ; однобайтовая переменная
var_x         defw 0         ; двухбайтовая переменная
var_y         defw 0        ; двухбайтовая переменная

А затем оперируем постоянно с ними, как на Бейсике:

Код:

                ; LET i=i+j

                ld a,(var_i)
                ld c,a
                ld a,(var_j)
                add a,c
                ld (var_i),a

                ; или вот так, но тут портится регистр HL:

                ld hl,var_i
                ld a,(var_j)
                add a,(hl)
                ld (hl),a


                ; LET x=x+y

                ld hl,(var_x)
                ld de,(var_y)
                add hl,de
                ld (var_x),hl


                ; сложение однобайтовой и двухбайтной переменной LET x:=x+i:

                ld a,(var_i)
                ld c,a
                ld b,0                         ; превратили регистр a в регистр bc
                ld hl,(var_x)
                add hl,bc
                ld (var_x),hl

Проверка условий:

Код:

                ; IF i>j THEN LET i=i-j ELSE LET i=i+j
                ; т.к. в асме нет проверки условия "больше", то заменяем на "меньше":
                ; IF j<i THEN LET i=i-j ELSE LET i=i+j

                ld a,(var_j)
                ld hl,var_i
                cp (hl)
                jp c,label01
                
                add a,(hl)
                jp label02

label01       ld a,(hl)
                ld hl,var_j
                sub a,(hl)

label02       ld (var_i),a

Цикл со счетчиком:

Код:

               ; повторить 45 раз

                ld b,45
loop01       push bc                              ; запомнить b в стеке
                ...
                pop bc                               ; достать b из стека
                djnz loop01

               ; если внутри цикла регистр b не изменяется, то можно убрать push bc и pop bc.

Цикл со счетчиком и с принудительным выходом из тела цикла:

Код:

              ; FOR i=0 to 20
              ; ...
              ; IF i>15 THEN <выход из цикла>
              ; NEXT i
              ; ...

              ld b,20
loop01     push bc
              ld a,20
              sub a,b
              ld (var_i),a                         ; получили значение i
              ...
              ld a,(var_i)
              cp 16                                ; if i>=16
              jp nc,label01                       ; then goto label01
              pop bc
              djnz loop01
              jp label02
label01     pop bc                               ; возвращаем стек в исходное состояние, т.к. до этого мы туда втолкнули bc
label02     ...

**jerri** · 16.01.2012, 10:25

Andrew771, подожди физикой грузить
пусть сначала лирику опишет

**Andrew771** · 16.01.2012, 10:46

Процедура вывода спрайта (без масок):

Код:

; подпрограма вывода спрайта
; входные параметры: HL=адрес спрайта, D=вертик.координата вывода на экране, E=гориз.координата вывода на экране
; выходных параметров нет

PUTSPR		LD	A,(HL)
		AND	A
		RET	Z				; выход, если пустой спрайт
		LD	B,A
PUTS1		PUSH	BC				; B = количество знакомест в спрайте

		INC	HL
		LD	A,(HL)
		ADD	A,D
		LD	B,A
		INC	HL
		LD	A,(HL)
		ADD	A,E
		LD	C,A
		INC	HL
		PUSH	DE				; DE = координаты спрайта на экране
		EX	DE,HL				; DE = адрес нахождения в спрайте, HL = свободно





                LD      A,B				; расчет адреса первого байта знакоместа в HL
                LD      H,A
                RRCA
                RRCA
                RRCA
                AND	A,224
		ADD	A,C
                LD	L,A
                LD	A,H
                AND	24
                OR	64
                LD	H,A				; HL = адрес вывода знакоместа на экране, DE = адрес изображения в спрайте

		; вывод знакоместа (8 строк)


		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта
		INC     DE
                INC     H

		LD	A,(DE)
		LD	(HL),A				; вывели байт спрайта

		EX	DE,HL				; HL = адрес нахождения в спрайте

		POP	DE				; HL = адрес нахождения в спрайте, DE = координаты спрайта на экране
		POP	BC				; B = цикл по количеству знакомест в спрайте
		DJNZ	PUTS1
		RET



; спрайты

SPRITE01
DEFB 14                                                   ; количество знакомест в спрайте
DEFB 14,3, 0,0,0,0,0,0,255,255                    ; знакоместо 1: координата y, координата x, 8 байтов изображения
DEFB 15,3, 0,23,20,243,0,0,0,0                    ; знакоместо 2
...            и так 14 знакомест ...

---------- Post added at 10:32 ---------- Previous post was at 10:30 ----------

Сообщение от jerri

Andrew771, подожди физикой грузить
пусть сначала лирику опишет

ALKO уже умеет игры на Бейсике и Дельфи писать, к асму надо приучить.

---------- Post added at 10:46 ---------- Previous post was at 10:32 ----------

Сообщение от ALKO

Как можно перевести из указания координат видом X/Y в адрес хранящийся ввиде двух байт (DEC)? Что б записывать значения через Poke.

Код:

                LD      B,Y
                LD      C,X

                LD      A,B
                LD      H,A
                RRCA
                RRCA
                RRCA
                AND	A,224
		ADD	A,C
                LD	L,A
                LD	A,H
                AND	24
                OR	64
                LD	H,A	  ; HL = адрес вывода знакоместа на экране

**ALKO** · 16.01.2012, 14:56

Сообщение от Andrew771

ALKO уже умеет игры на Бейсике и Дельфи писать,

с\с++ не указали.

**Andrew771** · 16.01.2012, 15:04

Сообщение от ALKO

с\с++ не указали.

Тогда попробуй кросс-компилятор ccz80, удобный, но не оптимальный: http://zx.pk.ru/showpost.php?p=450358&postcount=4

**AER** · 16.01.2012, 16:30

все вопросы решаются тут - http://zxpress.ru/

**AndTorp** · 16.01.2012, 19:38

Сообщение от Andrew771

ALKO уже умеет игры на Бейсике и Дельфи писать, к асму надо приучить.

В таком случае, для приучения, можно попробовать попереводить с ЯВУ на ассемблер какие-нибудь программы.
Например из книги Максима Мозгового "Занимательное программирование".

Сообщение от alone

Для начала питона осильте. Потом уже к тетрисам можно переходить

Удав и Тетрис, в вышеприведенной книге, разобраны хорошо.

**ALKO** · 16.01.2012, 20:57

Сообщение от Andrew771

огда попробуй кросс-компилятор ccz80, удобный, но не оптимальный:

z88dk оптимизированее...Только с ним не могу разобраться.

---------- Post added at 19:45 ---------- Previous post was at 19:43 ----------

Спасибо за код перевода XY в 2 байта.
Теперь то же самое нужно для перевода address (формата DEC) в 2 байта.

---------- Post added at 20:53 ---------- Previous post was at 19:45 ----------

На бейцыке это будет примерно так:
add= 40000
x=int(add/256)
y= add-(x*256)

---------- Post added at 20:55 ---------- Previous post was at 20:53 ----------

x - старший байт
y - младший байт

---------- Post added at 20:57 ---------- Previous post was at 20:55 ----------

хотя проще будет выбирать фрейм
40000+k*n, где n - номер фрэйма
k - объём фрейма в байтах

**goodboy** · 16.01.2012, 21:40

Сообщение от ALKO

для перевода address (формата DEC) в 2 байта.

На бейцыке это будет примерно так:
add= 40000
x=int(add/256)
y= add-(x*256)

x - старший байт
y - младший байт

на ZX бейсике проще сделать так
RANDOMIZE addr
hi=peek 23671
low=peek 23670

User Tag List

Тема: C чего начать геймдэв для горбатыша?

Опции темы

Отображение

Информация о теме

Пользователи, просматривающие эту тему

Похожие темы

Голая Амига с чего начать

Концепции? Для чего?

Как заставить плеер PT3 начать играть заново?

Подскажите с чего начать знакомство со спекки...

Ваши права