Как быстро скроллить память на 2 пиксела?

[Barmaley_m]

Нет, не оправдает. Попробуй напиши и рассчитай, сколько получится тактов.

Пишем (скролл влево):

    LD SP,nn ;10
    POP HL ;10
    POP DE ;10
    POP BC ;10
    RL H ;8
    RL L ;8
    RL D ;8
    RL E ;8
    RL B ;8
    RL C ;8
    EXX ;4
    POP HL;10
    POP DE ;10
    POP BC ;10
    RL H ;8
    RL L ;8
    RL D ;8
    RL E ;8
    RL B ;8
    RL C ;8
    EXX ;4
    EX AF,AF' ;4
    RL H ;8
    RL L ;8
    RL D ;8
    RL E ;8
    RL B ;8
    RL C ;8
    EXX ;4
    RL H ;8
    RL L ;8
    RL D ;8
    RL E ;8
    RL B ;8
    RL C ;8
    EX AF,AF' ;4
    PUSH BC ;11
    PUSH DE ;11
    PUSH HL ;11
    EXX ;4
    PUSH BC ;11
    PUSH DE ;11
    PUSH HL ;11

Этот фрагмент обрабатывает 12 байт. Растактовка:
На POP - 6*10 = 60 тактов
На PUSH - 6*11 = 66 тактов
На LD SP - 10 тактов
На EXX - 4*4 = 16 тактов
На EX AF,AF' - 2*4 = 8 тактов
На RL - 12*2*8 = 192 такта
Всего 352 такта
На каждый байт - 29 + 1/3 тактов в среднем.

Хоть 4 команды EXX сжирают 16 тактов, а одна LD SP - 10 тактов - то кажется, что без EXX будет быстрее. Однако, если делать блоками по 6 байт без EXX - то будет:
POP - 3*10 = 30
PUSH - 3*11 = 33
LD SP - 10
EX AF,AF' - 8
RL - 6*2*8 = 96
Всего - 177
На каждый байт - 29.5 тактов в среднем. Чуть больше.

Причина в том, что при обработке блоками по 12 байт встречается в 2 раза меньше команд EX AF,AF' в среднем. То есть с EXX потеря 6 тактов на EXX, однако выигрыш 8 тактов на EX AF,AF'. В конечном счете выигрыш в 2 такта.

[Advertiser]

[Titus]

Barmaley_m, круто)
Делай, пожалуйста, демы)

[drbars]

Barmaley_m, не работает. вся строка на 3 не сдвигается.

[drbars]

У меня как-то так получилось:
58 тактов / байт

	LD HL,#401F
	DUP 32 			; SCROLL 3
	LD C,(HL)
	RL C
	EX AF,AF'
	RL C
	EX AF,AF'
	RLA
	RL C
	RRA
	LD (HL),C 	
	DEC L
	EDUP

Стековый вариант 57,5 тактов на байт

Если использовать прямую адресацию LD HL,(nn) / LD (nn),HL — получим 56 тактов на байт.

	LD (STACK+1),SP
	LD HL,#401E
	DUP 16 			; SCROLL 3
	LD SP,HL
	DEC L
	DEC L
	POP DE
	RL D
	EX AF,AF'
	RL D
	EX AF,AF'
	RLA
	RL D
	RRA
	RL E
	EX AF,AF'
	RL E
	EX AF,AF'
	RLA
	RL E
	RRA
	PUSH DE	
	EDUP
STACK:
	LD SP,#0000

Если пишем стеком LD HL,(nn) / PUSH HL немного быстрее будет — 53,5 такта на байт.

ADR=#401E
	LD (STACK+1),SP
	LD SP,#4020

	DUP 16 			; SCROLL 3
	LD HL,(ADR)
	RL H
	EX AF,AF'
	RL H
	EX AF,AF'
	RLA
	RL H
	RRA
	RL L
	EX AF,AF'
	RL L
	EX AF,AF'
	RLA
	RL L
	RRA
	PUSH HL

ADR=ADR-2	
	EDUP

STACK
	LD SP,#0000

Вариант без EX AF,AF', по скорости одинаково.

ADR=#401E
	LD (STACK+1),SP
	LD SP,#4020

	DUP 16 			; SCROLL 3
	LD HL,(ADR)
	RL H
	RLA
	RL H
	RLA
	RL H
	RRA
	RRA
	RL L
	RLA
	RL L
	RLA
	RL L
	RRA
	RRA
	PUSH HL

ADR=ADR-2	
	EDUP

STACK
	LD SP,#0000

[drbars]

Если на 3 надо первым проходом rld вторым rr обратно. Хотя все это не актуальные извраты имхо.

Этот пример тут был уже, тоже нерабочий.

[Titus]

Этот пример тут был уже, тоже нерабочий.

Разве может Alone дать нерабочий пример)

Бармалей написал пример скроллинга на 2, а не на 3.

[drbars]

Разве может Alone дать нерабочий пример)
Бармалей написал пример скроллинга на 2, а не на 3.

У меня он чё-та не заработал. Как им строку сдвинуть в 32 байта на 3 точки влево?

Там ошибка, вот правильно:
37 тактов байт.

	DUP 32 			; SCROLL 3
	RLD
	RR (HL)
	DEC L
	EDUP

[Barmaley_m]

У меня он чё-та не заработал.

Не понял, что не заработало, где ошибки?

Как им строку сдвинуть в 32 байта на 3 точки влево?

Тема о сдвиге на 2 точки. Мой код свигает на 2.

То, что 32 не делится на 12, означает, что надо двигать две группы по 12 и потом еще одну группу из 8 байт. Получить на базе моего кода сдвиг укороченной группы из 8 байт - задача несложная. Ее я оставил в качестве домашнего задания тем, кому это интересно.

Ну и вообще уже не раз было сказано, что, даже если сдвигать всю информацию чисто на регистрах, 8 тактов на сдвиг одного байта на один бит - это слишком много. Фреймового скролла на 2 пиксела на полный экран не получится. Почитайте все тему разработки Sea Dragon. Там было рассмотрено много разных вариантов, в итоге от "честного" скролла отказались в пользу тайловой графики.

[drbars]

То есть это правильно, а у алона ошибка? Мда...

Сам проверь.. DEL L после RR надо и всё.

RLD: DEC L
+
RR (HL):INC L
=
41 такт на байт.

---------- Post added at 11:49 ---------- Previous post was at 11:45 ----------

Не понял, что не заработало, где ошибки?

Вроде как читать стеком POP xx и записывать PUSH xx подходит для сдвига вправо RR x. Для сдвига влево читать с конца нужно, POP не годится, т.к. увеличивает SP на 2.

[drbars]

krt17, видимо значит мой вариант c RLD не рабочий...