Есть ли пара для гасилки из Терминатора?

[STD]

Всех форумчан с Днем России!
Скажите, есть ли у кого процедура зажигания экрана, которая бы точно повторяла процедуру его гашения как в Терминаторе? Если есть, поделитесь, плиз. Набрал тут процедуру зажигания, которая предлагалась как пара в этюдах Ревю №3 за 1995г., но там эффект совершенно не такой красивый, а очень хочется чтобы заставка в игре и зажигалась и гасилась одинаково. Или может у кого из гуру изменить процедуру гашения на зажигание займет 5 минут? Не проявите свою благосклонность?

Скрытый текст

FO0   ld   b,7
FO01  halt
      ld   hl,24000
FO02  dec  hl 
      ld   a,l 
      or   h 
      jr   nz,FO02
      ld   hl,22528
FO03  ld   a,(hl) 
      and  56
      jr   z,FO04
      sub  8
FO04  ld   c,a 
      ld   a,(hl) 
      and  7
      jr   z,FO05
      dec  a 
FO05  or   c 
      ld   (hl),a 
      inc  hl 
      ld   a,h 
      cp   91
      jr   nz,FO03
      djnz FO01
      ret

[свернуть]

[Advertiser]

[denpopov]

Набрал тут процедуру зажигания, которая предлагалась как пара в этюдах Ревю №3 за 1995г., но там эффект совершенно не такой красивый, а очень хочется чтобы заставка в игре и зажигалась и гасилась одинаково. Или может у кого из гуру изменить процедуру гашения на зажигание займет 5 минут? Не проявите свою благосклонность?

как два пальца об асфальт. Как только праздник кончится

[goodboy]

вот процедуры из игры
зажигание (надеюсь где находятся аттрибуты для картинки поймёшь)

	LD   B,#07
L7E74:	HALT
	LD   HL,#5800
L7E78:	LD   A,H
	ADD  A,#14
	LD   H,A
	LD   C,(HL)
	LD   A,C
	AND  #38
	LD   D,A
	LD   A,C
	AND  #07
	LD   E,A
	LD   A,H
	SUB  #14
	LD   H,A
	LD   A,(HL)
	AND  #38
	CP   D
	JR   NC,L7E92
	ADD  A,#08
	LD   D,A
L7E92:	LD   A,(HL)
	AND  #07
	CP   E
	JR   NC,L7E9A
	INC  A
	LD   E,A
L7E9A:	LD   A,C
	AND  #C0
	OR   D
	OR   E
	LD   (HL),A
	INC  HL
	LD   A,H
	CP   #5B
	JR   NZ,L7E78
	DJNZ L7E74
	RET

гашение

	LD   B,#07
L7E4F:	HALT
	LD   HL,#0258
	CALL #7C19
	LD   HL,#5800
L7E59:	LD   A,(HL)
	AND  #38
	JR   Z,L7E60
	SUB  #08
L7E60:	LD   C,A
	LD   A,(HL)
	AND  #07
	JR   Z,L7E67
	DEC  A
L7E67:	OR   C
	LD   (HL),A
	INC  HL
	LD   A,H
	CP   #5B
	JR   NZ,L7E59
	DJNZ L7E4F
	RET
L7C19:	DEC  HL
	LD   A,L
	OR   H
	JR   NZ,L7C19
	RET

[STD]

Спасибо!!! Да, звание ГУРУ просто так не дают

[krt17]

Зажигалка не такая как гасилка, делал недавно правильную совсем другой эффект. Гудбой откуда это убожество выдрано?
Конкурс в Ревю 95 года помню, очень расстроился что к моей процедурке приклеили какую то мелочь другого участника и написали ай какой он молодец, а ты krt17 нуб иди учись Прикольное было время.

- - - Добавлено - - -

Перечитал понял, странно от буржуев в 90-х ожидал большего, даже у никодима лучше сделано.

[STD]

Зажигалка не такая как гасилка, делал недавно правильную совсем другой эффект. Гудбой откуда это убожество выдрано?

Ну, не знаю, попробовал и мне кажется вполне себе. В любом случае с тем зажиганием, что я сначала набрал из вышеуказанного Ревю не сравнить - в разы приятнее.
Гудбой, ещё раз спасибо! Разбираясь, где там буффер атрибутов заодно смог модифицировать, чтобы буффер стал по любому адресу. Горжусь собой уже полчаса ))