Преодоление барьера машинного кода. Hello world на zx spectrum , и всё такое прочее

[Spectramine]

Вот именно. Мне для преодоления барьера машинного кода хватило POKE и RANDOMIZE USR)

[Bedazzle]

В общем, тот набросок, что накидал, вышел 34 байта, но не предел.

22 байта через водку /зачёркнуто/ ром /зачёркнуто/
через rst 16

[Shiny]

22 байта через водку /зачёркнуто/ ром /зачёркнуто/
через rst 16

ну пости здесь, разрушим барьеры что-ли.

- - - Добавлено - - -

	device zxspectrum128
        ORG #6000
begin

	ld de,$4000
lp1:
	ld a,e
	and 31
	
	ld l,a
	add hl,hl
	add hl,hl
	ld h,$1E
	add hl,hl
	inc h
	push de
	ld b,8
lp2:
	ld a,(hl)
	ld (de),a
	inc hl
	inc d
	djnz lp2
	pop de
	inc e
	jr nz,lp1
	ld a,d
	add a,8
	ld d,a
	cp $58
	jr nz,lp1
	jr $
end
	display /d,end-begin
	savesna "!void.sna",begin

34 байта без jr $

[Bedazzle]

ну пости здесь, разрушим барьеры что-ли.

	DEVICE ZXSPECTRUM48

	org 25000
QUIZZSTART:
	ld a, 22	; AT
	rst 16
	xor a		; xcoord
	rst 16
	xor a		; ycoord
	rst 16

	ld c, 22
loop1:
	ld b, 32
loop2:
	ld a, ' '+32
	sub b
	rst 16
	djnz loop2

	dec c
	db 32, -11	; ;jr nz loop1
	
stop:
	jr stop
	
	;ret
	
QUIZZEND:	
	
	
	SAVEBIN "quizz.bin", QUIZZSTART, QUIZZEND - QUIZZSTART

Почему-то ужасм не компилит jr nz loop1 у меня, просто скипает эту команду, если смотреть дизасм :/ причём в другом проекте нормально компилится.
Поэтому поставил затычку через db.

[Shiny]

jr nz,loop1 ?

[Spectramine]

Почему-то ужасм не компилит jr nz loop1 у меня, просто скипает эту команду, если смотреть дизасм :/ причём в другом проекте нормально компилится.
Поэтому поставил затычку через db.

Может, запятая пропущена между nz и loop1?

[Bedazzle]

jr nz,loop1 ?

Ну вот нельзя немножко накосячить, как все сразу всё знают.

[krt17]

Вы же меня ждали? Нет, ну ладно, 21 без rst

Скрытый текст

			device	zxspectrum48
			org	0x8000
start
			ld	de, 0x57ff
.l1			
			ld	h, 0x3d
			ld	a, e
		.3	add	a, a
			xor	d
			and	0xf8
			xor	d
			ld	l, a
			ldd
			ld	a, h
			cp	d
			jr	nz, .l1
			ret
			display	/A,$-start
			savesna	"test_g.sna", start

[свернуть]

Для преодолевателей барьеров думаю не предел.

[Bedazzle]

Вы же меня ждали? Нет, ну ладно, 21 без rst

Декремент... ХитрО!

[Shiny]

аплодирую стоя (: