32 бит деление

[ivagor]

По аналогии со второй версией без восстановления остатка, сделал подобную версию и с восстановлением

Скрытый текст

; BC = HLBC/DE, HL = HLBC%DE
; Restoring division
DIV32:
		ld a,b
		call DIV32_8
		push af
		ld a,c
		call DIV32_8
		pop bc
		ld c,a
		ret
		
; A = HLA/DE, HL = HLA%DE
DIV32_8:
		ld b,8
DIV321:
		add a,a
		adc hl,hl
		jr c, DIV322
		sbc hl,de
		jr nc, DIV323
		add hl,de
		djnz DIV321
		ret
DIV322:
		ccf
		sbc hl,de
DIV323:
		inc a
		djnz DIV321
		ret

[свернуть]

+7 байт, но она быстрее и 2в1 - тут не только 32/16=16, но и 24/8=8 (кстати без восстановления остатка тоже во второй версии эта фишка есть, забыл там написать).
В итоге у каждого метода (restoring и non-restoring) по два варианта: компактный и побыстрее. Если сравнивать методы, то очевидно restoring компактнее, non-restoring быстрее. Можно еще немного ускорить за счет некоторого увеличения размера, но не сильно, тут уже каждый сам может при желании доработать.

[Sayman]

снова возник вопрос:
вот эти процедуры деления, там написано в комментариях: DE = HLDE/BC, HL = HLDE%BC
я не сильно спец в таких вещах, но модуль числа то там зачем? или это остаток? или как?

[b2m]

А разве остаток от деления и "модуль числа" не одно и то-же?
(на самом деле, модуль числа это совсем другое, но я понял, что ты имел ввиду деление по модулю)

[ivagor]

Избавиться в приведенных процедурах деления от вычисления остатка и сохранить вычисление правильного частного не получится. Хотя если быть очень занудным, то можно так: полностью развернуть и тогда можно будет убрать одну операцию ближе к завершению деления. Экономия мизерная, но если остаток совсем не нужен, размер не важен, зато важен каждый такт, то почему бы и нет (сам так делал). Можно наоборот - вычислять только остаток без частного, вот тут процедуру можно упростить, ускорить и сократить.

[Sayman]

хотелось бы вернуться к банным борашкам. Возникла потребность в делении 32:32, наверное даже с остатком. Можете помочь, товарищи знатоки?!

[ivagor]

Возникла потребность в делении 32:32, наверное даже с остатком

С уклоном в скорость или компактность?

[Sayman]

С уклоном в скорость или компактность?

ну скорость бы хотелось.... наверное.

[ivagor]

Сравнительно быстрый вариант, но без фанатизма

;BCBC'=BCBC'/DEDE'
;HLHL'=BCBC'%DEDE'
DIV323232:
		ld hl,0
		exx
		ld hl,0
		ld a,b
		exx
		push bc
		call DIV328
		exx
		ld b,a
		ld a,c
		exx
		call DIV328
		exx
		ld c,a
		exx
		pop bc
		ld a,b
		call DIV328
		push af
		ld a,c
		call DIV328
		pop bc
		ld c,a
		ret
DIV328:
		ld b,8
DIV328loop:
		add a,a
		adc hl,hl
		exx
		adc hl,hl
		exx
		sbc hl,de
		exx
		sbc hl,de
		exx
		jr nc,DIV328_
		add hl,de
		exx
		adc hl,de
		exx
		djnz DIV328loop
		ret
DIV328_:
		inc a
		djnz DIV328loop
		ret

[свернуть]

[Sayman]

спустя вот это всё время выясняется, что вот эта процедура работает не корректно.
если заставлять её делить 32бита просто на 2 (или подобные значения), то выдаёт мусор.

[ivagor]

если заставлять её делить 32бита просто на 2 (или подобные значения), то выдаёт мусор.

Если заставлять делить 32 бита на 2 или 3 или на много что еще с получением результата не помещающегося в 16 бит, то нужно использовать другую процедуру. А в той процедуре написано: BC = HLBC/DE, HL = HLBC%DE и она работоспособна в данных пределах.