ЭТЮДЫ

[Знахарь]

Destr красава, особенно полезно для 8 бит результата плюс остаток.
Небольшой макрос для вычисления адреса в пиксельном экрана познакоместно. Раньше мучался, сейчас использую постоянно.

			macro	at x,y
			db	(y&0x07)*0x20+x
			db	(y&0x18)+0x40
			endm

Вот, кстати, нашлись подобные макросы в Alasm:

alasm:

Вычисление экранного адреса.

getS метка,3,4*8 (4пикселя и *8 для знакомест)

\0 - Имя создаваемой переменной
\1 - X coord (в знакоместах)
\2 - Y coord (в пикселях)

MACRO getS ; label,X,Y ($-SCR)
\0 EQU Ss
\0=\0+((\2)&192*32)+((\2)&7*256)+((\2)&56*4)+((\1) &31)

ENDM



Вычисление адреса в атрибутах.

get@ метка,X,Y

\0 - Имя создаваемой переменной
\1 - X координата (в знакоместах)
\2 - Y координата (в знакоместах)

MACRO get@ ; label,Xat,Yat (@-ATTR)
\0 EQU As
\0=\0+((\2)*32)+((\1)&#1F)

ENDM

[Advertiser]

[Знахарь]

коллеги, а никто не желает запостить этюдик поворот спрайта на 90 градусов? Простой - кратный знакоместу. Хватит для 8х8 точек и 16х16 точек

[char]

навскидку, будет что-то такое:

symrot:
	ld	b,#08
lp_rot1:
	push	hl
        ld	a,#80
lp_rot2:
	rlc	(hl)
	inc	hl
	rra
	jr	nc,lp_rot2

	pop	hl
	ld	(de),a
	inc	de
	djnz	lp_rot1

	ret

для 2*2, можно дописать сверху:

symrot4:
	call	symrot2
        ld      c,#08
        add    hl,bc

symrot2:
        push  hl
	ld	bc,#0010
	add	hl,bc
	call	symrot
        pop   hl

не проверялось, возможно где-то что-то просмотрел

[blackmirror]

Если рассматривать вариант отражения спрайта 8x8 относительно диагонали (поворот на 90* получается при записи строк в обратном порядке, но с диагональю проще объяснять), то нужно выполнить следующие операции:
1) разделить блок 8x8 на 4 части, два блока на диагонали оставить на месте, два других переставить.
2) разделить каждый блок 4x4 на 4 части, два блока на диагонали оставить на месте, два других переставить.
3) разделить каждый блок 2x2 на 4 точки, две точки на диагонали оставить на месте, две другие переставить.
При желании данные шаги можно выполнять и в другом порядке.

Для выполнения 1 шага нужно загрузить первые 4 строки в BCDE, далее используя команду RLD и регистр A обменять младшие половины загруженныx строк со старшими половинами строк лежащих в памяти(два блока в памяти при этом будут переставлены, но это можно исправить сдвинув каждую строку 4 командами RLC или RRC, когда дело дойдёт до второй половины спрайта).

Для выполнения 2 шага нужно провести следующие вычисления:
A=(B^(D>>2))&0x33;
B^=A;
D^=A<<2;
и аналогично для строк C и E

Третий шаг выглядит аналогично, только сдвиг будет не на 2, а на 1, и маска будет 0x55 вместо 0x33.
Теперь первая половина спрайта готова и нужно загрузить и выполнить 2 и 3 шаг для второй половины спрайта.

[Shiny]

с 16х16 вышло так

[char]

если 16*16 графика идет не посимвольно, а 2 байта * 16 строк, то тогда можно вот так, без ix/iy

rot16:
	call	rot16a
	inc	hl

rot16a:
	ld	bc,#0880
lp_r161:
	push	hl
        ld	a,c
lp_r162:
	rlc	(hl)
	inc	hl
	inc	hl
	rra
	jr	nc,lp_r162

	ex	af,af'

        ld	a,c
lp_r163:
	rlc	(hl)
	inc	hl
	inc	hl
	rra
	jr	nc,lp_r163

	ld	(de),a
	inc	de
	ex	af,af'
	ld	(de),a
	inc	de

	pop	hl
	djnz	lp_r161

	ret

[Shiny]

если 16*16 графика идет не посимвольно, а 2 байта * 16 строк, то тогда можно вот так, без ix/iy

это зеркальное отражение по вертикали.

[char]

это зеркальное отражение по вертикали.

где? ...сходил, проверил, все нормально сработало, даже без ошибок

вставь к себе

ld hl,spr
ld de,spr+32
push de
call rot16
pop hl
push de
call rot16
pop hl
push de
call rot16
pop hl

[Shiny]

мда. не увидеть такого простого решения

стареем.

[krt17]

Просто 2 на 2 вращать не очень интересно поэтому от меня произвольного размера

Скрытый текст

;in hl - original
;   de - destination
;   bc - height weight
sprRotate
			ld	a, e
			add	a, b
			ld	e, a
			jr	nc, $+3
			inc	d
			dec	de
			ld	a, c
.l3			; цикл по строкам
			push	af
			ld	a, 0x08
.l2			; цикл по линиям
			push	af
			push	hl
			push	bc
			ld	a, b
.l1			; цикл по байтам в линии
			push	af
			ld	b, 0
			ld	a, 0x80
.l0			; цикл по байтам
			rlc	(hl)
			rra
			jr	c, .s1
			add	hl,bc
			jr	.l0
.s1
			add	hl,bc
			ld	(de), a
			dec	de
			pop	af
			dec	a
			jr	nz, .l1
			pop	bc
			push	bc
			ex	de, hl
			ld	c, b
			ld	b, a
			add	hl, bc
			add	hl, bc
			ex	de, hl
			pop	bc			
			pop	hl
			pop	af
			dec	a
			jr	nz, .l2
			inc	hl
			pop	af
			dec	a
			jr	nz, .l3
			ret

[свернуть]

Ну и проверка со спрайтом на злобу дня так сказать