        ORG #5B00;=23296
;ࠩ  祭 6- ⠭  
; ࠡ  ⥬ ⠩஬.
;⠥ 祭 FRAMES  ॢ   , .  ᥪ.
;Grand, 1.11.2009.
;
        JR PG_ON
        JR RTC
        DEFB 0
        DEFB 6
;
PG_TAB  DEFB #10,#11,#13,#14,#16,#17,0
PG_ON   PUSH HL;祭  , . .  A
        LD HL,PG_TAB
        ADD A,L
        LD L,A
        LD A,(HL)
        OR A
        POP HL
        SCF 
        RET Z ;᫨ 室  CY=1 -  믮.
        PUSH BC
        LD BC,#7FFD
        OUT (C),A
        POP BC
        OR A
        RET ;室  CY=0 - 믮.
;
; 祭 ᮢ (E), (B)  ᥪ㭤 (C).
RTC     LD BC,(23674)
        LD DE,(23672)
        LD B,0
        LD A,50
        CALL DV32_8
        CALL DV32_8-2
        LD (RTC1+1),A
        CALL DV32_8-2
        LD (RTC2+1),A
        LD A,24
        CALL DV32_8
        LD E,A;
RTC2    LD B,000;࠭ 
RTC1    LD C,000;࠭ ᥪ㭤
        OR A
        RET ;室  CY=0 - 믮.
;
        DEFS #5B5C-$+1; ﬨ
;  ⥪.   23388 ⥫쭮.
;
        LD A,60
;  ⪮ (楤  Caro):
;  BCDE (32bits)
;⥫  A (8bits)
;⭮  BCDE (32bits)
;⮪  A (8bits)
DV32_8  LD L,A
        LD H,32
        EXX 
        LD BC,0
        LD DE,0
        EXX 
        XOR A
DLOOP   RL E
        RL D
        RL C
        RL B
        RLA 
        JR C,NOCHK
        SUB L
        JR NC,NOGO
        ADD A,L
        CCF 
        JR YESGO
NOCHK   SUB L
NOGO    SCF 
YESGO   EXX 
        RL E
        RL D
        RL C
        RL B
        EXX 
        DEC H
        JR NZ,DLOOP
        EXX 
        RET 
;
        DEFM "** Driver of TR-DOS "
        DEFM "NAVIGATOR for ZX SPECTRUM 128 and "
        DEFM "System timer, 2009 **"

