Алгоритмы рисования окружности и OVER 1

Вот Мичнер в более приятной для Олега паскалевидной форме: ;)

Код:

---

procedure bres_circle(xc,yc,r:interger):
 var x,y,d:integer:
 procedure sim(x,y;integer);
  begin
    putpixel(x+xc,y+yc,White);
    putpixel(x+xc,-y+yc,White);
    putpixel(-x+xc,-y+yc,White);
    putpixel(-x+xc,y+yc,White);
    putpixel(y+xc,x+yc,White);
    putpixel(y+xc,-x+yc,White);
    putpixel(-y+xc,-x+yc,White);
    putpixel(-y+xc,x+yc,White);
  end;
  begin
  d:=3-2*y;
  x:=0;
  y:=r;
  while(x <= y) do
    begin
    sim(x,y);
    if d<0    then d:=d+4*x+6
    else begin
    d:=d+4*(x-y)+10;
    dec(y)
    end;
  inc(x)
  end;
 end;

---

Кстати, воспринимается полегче, чем Си.

Цитата:

---

Сообщение от Sergey

Не могу сказать, сколько раз рисуются точки, - это, вообще, странно слышать, что одна точка несколько раз рисуется.

---

Вот-вот, а я-то как удивился. :)

Цитата:

---

Сообщение от Sergey

Зачем, также, этот кривой ПЗУшный алгоритм?

---

Разве что для полного соответствия ZX-Бейсику или экономии памяти. Ну и реверанс в сторону Ревю и книжек по графике, где окружность предлагалось рисовать только алгоритмом из ПЗУ.

Цитата:

---

Сообщение от Sergey

Рекомендую алгоритм Мичнера. Мне его окружности больше глаз радуют.

---

Спасибо! Полезно и для не-ZX. Если будет целиком в машкоде (или адаптированный для Спека) — буду рад увидеть код.

Цитата:

---

Сообщение от Oleg N. Cher

Хотелось бы найти быструю и корректную в этом смысле процедуру. Что посоветуете?

---

Решил пока воздержаться от изобретания велосипеда, - вот нашёл:
http://icereijo.com/a-circle-algorithm-for-zx-spectrum/
там и исходники, и тапка, и видео даже.

Цитата:

---

Сообщение от Oleg N. Cher

То есть некоторые точки рисуются по два раза. И даже если вообще никто не рисует окружности в режиме OVER 1, то всё равно это - потеря производительности.

---

Эврика. Выбранная тобой процедура, используя свойства симметрии, рисует точки по октетам. При одной из координат равной 0, количество вариантов расположения точек вырождается до 4-х: смещения от оси симметрии равны +0/-0. Поэтому точки при этом рисуются на одном и том же месте. Избежать этого можно, если для случаев x=0 / y=0 сделать специальные п/п рисования точек.

а как включить режим OVER 1 для #22Е5 через код?

Цитата:

---

Сообщение от GM BIT

а как включить режим OVER 1 для #22Е5 через код?

---

На скорую руку вот так включал #5C91=1
Но это без передачи управления бейсику, иначе он обратно вернёт.

Пробуйте. Не должно быть повторных точек. Учитывает края экрана.
Расплата: 14 и 20 тактов на точку соответственно.

Код:

---

void circle3(unsigned char cx, unsigned char cy, unsigned char r) __naked
{ cx,cy,r;
__asm
        ld  hl,#2
        add hl,sp
        ld  b,(hl)
        inc hl
        ld  c,(hl)
        inc hl
        ld  l,(hl)

        ld        (xcyc+1),bc ; b = x, c = y. , переменная в коде команды.
        xor        a,a
        ld        c,l ; y = r;
        ld        b,a ; x = 0;
        ld        h,a
        add        hl,hl
        ld        de,#5
        ex        de,hl
        or        a,a
        sbc hl,de
        ld        (var_d+1),hl ; d = 5 - 2r;

loop:
        ld        a,b
        cp        c
        jp        c,q0
        call        z,pixels
        ret
q0:        call        pixels
var_d:
        ld        de,#0 ;        _d        переменная в коде команды.
        bit        7,d
        jp        z,q1
; d < 0:
        ld        h,#0
        ld        l,b
        add        hl,hl
        add        hl,hl
        add        hl,de
        ld        de,#6
        add        hl,de
        ld        (var_d+1),hl
        inc        b        ; ++x
        jp        loop

q1:        ld        a,b        ; x-y
        sub c
        ld        l,a
        sbc a,a
        ld        h,a ; sign is extended
        add        hl,hl
        add        hl,hl
        add        hl,de
q3:        ld        de,#10
        add        hl,de
        ld        (var_d+1),hl
        dec        c        ; --y
        inc b        ; ++x
        jp        loop

pixels:
        ;xc+x, yc+y
xcyc:        ld        hl,#0        ;(xcyc)
        ld        a,b
        or  a,a
        jp  z,p1
        add        a,h
        jp        c,p1
        ld        d,a
        ld        a,c
        or  a,a
        jp  z,p1
        add a,l
        cp        a,#192
        jp        nc,p1
        ld        e,a
        call        plote
        ; xc+x, yc-y
        ld        hl,(xcyc+1)
p1:        ld        a,b
    or  a,a
    jp  z,p2
        add        a,h
        jp        c,p2
        ld        d,a
        ld        a,l
        sub a,c
        jp        c,p2
        ld        e,a
        call        plote
        ; xc-x, yc-y
        ld        hl,(xcyc+1)
p2:        ld        a,h
        sub        a,b
        jp        c,p3
        ld        d,a
        ld        a,l
        sub a,c
        jp        c,p3
        ld        e,a
        call        plote
        ; xc-x, yc+y
        ld        hl,(xcyc+1)
p3:        ld        a,h
        sub        a,b
        jp        c,p4
        ld        d,a
        ld        a,l
        or  a,a
        jp  z,p4
        add a,c
        cp        #192
        jp        nc,p4
        ld        e,a
        call        plote
        ; xc+y, yc+x
        ld        hl,(xcyc+1)
p4:        ld        a,h
    or  a,a
    jp  z,p5
        add        a,c
        jp        c,p5
        ld        d,a
        ld        a,b
        or  a,a
        jp  z,p5
        add a,l
        cp        #192
        jp        nc,p5
        ld        e,a
        call        plote
        ; xc+y, yc-x
        ld        hl,(xcyc+1)
p5:        ld        a,c
    or  a,a
    jp  z,p6
        add        a,h
        jr        c,p6
        ld        d,a
        ld        a,l
        sub a,b
        jr        c,p6
        ld        e,a
        call        plote
        ; xc-y, yc-x
        ld        hl,(xcyc+1)
p6:        ld        a,h
        sub        a,c
        jr        c,p7
        ld        d,a
        ld        a,l
        sub        a,b
        jr        c,p7
        ld        e,a
        call        plote
        ; xc-y, yc+x
        ld        hl,(xcyc+1)
p7:        ld        a,h
        sub        a,c
        ret        c
        ld        d,a
        ld        a,b
        or  a,a
        ret z
        add        a,l
        ret        c
        ld        e,a
        call        plote
        ret
plote:  ; (C)SATSOFT, Body #07.
        push        bc
;    LD        D,10        ;КООРДИНАТА Х
;        LD        E,11        ;КООРДИНАТА Y
        LD        A,#0xAF        ;РАСЧЕТ АДРЕСА ПО КООРДИНАТАМ
        SUB        E
        jp        c,exit
        LD        E,A
        AND        A
        RRA
        SCF
        RRA
        AND        A
        RRA
        XOR        A,E
        AND        #0xF8
        XOR        A,E
        LD        H,A
        LD        A,D
        RLCA
        RLCA
        RLCA
        XOR        A,E
        AND        #0xC7
        XOR        A,E
        RLCA
        RLCA
        LD        L,A
        LD        A,D            ;КООРДИНАТА Х
        AND        #0x07        ;МАСКИРОВАНИЕ
        LD        B,A            ;ОСТАТОК ОТ ДЕЛЕНИЯ Х НА 8
        INC        B            ;+1
        LD        A,#0xFE        ;ВВЕЛИ БАЙТ 11111110
PLOOP:
    RRCA                ;ВРАЩЕНИЕ N+1 РАЗ
        DJNZ        PLOOP
        LD        B,#0xFF        ;ИНВЕРСИЯ,ЧТОБЫ ПЕЧАТЬ ТОЧКИ БЫЛА ЧЕРНЫМ
        XOR        A,B            ;ПО БЕЛОМУ
        LD        B,A            ;ЗАПОМНИЛИ В РЕГИСТРЕ 'B'
        LD        A,(HL)        ;В 'А' ГРУЗИМ ЗНАЧЕНИЕ ИЗ ЭКРАНА
        OR        A,B            ;ВКЛЮЧЕМ ТРЕБУЕМЫЙ БИТ
        LD        (HL),A        ;ГРУЗИМ В ЭКРАН ПОЛУЧЕННЫЙ РЕЗУЛЬТАТ
exit:
    pop bc
        RET                ;ВЫХОД ИЗ ПРОЦЕДУРЫ        :)

__endasm;
}

---

Как всё-таки можно зафиксить "библейский" алгоритм рисования окружности под OVER 1 ? (см. первый пост темы).

Скрытый текст

Код:

---

;--------------------------------------------------
;9. Окружность, на входе в HL,127+87*256 (x=127, y=87)
;--------------------------------------------------

CIRCLE  LD HL,127+87*256        ;(x=127, y=87)
        LD D,50                  ;r=50
        LD C,0: LD B,D
LOOP    CALL DOT                            ;sector 1
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 4
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 5
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 8
        LD A,C: LD C,B: LD B,A: CALL DOT    ;sector 3
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 6
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 7
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 8
        LD A,C: LD C,B: LD B,A
        INC C
        LD A,D: SUB C: LD D,A: JR NC,LOOP
        DEC B
        LD A,D: ADD A,B: LD D,A
        LD A,B: CP C: JR NC,LOOP
        RET

DOT    PUSH HL: PUSH DE: PUSH BC
        LD A,H: ADD A,B: LD B,A
        LD A,L: ADD A,C: LD C,A
        CALL #22e5
        POP bc: POP DE: POP HL
        RET

---

[свернуть]

Я протестировал его с фиксом, предложенным Destr, - запоминать координаты предыдущей точки и если текущие совпадают с ними, то не рисовать.

Код:

---

DOT    PUSH HL: PUSH DE: PUSH BC
        LD A,H: ADD A,B: LD B,A
        LD A,L: ADD A,C: LD C,A
WRAP ; fixed for OVER 1 by Destr
        LD HL,#ffff: LD (WRAP+1),BC
        AND A: SBC HL,BC: CALL NZ,#22e5
        POP bc: POP DE: POP HL
        RET

---

Не получается. Причина - некоторые (но не все) точки по одним координатам рисуются не подряд.

Зафиксить бы, братцы, - уж больно процедурка хороша. Компактная такая.

у тебя есть два варианта рисования точек в круге.

1ый когда количество точек четное
2ой когда оно нечетное
в варианте с четным количеством все будет ОК
в варианте с нечетным последняя точка будет рисоваться 2 раза.

Oleg N. Cher, Тупо сделал заплатку.

Код:

---

;--------------------------------------------------
;9. Окружность, на входе в HL,127+87*256 (x=127, y=87)
;--------------------------------------------------

CIRCLE  LD HL,127+87*256        ;(x=127, y=87)
        LD D,56                  ;r=50
        LD C,D: LD B,0
        CALL DOT
        LD A,C: NEG: LD C,A: CALL DOT
        LD B,C: LD C,0
        CALL DOT
        LD A,B: NEG: LD B,A: CALL DOT
        jr DLOOP
LOOP    CALL DOT                            ;sector 1
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 4
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 5
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 8
HLOOP
        LD A,C: LD C,B: LD B,A: CALL DOT    ;sector 3
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 6
        LD A,B: NEG: LD B,A: CALL DOT        ;sector 7
        LD A,C: NEG: LD C,A: CALL DOT        ;sector 8
        LD A,C: LD C,B: LD B,A
DLOOP
        INC C
        LD A,D: SUB C: LD D,A: JR NC,LOOP
        DEC B
        LD A,D: ADD A,B: LD D,A
        LD A,C: CP B: JR C,LOOP
        JP Z,HLOOP
        RET

DOT    PUSH HL: PUSH DE: PUSH BC
        LD A,H: ADD A,B: LD B,A
        LD A,L: ADD A,C: LD C,A
        CALL #22e5
        POP bc: POP DE: POP HL
        RET

---

---------- Post added at 23:18 ---------- Previous post was at 23:13 ----------

JP Z,HLOOP можно поменять на JR Z,HLOOP
jr DLOOP можно убрать.( тупо отрисуются лишние 8 точек, зато экономия байтов :) )
Это по вкусу.