Saboteur 2 Remake

Версия 128К. Раз в trdos варианте картинки не было, то я и тут не вставил. Если надо, то могу добавить. Игра сделана моноблоком. Особенность оного в +3дос состоит в том, что файл нельзя переименовывать. (хотя, в приципе, можно добавить в файлик несколько байт, что бы это можно было бы делать). Блоки кодов все пакованные и слиты в 1 файл. В образе выложенном присутствует boot который поддерживает "длинные имена". Если эти самые длинные имена используются, то появляется файл catfile. Иначе говоря, в этом самом образе файл самой игры это sab2.bas и ещё 2 файла относятся к буту.

Сорри, написал просьбу сделать +3-версию и свалил в отпуск в царства Природы и Бахуса. Во вложении не-debug-версия, код boot.a80 и сборщика ниже. Желательно релизить на WoS эту версию с загрузчиком по мотивам моего загрузчика.

Boot.a80

Код:

---

        MODULE Boot

CLEAR = #fd
NUMBER = #0e
RANDOMIZE = #f9
USR = #c0
REM = #ea
ENTER = #0d
TR_DOS = #3d13


        MACRO FINDFILE FileName, Loader_TRDSEC, Loader_LEN
        ld de,FileName
        call FindFile
        set 2,l
        ld a,(hl)
        ld (Loader_LEN),a
        inc hl
        ld e,(hl)
        inc hl
        ld d,(hl)
        ld (Loader_TRDSEC),de
        ENDM


BasicStart:

Line1:
        db #00, #01
        dw Line1End - Line1Start
Line1Start:
        db CLEAR, "0", NUMBER, #00, #00: dw #5fff: db #00, ":", RANDOMIZE, USR, "0", NUMBER, #00, #00: dw BootCode: db #00, ":", REM
BootCode:
        xor a
        ld (#8800),a
        out (#0fe),a
        ld hl,#4000
        ld de,#4001
        ld bc,#1800
        ld (hl),l
        ldir
        ld (hl),#08
        ld bc,#2ff
        ldir
        ld hl,#8000
        ld de,#0000
        ld bc,#0805
        call TR_DOS

        IFDEF IncludePicture
        FINDFILE SCRFileName, SCR_TRKSEC, SCR_LEN
        ENDIF
        FINDFILE Page5FileName, Page5_TRKSEC, Page5_LEN
        FINDFILE CodeFileName, Code_TRKSEC, Code_LEN
        FINDFILE Page1FileName, Page1_TRKSEC, Page1_LEN
        FINDFILE Page3FileName, Page3_TRKSEC, Page3_LEN
        FINDFILE Page4FileName, Page4_TRKSEC, Page4_LEN

        IFDEF IncludePicture
SCR_TRKSEC = $ + 1       
        ld de,#0000
SCR_LEN = $ + 2
        ld bc,#0005
        ld hl,#4000
        call TR_DOS
        ENDIF

Page5_TRKSEC = $ + 1
        ld de,#0000
Page5_LEN = $ + 2
        ld bc,#0005
        ld hl,#6000
        call TR_DOS

Code_TRKSEC = $ + 1
        ld de,#0000
Code_LEN = $ + 2
        ld bc,#0005
        ld hl,EntryPoint
        call TR_DOS

        di
        ld bc,#7ffd
        ld a,#11
        out (c),a
Page1_TRKSEC = $ + 1
        ld de,#0000
Page1_LEN = $ + 2
        ld bc,#0005
        ld hl,#c000
        call TR_DOS
       
        di
        ld bc,#7ffd
        ld a,#13
        out (c),a
Page3_TRKSEC = $ + 1
        ld de,#0000
Page3_LEN = $ + 2
        ld bc,#0005
        ld hl,#c000
        call TR_DOS

        di
        ld bc,#7ffd
        ld a,#14
        out (c),a
Page4_TRKSEC = $ + 1
        ld de,#0000
Page4_LEN = $ + 2
        ld bc,#0005
        ld hl,#c000
        call TR_DOS

        ld sp,STACK
        ei
        jp EntryPoint

SCRFileName:
        db "sab2_$  C"
Page5FileName:
        db "sab2_5  C"       
CodeFileName:
        db "sab2_0  C"       
Page1FileName:
        db "sab2_1  C"
Page3FileName:
        db "sab2_3  C"
Page4FileName:
        db "sab2_4  C"
FindFile:
        ld hl,#8000
.find_loop:
        ld a,(hl)
        and a
        jr z,.file_not_found
        ld b,#09
        push de
.check_name_loop:
        ld a,(de)
        cp (hl)
        jr nz,.next_file
        inc de
        inc hl
        djnz .check_name_loop
        pop de
        ret
.next_file:
        pop de
        ld a,l
        and #f0
        add #10
        ld l,a
        jr nc,.find_loop
        inc h
        jr .find_loop
.file_not_found:
        rst #08
        db #1a       
        db ENTER
        dw #0000
Line1End:       
       

BasicEnd:
        ENDMODULE

---

[свернуть]

Сборщик:

Saboteur2.a80

Код:

---

        DEVICE ZXSPECTRUM48

        ;DEFINE Debug

        IFDEF Debug
                DISPLAY "Debug version"
                DEFINE Sinclair2
                DEFINE InfiniteTime
                DEFINE InfiniteEnergy
                DEFINE KillByFirstHit
                DEFINE BASICFileName "boot.B"
        ELSE
                DISPLAY "Release version"
                DEFINE BASICFileName "SAB2.B"
                DEFINE IncludePicture
        ENDIF
       
        DEFINE TRDFileName "Saboteur2-128.trd"
       
        EMPTYTRD TRDFileName

        INCLUDE "Declarations\Structures.a80"
        INCLUDE "Declarations\Enums.a80"
        INCLUDE "Declarations\Consts.a80"

        ORG #5d3b
        INCLUDE "Boot.a80"
        SAVETRD TRDFileName, BASICFileName, Boot.BasicStart, Boot.BasicEnd - Boot.BasicStart


        IFDEF IncludePicture
        ORG #4000
        INCBIN "Screen.C"
        SAVETRD TRDFileName, "sab2_$.C", #4000, #1b00
        ENDIF

        ORG #6000
        MODULE Page5
        INCLUDE "Devices\Text.a80"
        INCLUDE "Game\Text.a80"
        INCLUDE "Game\Init\Init.a80"
        INCLUDE "Game\Init\MissionSettings.a80"
        INCLUDE "Game\Init\Briefing.a80"
        INCLUDE "Setup.a80"               
        ENDMODULE
        DISPLAY "Entry point at: ", EntryPoint
        DISPLAY "Stack at: ", STACK

        DISPLAY "Page 5 ends at: ", $
        SAVETRD TRDFileName, "sab2_5.C", #6000, $ - #6000

        ORG Page2Start       
        INCLUDE "Devices\MaskTable.a80"
        INCLUDE "Devices\Screen_6912.a80"
        INCLUDE "Game\Game.a80"
        INCLUDE "Devices\HID.a80"
        INCLUDE "Devices\Beeper.a80"
        DISPLAY "Page 2 Starts at: ", Page2Start
        DISPLAY "Code ends at:", $
Page0End:       

        SAVETRD TRDFileName, "sab2_0.C", EntryPoint, $ - EntryPoint

        ORG #c000
        MODULE Page1
        INCLUDE "MainMenu\MainMenu.a80"
        ENDMODULE
        DISPLAY "Page 1 ends at: ", $
Page1End:       
        SAVETRD TRDFileName, "sab2_1.C", #c000, $ - #c000

        ORG #c000
        MODULE Page3
        INCLUDE "Game\LocationBuilder\LocationBuilder.a80"
        ENDMODULE
        DISPLAY "Page 3 ends at:", $
Page3End:
        SAVETRD TRDFileName, "sab2_3.C", #c000, $ - #c000

        ORG #0c000
        MODULE Page4
        INCLUDE "Game\HeroesSprites.a80"
        ENDMODULE
        DISPLAY "Page 4 ends at: ", $
Page4End:
        SAVETRD TRDFileName, "sab2_4.C", #c000, $ - #c000

        DISPLAY "Page 5 free space: ", Page5.Setup.Show - #6000
        DISPLAY "Page 0 free space: ", #10000 - Page0End
        DISPLAY "Page 1 free space: ", #10000 - Page1End
        DISPLAY "Page 3 free space: ", #10000 - Page3End
        DISPLAY "Page 4 free space: ", #10000 - Page4End

---

[свернуть]

PS Output компиляции:

Скрытый текст

Код:

---

SjASMPlus Z80 Cross-Assembler v1.07 RC8 (build 06-11-2008)
Pass 1 complete (0 errors)
Pass 2 complete (0 errors)
> Release version
> Normal Energy
> Entry point at: 0x688E
> Stack at: 0x81FF
> Page 5 ends at: 0x7371
> Controls: AZNM[SP]
> Normal Time
> Random kill of guard
> Page 2 Starts at: 0x9500
> Code ends at:0xD664
> Page 1 ends at: 0xD527
> Page 3 ends at:0xEA23
> Page 4 ends at: 0xCDBF
> Page 5 free space: 0x088E
> Page 0 free space: 0x299C
> Page 1 free space: 0x2AD9
> Page 3 free space: 0x15DD
> Page 4 free space: 0x3241
Pass 3 complete
Errors: 0, warnings: 0, compiled: 13932 lines, work time: 0.078 seconds
[Finished in 0.2s]

---

[свернуть]

Цитата:

---

Сообщение от Alex Rider

Сорри, написал просьбу сделать +3-версию и свалил в отпуск в царства Природы и Бахуса. Во вложении не-debug-версия, код boot.a80 и сборщика ниже. Желательно релизить на WoS эту версию с загрузчиком по мотивам моего загрузчика

---

Как вы и просили. Версия 128К под +3DOS. С картинкой. Вставил ещё паузу 10с для лицезрения оной после загрузки. Если хотим запуска ранее - жмём любую клавишу. (Если задержка не нравится, могу убрать).

Господи, запустил для сравнения оригинальную версию — чуть не помер. КАК я играл в эту тормозную жуть?

Отличная версия, спасибо!

Моя пара предложений:

1) В оригинальной игре есть очень неприятный глюк (фича?) опроса клавиатуры: например, чтобы стоя спиной к врагу, развернуться и ударить, нужно практически ПО-ОЧЕРЕДИ нажать «назад», а потом «удар». Что, конечно, ни в какие ворота.

Предложение: исправить это так, чтобы можно было жать «назад+удар» одновременно и героиня сразу поворачивалась и била? А то это караул какой-то.

2) Может, в главном меню по-умолчанию всё-таки оставить клавиатуру, а не Sinclair 2. Здорово, кстати, что поставили его вместо никому не нужного Protek.

Прошу прощения
128 версия
делаю редефайн
устанавливаю клавиатуру
после старта игры работает только выстрел на пробел
кнопки движения не работают
ЧЯДНТ?

Цитата:

---

Сообщение от jerri

кнопки движения не работают

---

Не работает redefine, т.е. клавиши в режиме keyboard остаются теми же что и были

Цитата:

---

Сообщение от Vadim

Не работает redefine, т.е. клавиши в режиме keyboard остаются теми же что и были

---

а почему?

Цитата:

---

Сообщение от jerri

а почему?

---

У Alex Rider надо спрашивать. Я лишь подтвердил, что не работает и заметил, что старые кнопки, которые были сразу заданы работают. Видимо редифайн пишется в буфер и потом он забыл скопировать в массив с рабочими кодами.

Цитата:

---

Сообщение от Vadim

Как вы и просили. Версия 128К под +3DOS. С картинкой. Вставил ещё паузу 10с для лицезрения оной после загрузки. Если хотим запуска ранее - жмём любую клавишу. (Если задержка не нравится, могу убрать).

---

Vadim, спасибо! Выйду из отпуска - положу на WoS.

---------- Post added at 19:50 ---------- Previous post was at 19:25 ----------

Цитата:

---

Сообщение от michellekg

В оригинальной игре есть очень неприятный глюк (фича?) опроса клавиатуры: например, чтобы стоя спиной к врагу, развернуться и ударить, нужно практически ПО-ОЧЕРЕДИ нажать «назад», а потом «удар». Что, конечно, ни в какие ворота.

---

Это точно "By design", не баг. Надо сильно подумать как сделать, сходу в существующем коде решение не придумывается. И да, надо тогда так же обрататывать "вниз" + "назад" + "огонь" и "вверх" + "назад" + "огонь". Маловероятно сделать как ты хочешь. В любом случае, раньше следующей недели не займусь.

Цитата:

---

Сообщение от Vadim

Я лишь подтвердил, что не работает и заметил, что старые кнопки, которые были сразу заданы работают. Видимо редифайн пишется в буфер и потом он забыл скопировать в массив с рабочими кодами.

---

Спасибо за багу, посмотрю. Там был рефакторинг, потом откат. Должно писаться сразу куда надо, а вот куда оно пишется и что при этом ломает - вопрос.

Цитата:

---

Сообщение от michellekg

Может, в главном меню по-умолчанию всё-таки оставить клавиатуру, а не Sinclair 2.

---

В версии из этого поста должна быть клава по дефолту. На Sinclair 2 мне проще отлаживаться.