Программирование на ассемблере

Цитата:

---

Сообщение от Improver

Если глянуть исходники МДОС Т-72, то там палитру тоже устанавливали за два раза, но между ними была небольшая задержка:

Код:

---

        ...
L_F613:        OUT    00Ch        ; палитра -- установка физического цвета
        PUSH PSW
        POP  PSW
        PUSH PSW
        POP  PSW
        DCR  E
        DCR  D                ; (счётчик -1)
        OUT    00Ch        ; палитра -- установка физического цвета, ещё раз
        ...

---

Думаю, такой вариант можно считать оптимальным и по скорости, и по объёму.

Все ПЗУ на Векторах, как правило, имели при запуске команду отключения КД. Кроме того, квази-диск отключает БЛК-СБР -- там это сделано аппаратно, таким образом, если демку будут запускать, например, загрузкой "с ленты", или из загрузочной записи дискеты, то можно этот момент пропустить, а если из под МДОСа -- то эти команды обязательны.

---

Спасибо за этот сниппет. Очень класный.
Вот мой вариант который может тищить данные с квазидиска и сетить палитру без отключения прерываний. За основу был взят приведенный тобой код.

Код:

---

; Set palette copied from the ram-disk no blocking interruptions
; input:
; de - the addr of the first item in the palette
; use:
; hl, bc, a
PALETTE_COLORS = 16

SetPaletteFromRamDisk:
                        hlt
                        ; store sp
                        lxi h, $0000
                        dad sp
                        shld @restoreSp+1
                        ; copy unpacked data into the ram_disk
                        xchg
                        RAM_DISK_ON()
                        sphl

                        mvi        a, PORT0_OUT_OUT
                        out        0
                        mvi e, $00
@loop:               
                        pop b
                        ; even color
                        mov        a, e
                        out        2
                        mov a, c
                        out $0c
                        xthl ; delay 24
                        xthl ; delay 24
                        inr e ; counter plus delay 8
                        inr h ; delay 8
                        dcr h ; delay 8
                        out $0c
                        ; odd color
                        mov        a, e
                        out        2
                        mov a, b
                        out $0c
                        xthl ; delay 24
                        xthl ; delay 24
                        inr e ; counter plus delay 8
                        inr h ; delay 8
                        dcr h ; delay 8               
                        out $0c
                        mov a, e
                        cpi PALETTE_COLORS
                        jnz        @loop

@restoreSp: lxi sp, TEMP_ADDR
                        RAM_DISK_OFF()
                        ret
                        .closelabels

; mount the ram-disk
.macro RAM_DISK_ON(_command = RAM_DISK0_B0_STACK)
                        mvi a, _command
                        out $10
.endmacro

; dismount the ram-disk
.macro RAM_DISK_OFF()
                        xra a
                        out $10
.endmacro

---

Какие алгоритмы в реальности используются, для вывода на экран спрайта (многоцветного) с маской?
Или сначала в буфере создается микс (фона и спрайта), который потом просто копируется на экран?
Тогда интересует алгоритм создания микса.
Я таким ни когда не занимался, прикинул, цикл получился (если правильно посчитал) 112 тактов на байт :(

Скрытый текст

Код:

---

...
adr:
  ldax  b
  ana  m
  xchg
  ora m
  xchg
  mov  m,a
  inx h
  inx d
  inx b
adr_a:
  mvi a,8
  dcr a
  sta adr_a+1
  jnz adr
...

---

[свернуть]

Вывод в одну плоскость что-то вроде

с использованием стека

Код:

---

;SP - маска, байт спрайта, маска, байт спрайта, ...
;HL - VRAM
                pop b\ mov a,m\ ana c\ ora b\ mov m,a\ dcr l
;12+8+4+4+8+8=44 такта/байт

---

[свернуть]

без стека

Код:

---

;HL - маска, байт спрайта, маска, байт спрайта, ...
;DE - VRAM
                ldax d\ ana m\ inx h\ ora m\ inx h\ stax d\ dcr e
;8+8+8+8+8+8+8=56 тактов/байт

---

[свернуть]

Вместо dcr l и dcr e могут быть другие dcr или inr, смотря как выводим. Если две плоскости, то просто используем оставшуюся регистровую пару (DE или BC соответственно). Для 3-4 плоскостей придется добавлять переходы.

Цитата:

---

Сообщение от ivagor

Вывод в одну плоскость что-то вроде
...
Для 3-4 плоскостей придется добавлять переходы.

---

Ясно, спасибо.
Я посчитал, что хранить маску в спрайте слишком накладно по расходу памяти.
Для спрайта на 3-4 плоскости, при отдельном хранении маски, спрайт будет занимать меньше памяти, но получилось, что выводится такой спрайт практически в 2-3 медленнее.

Не все так плохо.

По битпланам без стека

Код:

---

;HL - маска
;DE - спрайт
;BC - VRAM
                ldax b\ ana m\ inx h\ xchg\ ora m\ inx h\ xchg\ stax b\ dcr c
;8+8+8+4+8+8+4+8+8=64 такта/байт

---

[свернуть]

После каждого битплана отматываем маску на начало.
Или

В два битплана стеком

Код:

---

;SP - маска, байт спрайта, байт спрайта, маска, байт спрайта, байт спрайта, ...
;HL и DE - VRAM
;начало
                pop b\ mov a,m\ ana c\ ora b\ mov m,a\ dcr l
                ldax d\ ana c\ pop b\ ora c\ stax d\ dcr e
;установившийся режим
                dcx sp\ pop b\ mov a,m\ ana c\ ora b\ mov m,a\ dcr l
                ldax d\ ana c\ pop b\ ora c\ stax d\ dcr e
;(12+12+8+4+4+8+8)+(8+4+12+4+8+8)=100 тактов/2 байта=50 тактов/байт

---

[свернуть]

Цитата:

---

Сообщение от ivagor

Не все так плохо.
...

---

Во, я ещё и растактовку смотрел в таблице, в которой:

Цитата:

---

ANA M 12 4 4 4

---

Цитата:

---

Сообщение от ivagor

Не все так плохо.

По битпланам без стека

Код:

---

;HL - маска
;DE - спрайт
;BC - VRAM
                ldax b\ ana m\ inx h\ xchg\ ora m\ inx h\ xchg\ stax b\ dcr c
;8+8+8+4+8+8+4+8+8=64 такта/байт

---

[свернуть]

После каждого битплана отматываем маску на начало.

---

Получается, для одного битплана можно хранить парами байт пиксели+маска, и обойтись без двух xchg = 56 тактов.

Цитата:

---

Сообщение от nzeemin

и обойтись без двух xchg = 56 тактов

---

Такой вариант я раньше привел

У двухбитпланового стекового варианта есть серьезный недостаток - несовместимость с методом Медноногова, нельзя использовать при разрешенных прерываниях. Исправление этого недостатка + небольшое ускорение:

Скрытый текст

Код:

---

;SP - маска, байт спрайта, байт спрайта, маска, байт спрайта, байт спрайта, ...
;HL и DE - VRAM
                pop b\ mov a,m\ ana c\ ora b\ mov m,a\ dcr l
                ldax d\ ana c\ pop b\ ora c\ stax d\ dcr e
;12+8+4+4+8+8+8+4+12+4+8+8=88 тактов
                mov a,b\ sta $+10\ ana m\ pop b\ ora c\ mov m,a\ dcr l
                ldax d\ ani 0\ ora b\ stax d\ dcr e
;8+16+8+12+4+8+8+8+8+4+8+8=100 тактов
;(88+100)/4=47 тактов/байт

---

[свернуть]

ivagor, пора книгу писать с фрагментами программ для вектора. Ну или в вики хотя бы выписывать - был бы отличный справочник, меньше затыков при разработке под Вектор.

Можно вот тут например собирать: http://www.emuverse.ru/wiki/%D0%9A%D...D1%80-06%D0%A6