Вопрос по опросу клавиатуры!

я использую такой рандомизатор:

Код:

---

rnd:      ld a,(rnd_data_e - 1)
          ld hl,rnd_data

          dup rnd_data_e - rnd_data - 1
          add a,(hl)
          ld (hl),a
          inc hl
          edup

          add a,(hl)
          ld (hl),a
          ret

rnd_data: db "HBF^db"
rnd_data_e:

---

от длины и "рандомности" строки в rnd_data зависит рандомность генератора.
чем длинее строка - тем рандомнее числа, но тем медленней работает.
4-8 символов обычно хватает для любых случаев.

чтоб в заданных пределах, то это уже сложней.
если надо от N до N+(2^x)-1, то можно так:

например если надо от 30 до 61, то пойдёт такой метод:

and 31
add a,30

если в совсем любых пределах, то без умножения не получится.

Цитата:

---

Сообщение от Sinus

на 2:

Код:

---

and a
rra

---

на 4:

Код:

---

and a
rra
and a
rra

---

на 8:

Код:

---

rrca
rrca
rrca
and %00011111

---

---

Может я в асме ничо не соображаю, но вроде команду SRL никто в проце не отменял

SRL A ;делим на 2
SRL A ;на 4
SRL A ;на 8

Цитата:

---

Сообщение от savelij

Может я в асме ничо не соображаю, но вроде команду SRL никто в проце не отменял

SRL A ;делим на 2
SRL A ;на 4
SRL A ;на 8

---

хороший вопрос.
дело в том, что разницы никакой (только srl флаг C не трогает):

and a: rra - 2 байта, 8 тактов
srl a - 2 байта, 8 тактов

более того:

srl a: srl a: srl a - 6 байт, 24 такта
rrca: rrca: rrca: and %00011111 - 5 байт, 19 тактов

надо делить на 4 так: rrca:rrca:and %00111111 - 4 байта, 11 тактов при безваите

rrca:rrca:and %00111111 - таки 15 тактов, а не 11
(хотя всё равно выгоднее чем "srl a:srl a" или "and a:rra:and a:rra" - и то и другое по 16 тактов).

АААААА! вот это меня плющит:)))))
первоначально хотел написать 7 тактов:)))
и ведь точно знаю, и считал ведь именно так: 4+4+7, но получилось 11... :)))))

Код:

---

;A=range - число будет в границах от 0 до range-1
Random
        push af
        call rand_
        pop af
        ld c,a
        ld b,0
        ex de,hl
        call mod
        ld a,l
        ret

rand_
        LD      D,0
        LD      BC,(rnd)
        LD      H,C
        LD      L,#FD
        LD      A,B
        OR      A
        SBC    HL,BC
        SBC    A,D
        SBC    HL,BC
        SBC    A,D
        LD      E,A
        SBC    HL,DE
        JR      NC,r1
        INC    HL
r1        LD      (rnd),HL
        RET
rnd        DW      0
       
mod        LD      A,16
        LD      HL,0
m0        RL      E
        RL      D
        RL      L
        RL      H
        SBC    HL,BC
        JR      NC,m1
        ADD    HL,BC
m1        CCF
        DEC    A
        JR      NZ,m0
        RET

---