ЭТЮДЫ

Цитата:

---

Сообщение от Vladson

Ещё небольшой апдейт, в последней строчке лучше юзать не "x<y" a "x<=y" (иначе в некоторых случаях будет одного пикселя не хватать)

---

А в режиме OVER 1, и так и так пикселя не хватать будет. :)
Хотя, конечно, в режиме OVER 0, незакрашенную окружность можно и 8-иточечно в одном цикле.

---------- Post added at 20:47 ---------- Previous post was at 20:45 ----------

Я-же не придираюсь, я пытаюсь дать объяснение, зачем нужно два цикла, и только.

Цитата:

---

Сообщение от Reobne

я пытаюсь дать объяснение, зачем нужно два цикла, и только.

---

наверное, можно обойтись и двумя циклами, хотя будет очень медленно.
по идее x^2+y^2=r^2.

Цитата:

---

Сообщение от Reobne

А в режиме OVER 1

---

Это также можно исправить проще и без второго цикла, либо без видимой потери качества либо даже совсем без оной, но вот в тонкостях не докопался пока.

По поводу вчерашнего вопроса о делении - у меня так ничего и не вышло.

в архиве 049.rar - оригинал с пейси, снапшот для TS-Conf, часть кода не моя, я просто использовал как основу.
может, есть идеи по ускорению?

Немного из раскопок на дисках:

Код:

---

;╔════════════════════════════════════════════════════════════╗
;║ ОТВЕТ НА ЗАДАЧУ ГН. КОЛОТОВА.                              ║▒
;║ ПРОЦЕДУРА ПЕЧАТИ СИМВОЛА АТРИБУТАМИ НА ЭКРАНЕ.            ║▒
;║                                                            ║▒
;║ CODING BY CARDINAL/PGC/BD.    DATA: 31.12.1999г.          ║▒
;╚════════════════════════════════════════════════════════════╝▒
; ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒

        ORG        #6000
        LD        A,127        ;СИМВОЛ
        LD        C,#38        ;ЦВЕТ

;---------------------------------------------------------------
SYM    ADD        A,A        ;40 БАЙТОВ, РЕКОРД!!!
        LD        L,A
        LD        H,15
        ADD        HL,HL
        ADD        HL,HL
        LD        DE,#5800
L1      LD        B,3
L2      PUSH        BC
        LD        A,(HL)
        LD        B,8
L3      RLA       
        PUSH        AF
        SBC        A,A
        AND        C
        LD        (DE),A
        INC        DE
        LD        (DE),A
        INC        DE
        LD        (DE),A
        INC        DE
        LD        (DE),A
        INC        DE
        POP        AF
        DJNZ        L3
        POP        BC
        DJNZ        L2
        INC        L
        LD        A,L
        AND        7
        JR        NZ,L1
        RET       
;---------------------------------------------------------------

---

Заодно найдены две процедурки форматирования..

Цитата:

---

Сообщение от denpopov

ОТВЕТ НА ЗАДАЧУ ГН. КОЛОТОВА. ║▒
;║ ПРОЦЕДУРА ПЕЧАТИ СИМВОЛА АТРИБУТАМИ НА ЭКРАНЕ.

---

А кто-нибудь пробовал эту процедуру запустить? :)

Цитата:

---

Сообщение от Destr

А кто-нибудь пробовал эту процедуру запустить

---

с дополненым кодом я пробовал, мелкие буквы как-то криво печатаются.

Цитата:

---

Сообщение от Destr

А кто-нибудь пробовал эту процедуру запустить? :)

---

Разве глючная?

Получил письмо на электромыло :)

Процедура рисует букву атрибутами на ВЕСЬ (32*24) экран.

Цитата:

---

hi,

"ГН. КОЛОТОВ" негодуэ и шлет более короткий вариант

успехов,
SerzhSoft.

;
;fullscreen (32x24) symbol (c) SerzhSoft
;A=symbol, C=color, 36 bytes
;

Код:

---

add a,a
ld l,a
ld h,#0f
add hl,hl
add hl,hl
ld de,#5800
lpp4
ld b,#03
lpp3
push hl
ld h,(hl)
lpp2
add hl,hl
sbc a,a
and c
ld l,#04
lpp1
ld (de),a
inc de
dec l
jr nz,lpp1
ld a,e
and #1f
jr nz,lpp2
pop hl
djnz lpp3
inc l
or e
jr nz,lpp4
ret

---

---

Автор всё ещё негодуэ...

Код:

---

;
;fullscreen (32x24) symbol (c) SerzhSoft
;A=symbol, C=color, 33 bytes
;
 add a,a
 ld l,a
 ld h,#0f
 add hl,hl
 add hl,hl
 ld de,#5800
lps2
 ld a,(hl)
 ld b,#18
lps1
 rlca
 push af
 sbc a,a
 and c
 ld (de),a
 inc de
 ld (de),a
 inc de
 ld (de),a
 inc de
 ld (de),a
 inc de
 pop af
 djnz lps1
 inc l
 ld a,e
 or a
 jr nz,lps2
 ret

---