Написание программ для БК0010

[nzeemin]

Для комплекта ещё - вариант из Stop the Express для MS-0515.
Но на самом деле тут в конце приписан ещё лишний нолик, потому что выводятся заработанные очки.
Точку входа Z34420 можно использовать для печати 3-значного числа.

; Подпрограмма: Печать 5-значного десятичного числа; R3=число
Z34400: MOV	#023420, R2		; 10000.
Z34404: CALL	Z34454			;
Z34410: MOV	#001750, R2		; 1000.
Z34414: CALL	Z34454			;
Z34420: MOV	#000144, R2		; 100.
Z34424: CALL	Z34454			;
Z34430: MOV	#000012, R2		; 10.
Z34434: CALL	Z34454			;
Z34440: ADD	#000060, R3		; '0'
Z34444: MOVB	R3, (R1)+		;
Z34446: MOVB	#000060, (R1)+		;
Z34452: RETURN				;
Z34454: MOV	#000060, R0		; '0'
Z34460: SUB	R2, R3			;
Z34462: BLO	Z34470			;
Z34464: INC    	R0			;
Z34466: BR     	Z34460			;
Z34470: ADD	R2, R3			;
Z34472: MOVB	R0, (R1)+		; копируем в экран план
Z34474: RETURN

[Advertiser]

[Manwe]

Для комплекта ещё - вариант из Stop the Express для MS-0515.

Вариант из Stop the Express занимает 31 слово (в десятичной системе счисления).
Я делал быстрый (без CALLов) вариант со степенями 10. Из полезного: не печатает лидирующие нули, добавляет в конец символ конца строки.
Размер 25 слов:

; Fast DECIMAL by Manwe
; input: R0 - number
;        R1 - pointer to output text string

DECIM:	MOV #TEN,R5	; table address
1:	CMP (R5)+,R0	; skip leading zeros
	BHI 1		; branch if higher, for 16-bit not signed
	MOV -(R5),R3
	BEQ 4		; if less then 10

2:	MOV #57,R4	; 0 symbol in ASCII codepage - 1
3:	INC R4		; count digits
	SUB R3,R0
	BHIS 3		; branch if higher or same, for 16-bit not signed
	MOVB R4,(R1)+	; print R4

	ADD (R5)+,R0
	MOV (R5),R3
	BNE 2

4:	ADD #60,R0	; 0 symbol in ASCII codepage
	MOVB R0,(R1)+	; print R0
	CLRB (R1)	; write end marker of the text string
	RET

TEN:	.WORD 10000.,1000.,100.,10.,0