Написал на скорую руку тест, для проигрывания mp3 на u8.
Код:
; Тест проигрывания MP3 v0.0.1

; Port #xx04 Data Buffer (write/read)
; Port #xx05 Command/Status Register (write/read)

; Data Buffer (write/read):
;	bit 7-0	= Stores read/write data

; Command/Status Register (write):
;	bit 7	= XSC		0: активен
;	bit 6	= XDCS		0: активен
;	bit 5	= mode		0: режим SCI/SDI; 1: STREAM 32bit(левый канал + правый канал)
;	bit 4-0	= Reserved

; Command/Status Register (read):
; 	bit 7	= BUSY		1: Занято, идет передача; 0: Свободно 
; 	bit 6	= DREQ		1: Запрос новых данных; 0: Занято
;	bit 5-0	= Reserved

	ORG #8000
        DI 

; Отключение SYSTEM_AUDIO потока звука от AY, GS....

        LD A,%11000000
        OUT (#05),A

        CALL WAIT

        LD A,%01000000	; SCI
        OUT (#05),A

        LD D,#02		; Write
        CALL VS_RW
        LD D,#00		; SCL_MODE
        CALL VS_RW
        LD D,#48		; SM_LINE1 & SM_SDNEW & SM_RESET
        CALL VS_RW
        LD D,#04
        CALL VS_RW

        CALL WAIT
        CALL WAIT
        CALL WAIT

        LD A,%11000000
        OUT (#05),A

        CALL WAIT

        LD A,%00000000	; SDI
        OUT (#05),A

        LD HL,#8100             ; Адрес MP3 файла "ROCKET"
        LD BC,18252             ; Длина MP3 файла "ROCKET"
        CALL VS_STREAM          ; Проиграть

        LD BC,2048
CLS     LD D,0
        CALL VS_RW
        DEC BC
        LD A,C
        OR B
        JR NZ,CLS

        LD A,%11000000
        OUT (#05),A

        CALL WAIT

        LD A,%00000000
        OUT (#05),A


        LD HL,TABLE
        LD BC,44
        CALL VS_STREAM


; Подключить SYSTEM_AUDIO поток для вывода звука от AY, GS...
        LD A,%00100000          ; XCS=0 XDCS=0
        OUT (#05),A
        RET 

VS_STREAM
        LD D,(HL)
        CALL VS_RW              ; Передача в VS1053
        INC HL
        DEC BC
        LD A,B
        OR C
        JR NZ,VS_STREAM
        RET 

VS_RW   IN A,(#05)
        OUT (#FE),A
        RLCA 
        JR C,VS_RW
        RLCA 
        JR NC,VS_RW
        LD A,D
        OUT (#04),A

VS_RW1  IN A,(#05)
        OUT (#FE),A
        RLCA 
        JR C,VS_RW1
        RLCA 
        JR NC,VS_RW1
        IN A,(#04)
        RET 

WAIT    LD BC,0
LL0     DEC BC
        LD A,C
        OR B
        JR NZ,LL0
        RET 

; Обычный заголовок PCM с безконечной длиной для SYSTEM_AUDIO
; См. мануал VS1053b стр.51 9.6 Feeding PCM data
TABLE   DB #52,#49,#46,#46,#FF,#FF,#FF,#FF      ; REFF....
        DB #57,#41,#56,#45,#66,#6D,#74,#20      ; WAVEfmt
        DB #10
        DB #00,#00,#00,#01,#00,#02,#00

        DB #80,#BB,#00,#00                      ; 48kHz
        DB #00,#EE,#02,#00

        DB #04,#00
        DB #10,#00
        DB #64,#61,#74,#61                      ; data
        DB #FF,#FF,#FF,#FF