расскажите о PDP-11 и его софте

[form]

form, вопрос от глупца
- можно ли установить M-PLUS на ДВК 4 с 1 м памяти и с 4 терминалами
- можно ли на присоединенную корзину с процессорм вм3 и 256 м памяти и еще что либо и собрать SMP систему

Для установки нужны или стандартные устройства (с точки зрения DEC) или нужно написать драйверы ДВКшного винчестера. Дискеты для такой системы не годятся, я их просто использовал как очень простые устройства с точки зрения драйвера для проверки запуска в принципе.

Что касается SMP - тут все просто - надо с нуля создавать железо которого почти никто никогда не видел.

[Advertiser]

[bigral]

RP - неоднозначно. От точного названия меняется тип контроллера и между собой не то, что не совметимы, а вообще все разное Если назвать точный тип диска который нужен, я могу просто сделать образ с дистрибутивом.

Тут задекларированна такая поддержка винтов:
If the RK or RL disks are too small, then there is the option to configure a RH70 (for 11/70) or RH11 controller with a single RP03, RP04, RM05, RP06, or RP07 disk. The disk data for the RM or RP disk is also stored on a SD card.

Я не очень в курсе какой из этих "RP03, RP04, RM05, RP06, RP07" наиболее "стандартный" вариант шоли.

На УКНЦ ни о каком SMP даже речи не идет (равно впрочем как и об RSX-11M-PLUS - он не то, что на 16битах - он даже на 18 не работает)

Можно детальнее обьяснить почему? Как я понимаю процессор требует какой-то фичи которую трудно\невозможно прикрутить снаружи его?

И почему это RSX-11M-PLUS требует 22bit? В чем существенная разница между 16bit/18bit/22bit PDP процами? Может возможно MMU прикрутить снаружи процессора?

[form]

RH11 controller with a single RP03

)))))))))))))))))))))))))))))))))))))))))))))))))) ))

И почему это RSX-11M-PLUS требует 22bit? В чем существенная разница между 16bit/18bit/22bit PDP процами? Может возможно MMU прикрутить снаружи процессора?

Быть может разница именно в написанном?
MMU прикрутить снаружи полноценно нереально. Почему - уже говорилось в этой или в соседней теме вчера.

[bigral]

)))))))))))))))))))))))))))))))))))))))))))))))))) ))

че так весело? расскажи и я посмеюсь

Быть может разница именно в написанном?
MMU прикрутить снаружи полноценно нереально. Почему - уже говорилось в этой или в соседней теме вчера.

Ну интересуют именно детали, откуда эти дополнительные биты берутся, где они? (ну не знаю там внутри проца они или снаружи регистр задает эти дополнительные адреса и т.д.)

Наверно я чето пропустил, расскажи для тех кто в танке. Почему не реально прикрутить снаружи 22bit MMU?

[xailar]

form, неужели кроме как с винта на ДВК 4 ( проц вм3 и 1 м памяти) нельзя установить RSX- M , а если с ленты или посредством дискет

[bigral]

К стати, а где можно взять дистрибутив RSX-11M-PLUS v4.6 ?

update: сам нашел тут: ftp://ftp.trailing-edge.com/pub/rsxdists/

[bigral]

Тем кто очень хочет НО не знает с чего начать знакомство с PDP-11 и его софтом советую начинать с вот этого документа для полных ламеров: http://www.bitsavers.org/pdf/dec/pdp...PLUS_Sep87.pdf

на всякий случай пару команд:

>login
Account or name: user
Password: user
или
Account or name: system
Password: system

>help

[bigral]

Спустя десятилетия bsd 2.11 снова в сети!!! И не с софт-эмулятора, а с реального железа, подробности тут - http://pdp2011.sytse.net/wordpress/

а сам сервак тут - http://pdp11.sytse.net/

[form]

bsd 2.11 снова в сети!!!

Вот только такой системы нету
Есть 2.11BSD

Весьма похожа на современные BSD системы.
На моем 11/83 не грузится родным загрузчиком без патча #411 чтоли (с SCSI).

[Patron]

При аппаратной загрузке любого устройства PDP-11 - в память читается 1-й сектор 0-й дорожки, в R0 записывается номер привода и управление передаётся на адрес 0.

Поэтому, размер начального загрузчика ограничен 512 байтами. А так как некоторые адреса используются для векторов прерываний и не могут быть заняты - для первичного драйвера ( т.е. полноценной подпрограммы чтения носителя, вызываемой из основного кода начального загрузчика с параметрами R0 = Block, R1 = WordCount, R2 = BufAddr ) остаётся заметно меньше 512 байтов.

Задача ещё больше усложняется, когда размер сектора устройства меньше 512 байтов - тогда помимо первичного драйвера в первых словах начального загрузчика приходится иметь подпрограмму "дочитывания начального загрузчика", загружающую начальный загрузчик и первичный драйвер.

Один из наиболее сложных случаев - драйвер DX, вынужденный раскручиваться со 128 байтов, находящихся в 1-м секторе:

	.DRBOT	DX,BOOT1,READ

	. = DXBOOT+14
	.WORD	READS-DXBOOT
	.WORD	340
	.WORD	WAIT-DXBOOT
	.WORD	340

	. = DXBOOT+34		;34-52 USEABLE
BOOT1:	MOVB	UNITRD-DXBOOT(R0),RDCMD ;SET READ FUNCTION FOR CORRECT UNIT
REETRY:	MOV	@PC,SP		;INIT SP WITH NEXT INSTRUCTION
	MOV	#200,R2		;AREA TO READ IN NEXT PART OF BOOT
	CLR	R0		;SET TRACK NUMBER
	BR	B2$		;OUT OF ROOM HERE, GO TO CONTINUATION

	. = DXBOOT+56
UNITRD:	.BYTE	CSGO+CSRD	;READ FROM UNIT 0, SETS WEIRD BUT OK PS
	.BYTE	CSGO+CSRD+CSUNIT	;READ FROM UNIT 1

	. = DXBOOT+70		;PAPER TAPE VECTORS
WAIT:	TST	@R4		;IS TR, ERR, DONE UP? INT ENB CAN'T BE
	BEQ	WAIT		;LOOP TILL SOMETHING
	BMI	REETRY		;START AGAIN IF ERROR
RTIRET:	RTI			;RETURN

	. = DXBOOT+120
READS:	MOV	(PC)+,R4		;R4 -> RX STATUS REGISTER
BOTCSR:	 .WORD	DX$CSR
	MOV	R4,R5		;R5 WILL POINT TO RX DATA BUFFER
	MOV	(PC)+,(R5)+	;INITIATE READ FUNCTION
RDCMD:	.WORD	0		;GETS FILLED WITH READ COMMAND
	IOT			;CALL WAIT SUBROUTINE
	MOV	R3,@R5		;LOAD SECTOR NUMBER INTO RXDB
	IOT			;CALL WAIT SUBROUTINE
	MOV	R0,@R5		;LOAD TRACK NUMBER INTO RXDB
	IOT			;CALL WAIT SUBROUTINE
	MOV	#CSGO+CSEBUF,@R4	;LOAD EMPTY BUFFER FUNCTION INTO RXCS
BROFFS	=	READF-.		;USE FOR COMPUTING BR OFFSET
RDX:	IOT			;CALL WAIT SUBROUTINE
	TSTB	@R4		;IS TRANSFER READY UP?
	BPL	RTIRET		;BRANCH IF NOT, SECTOR MUST BE LOADED
	MOVB	@R5,(R2)+	;MOVE DATA BYTE TO MEMORY
	DEC	R1		;CHECK BYTE COUNT
	BGT	RDX		;LOOP AS LONG AS WORD COUNT NOT UP
	CLR	R2		;KLUDGE TO SLUFF BUFFER IF SHORT WD CNT
	BR	RDX		;LOOP

B2$:	MOV	SP,R1		;SET TO BIG WORD COUNT
	INC	R0		;SET TO ABSOLUTE TRACK 1
	MOV	@PC,R3		;ABSOLUTE SECTOR 3 FOR NEXT PART
				.ASSUME BPT EQ 3
	BPT			;CALL READS SUBROUTINE
;SECTOR 2 OF RX BOOT
BOOT2:	CMPB	(R3)+,(R3)+	;BUMP TO SECTOR 5
	BPT			;CALL READS SUBROUTINE
	CMPB	(R3)+,(R3)+	;BUMP TO SECTOR 7
	BPT			;CALL READS SUBROUTINE
	BIT	#CSUNIT,RDCMD	;CHECK UNIT ID
	BNE	BOOT		;BRANCH IF BOOTING UNIT 1, R0=1
	CLR	R0		;SET TO UNIT 0
	BR	BOOT		;NOW WE ARE READY TO DO THE REAL BOOT

READ:	MOV	(PC)+,@(PC)+	;MODIFY READ ROUTINE
	 .WORD	167
	 .WORD	RDX-DXBOOT
	MOV	(PC)+,@(PC)+
	 .WORD	READF-RDX-4
	 .WORD	RDX-DXBOOT+2
	MOV	#READ1-DXBOOT,@#B$READ ;CALLS TO B$READ WILL GO TO READ1
	MOV	#TRWAIT-DXBOOT,@#20 ;LETS HANDLE ERRORS DIFFERENTLY
	CLR	@#JSW		;CLEAR JSW SINCE THE DX BOOT IN SYSCOM AREA
	TST	HRDBOT		;DID WE REACH HERE VIA A HARDWARE BOOT?
	BEQ	READ1		;YES, DON'T SET UP UNIT NUMBER
	MOV	@#B$DEVU,R3	;NO, SET UP UNIT NUMBER
	MOVB	UNITRD-DXBOOT(R3),RDCMD ;STORE UNIT NUMBER
READ1:	ASL	R0		;CONVERT BLOCK TO LOGICAL SECTOR
	ASL	R0		;LSN=BLOCK*4
	ASL	R1		;MAKE WORD COUNT BYTE COUNT
1$:	MOV	R0,-(SP)		;SAVE LSN FOR LATER
	MOV	R0,R3		;WE NEED 2 COPIES OF LSN FOR MAPPER
	MOV	R0,R4
	CLR	R0		;INIT FOR TRACK QUOTIENT
	BR	3$		;JUMP INTO DIVIDE LOOP

2$:	SUB	#23.,R3		;PERFORM MAGIC TRACK DISPLACEMENT
3$:	INC	R0		;BUMP QUOTIENT, STARTS AT TRACK 1
	SUB	#26.,R4		;TRACK=INTEGER(LSN/26)
	BPL	2$		;LOOP - R4=REM(LSN/26)-26
	CMP	#-14.,R4		;SET C IF SECTOR MAPS TO 1-13
	ROL	R3		;PERFORM 2:1 INTERLEAVE
4$:	SUB	#26.,R3		;ADJUST SECTOR INTO RANGE -1,-26
	BPL	4$		;(DIVIDE FOR REMAINDER ONLY)
	ADD	#27.,R3		;NOW PUT SECTOR INTO RANGE 1-26
	BPT			;CALL READS SUBROUTINE
	MOV	(SP)+,R0		;GET THE LSN AGAIN
	INC	R0		;SET UP FOR NEXT LSN
	TST	R1		;WHATS LEFT IN THE WORD COUNT
	BGT	1$		;BRANCH TO TRANSFER ANOTHER SECTOR
	RETURN

READF:	TST	@R4		;ERROR, DONE, OR TR UP?
	BEQ	READF		;BR IF NOT
	BMI	BIOERR		;BR IF ERROR
	TSTB	@R4		;TR OR DONE?
	BPL	READFX		;BR IF DONE
	MOVB	@R5,(R2)+	;MOVE DATA BYTE TO MEMORY
	DEC	R1		;CHECK BYTE COUNT
	BGT	READF		;LOOP IF MORE
	MOV	#1,R2		;SLUFF BUFFER IF SHORT WD CNT
				;DON'T DESTROY LOC 0
	BR	READF		;LOOP

TRWAIT:	TST	@R4		;ERROR, DONE, OR TR UP?
	BMI	BIOERR		;HARD HALT ON ERROR
	BEQ	TRWAIT		;BR IF NOT
READFX:	RTI

	. = DXBOOT+606
BOOT:	MOV	#10000,SP	;SET STACK POINTER
	MOV	R0,-(SP)		;SAVE THE UNIT NUMBER
	MOV	#2,R0		;READ IN SECOND PART OF BOOT
	MOV	#<4*400>,R1	;EVERY BLOCK BUT THE ONE WE ARE IN
	MOV	#1000,R2		;INTO LOCATION 1000
	CLR	(PC)+		;CLEAR TO SHOW HARDWARE BOOT
HRDBOT:	 .WORD	1		;INITIALLY SET TO 1
	CALL	READ		;GO READ IT IN
	MOV	#READ1-DXBOOT,@#B$READ ;STORE START LOCATION FOR READ ROUTINE
	MOV	#B$DNAM,@#B$DEVN ;STORE RAD50 DEVICE NAME
	MOV	(SP)+,@#B$DEVU	;STORE THE UNIT NUMBER
	JMP	@#B$BOOT		;START SECONDARY BOOT

	.DREND	DX

Последние из 128 байтов "предзагрузчика" DX позволяют оценить, на какие ухищрения пришлось идти разработчикам для сокращения объёма кода:

B2$:	MOV	SP,R1		;SET TO BIG WORD COUNT
	INC	R0		;SET TO ABSOLUTE TRACK 1
	MOV	@PC,R3		;ABSOLUTE SECTOR 3 FOR NEXT PART
				.ASSUME BPT EQ 3
	BPT			;CALL READS SUBROUTINE