ДВК (и всё, что с ними связано)

[form]

А это часом не слишком большая дырка в системе? Таким образом любая задача получает режим KERNEL?

XM/ZM и не планировались как защищенные системы. В сстемах где реально нужна защита никто не допустит программу до векторов или PSW.

- - - Добавлено - - -

XM/ZM и не планировались как защищенные системы.

Впрочем виртуальные программы там более-менее защищены - прямого доступа к регистрам-векторам нет. Но непрямой опять таки есть. И также содержимое PSW в XM/ZM позволяет виртуальным программам выходить за рамки через MxPI/MxPD (кроме программ VBGEXE).

[Korchagin]

TPARK.MAC
.TITLE PARK2016.MAC
.MCALL .PRINT, .EXIT, .MTPS, .TRPSET ;используемые вызовы библиотеки

STARTF:
.TRPSET #AREA, #CNTRLRNOTFOUND ; переназначить 4 и 10 вектора на наш
обработчик на случай отсутствия регистра 174000 на шине
CMP @#174000, #401 ;сравнить содержимое регистра идентификации 174000 с
кодом 401(восьмеричное)
BNE CNTRLRNOTFOUND ;контроллер не обнаружен, выходим
10$: BIT #100000, @#174020 ;проверка занятости
BEQ 10$ ;занят, ждем
BIS #8., @#174020 ;начальная установка с выводом головок на нулевой трек
20$: BIT #100000, @#174020
BEQ 20$ ;занят, ждем
30$: BIT #1, @#174020
BNE 30$ ;ждем, пока операция не будет завершена
MOV LANDZONE, @#174012 ;поместить в регистр адреса цилиндра 174012
номер цилиндра для парковки
MOV #7, @#174006 ;сектор 7 (любой до 16)
MOV #0, @#174014 ;поверхность 0 (любая из доступных, 0 и 1 точно есть у
каждого диска)
MOV #40, @#174016 ;команда чтения сектора
.PRINT #SHUTDOWNMSG
.MTPS #340
BR .

CNTRLRNOTFOUND:
.PRINT #NOTFOUNDMSG
.EXIT

NOTFOUNDMSG: .ASCIZ /MFM CONTROLLER NOT FOUND/
SHUTDOWNMSG: .ASCIZ /TURN THE POWER OFF/
LANDZONE: .WORD 1230 ;664 цилиндр у моего HDD парковочный, на
других хдд он другой
AREA: .WORD 0, 0

.END STARTF

Так переназначать 4 и 10 вектора?
Сомневаюсь в .TRPSET #AREA, #0 ;восстановить оригинальные обработчики 4 и 10 векторов.

[form]

Сомневаюсь в .TRPSET #AREA, #0 ;восстановить оригинальные обработчики 4 и 10 векторов.

Не требуется - установка делается для задачи и после выхода ее теряется.

- - - Добавлено - - -

CHECK1: BIT #100000, @#174020 ;проверка занятости
BEQ CHECK1 ;занят, ждем

TST @#174020
BPL .-4

Ну и в таких незначимых местах лучше ставить локальные метки 1$, 2$, 10$, 20$ итд

- - - Добавлено - - -

Так переназначать 4 и 10 вектора?

Так. В данном случае не требуется особых разбирательств - все-равно единственная реакция - выход.

[Korchagin]

{здесь был ошибочный вариант}

[form]

MOV VECTORPART1, @#0 ;сохраняем нулевой вектор прерываний
MOV VECTORPART2, @#2
MOV #ZEROHANDLER, @#0 ; в книге Фрэнка так
TRAP 0 ;вызываем нулевой вектор прерываний

У команды TRAP (независимо от аргумента) вектор 34, а не 0
И сохранять-восстанавливать ничего не нужно...

А если в какой-то книге так - это печально... Ибо такой порядок аргументов (первые две команды) используется у интела, но не в MACRO-11

[Korchagin]

А как же хандлер к трапу 0 привязать?(((
Системный обработчик Трапа 0 ведь уже содержит в себе HALT? Тогда и дергаться не надо ни с какими своими обработчиками.

[Advertiser]

[form]

А как же хандлер к трапу 0 привязать?(((

TRAP имеет вектор 34. Независимо от аргумента. Аргумент является частью кода команды и может быть проанализирован обработчиком прерывания, и это все касаемо циферки. То есть будь то TRAP 0 или TRAP 377, а вектор всегда будет 34. Ну и инициализировать его лучше сразу на этапе сборки программы через .ASECT (пример как это делается писал выше).

Системный обработчик Трапа 0 ведь уже содержит в себе HALT?

Система никак не обрабатывает команду TRAP. Если же речь идет об адресах 0-2, то там для обычных программ записана очистка R0 и .EXIT, а для виртуальных - очистка R0 и .ASTX, но это никак не относится к делу

[Korchagin]

Буду разбираться тогда с ASECT

[form]

Буду разбираться тогда с ASECT

Там все просто: после директивы .ASECT адресация абсолютна, все .=xxx (без этого будет 0) именно это и означают - после этого адрес будет именно xxx. В нашем случае интересен .=34... После того как все абсолютно-адресные действия выполнены пишем .PSECT и после этого как обычно пишем программу. Для данного конкретного случая этого достаточно
В примере выше я также показывал как запретить запуск программы под VBGEXE (полезно для XM/ZM - ибо если прога будет выполняться под VBGEXE - она просто не сможет обратиться к регистрам устройств, а залезет в некую память вместо них).

[Korchagin]

Там все просто: после директивы .ASECT адресация абсолютна, все .=xxx (без этого будет 0) именно это и означают - после этого адрес будет именно xxx. В нашем случае интересен .=34... После того как все абсолютно-адресные действия выполнены пишем .PSECT и после этого как обычно пишем программу. Для данного конкретного случая этого достаточно
В примере выше я также показывал как запретить запуск программы под VBGEXE (полезно для XM/ZM - ибо если прога будет выполняться под VBGEXE - она просто не сможет обратиться к регистрам устройств, а залезет в некую память вместо них).

Понял, разбираюсь.

- - - Добавлено - - -

В процессе поиска дополнительной информации наткнулся на книжку "для самых маленьких" http://ideafix.name/wp-content/uploa...ff/book106.pdf. Теперь то я окончательно понял, почему PDP-11 была столь популярна в научных и промышленных кругах.

- - - Добавлено - - -

TPARK.MAC
.TITLE PARK2016.MAC
.MCALL .PRINT, .EXIT, .MTPS, .TRPSET ;используемые вызовы библиотеки

$JSX =: 4 ;EXTENDED JOB STATUS WORD
NOVBG$ =: 100 ;DISABLE VBGEXE BIT
$JSW =: 44 ;JOB STATUS WORD
TTSPC$ =: 10000 ;SPECIAL MODE TERMINAL BIT
TCBIT$ =: 100 ;INHIBIT TERMINAL WAIT BIT
$SYPTR =: 54 ;POINTER TO RMON
$CNFG1 =: 300 ;SYSTEM CONFIG WORD
FJOB$ =: 200 ;FOREGROUND LOADED BIT
$SYSGE =: 372 ;SYSGEN FEATURE WORD
RTEM$ =: 10 ;RTEM-11 SYSTEM

.ASECT
.=$JSX
.WORD NOVBG$ ;DISABLE VBGEXE
.=$JSW
.WORD TTSPC$!TCBIT$ ;SET TERMINAL MODE
.=034
.WORD TRAPZEROHANDLER ;адрес нового обработчика
.WORD 340 ;уровень привилегий 7
.PSECT

STARTF:
MOV @#$SYPTR,R0 ;R0 -> RMON
BIT #RTEM$,$SYSGE(R0) ;RTEM-11?
BNE 1$ ;YES, EXIT
TSTB $CNFG1(R0) ;FOREGROUND LOADED?
BPL 5$ ;IF PL NO, OK
.PRINT #FLOAD ;FOREGROUND LOADED ERROR
1$: .EXIT ;EXIT
5$: .TRPSET #AREA, #CNTRLRNOTFOUND ; переназначить 4 и 10 вектора на наш
обработчик на случай отсутствия регистра 174000 на шине
CMP @#174000, #401 ;сравнить содержимое регистра идентификации 174000 с
кодом 401(восьмеричное)
BNE CNTRLRNOTFOUND ;контроллер не обнаружен, выходим
10$: BIT #100000, @#174020 ;проверка занятости
BEQ 10$ ;занят, ждем
BIS #8., @#174020 ;начальная установка с выводом головок на нулевой трек
20$: BIT #100000, @#174020
BEQ 20$ ;занят, ждем
30$: BIT #1, @#174020
BNE 30$ ;ждем, пока операция не будет завершена
MOV LANDZONE, @#174012 ;поместить в регистр адреса цилиндра 174012
номер цилиндра для парковки
MOV #7, @#174006 ;сектор 7 (любой до 16)
MOV #0, @#174014 ;поверхность 0 (любая из доступных, 0 и 1 точно есть у
каждого диска)
MOV #40, @#174016 ;команда чтения сектора
.PRINT #SHUTDOWNMSG ;сообщение об отключении питания
INC @#PASSWORD ;введем пароль на разрешение останова
TRAP 0 ;трапнем для перехода в режим ядра и исполнения HALT

CNTRLRNOTFOUND:
.PRINT #NOTFOUNDMSG ;сообщение об отсутствии контроллера на шине
.EXIT

TRAPZEROHANDLER: ;обработчик трапа 0 и всех других номеров трапов - прерывание
перехвачено
BIT #1, @#PASSWORD ;вызов из нашей программы?
BNE 100$ ;нет, выходим
HALT ;останов машины
100$: RTI

FLOAD: ASCIZ /FOREGROUND TASK LOADED, DO NOT OFF THE POWER/
NOTFOUNDMSG: .ASCIZ /MFM CONTROLLER NOT FOUND/
SHUTDOWNMSG: .ASCIZ /TURN THE POWER OFF/
LANDZONE: .WORD 1230 ;664 цилиндр у моего HDD парковочный, на
других хдд он другой
AREA: .WORD 0, 0 ; или AREA: .BLKW 2 - параметры для EMT трапсета
PASSWORD: .WORD 0 ;для проверки права на останов
.END STARTF

Будет ли работать такой Франкенштейн?