Цифровая археология: 1801 и все-все-все

[Alex_K]

Откуда на ДВК адрес больше 0160000 ? Теневое ПЗУ у 1201.02 располагается по адресам 0140000-0157776, а в странице ввода-вывода лежит теневое ОЗУ. Или у FIS-программы в этом теневом ОЗУ лежит стек? Зачем? FIS ведь работает с реальным стеком...

Эмулятор FIS в прошивке -055 копируется из теневого ПЗУ в теневое ОЗУ по адресу 0171000. Если команда FIS была вызвана с разрешенными прерываниями, то и эмулятор FIS их также разрешает. Соответственно при любом прерывании в происходит переход из режима HALT в режим USER и в стек ложится PC и PSW прерванного эмулятора. Соответственно адрес возврата больше 0171000 и в сохраненном PSW установлен восьмой бит. Адрес больший 0160000 нужен, чтобы по RTI возвратится обратно в режим HALT. Так что используется стек прерванной программы, сам эмулятор FIS стека не использует.

[Advertiser]

[AFZ]

Адрес больший 0160000 нужен, чтобы по RTI возвратится обратно в режим HALT.

Зачем? Разве 8-го бита PSW недостаточно? Ведь ходит же способ запустить свою программу в HALT-mode (Полетаев в свое время выдал), она же точно в основном ОЗУ располагается, не в теневом.

[Alex_K]

Зачем? Разве 8-го бита PSW недостаточно? Ведь ходит же способ запустить свою программу в HALT-mode (Полетаев в свое время выдал), она же точно в основном ОЗУ располагается, не в теневом.

Для возврата из USER в HALT по RTI нужен не только установленный 8-й бит в сохраненном PSW, но и адрес возврата должен быть большим или равным 0160000.
С методом Полетаева знаком. По его методу программа перекачивается в теневое ОЗУ, там же и исполняется. А используется для этого выполнение команды FIS. Эмулятор FIS сохраняет в буфере регистры с R0 по R6, адрес буфера 0173002. Это и используется - программа перекачки располагается в регистрах с R0 по R5, делается левый FADD, а далее переходим на начало буфера через RTI, потом докачиваем, что надо.
Собственно его программа:

    Программа, скачивающая в основное ОЗУ содержимое ОЗУ HALT-режима в плате набазе 1801ВМ2.

        .TITLE  VM2
; команды 1801ВМ2
GO      =: 12   ; G
STEP    =: 16   ; P
RSEL    =: 20   ; R0:=SEL
MFUS    =: 21   ; R0:=(R5)+
RCPC    =: 22   ; R0:=CPC
RCPS    =: 24   ; R0:=CPS
MTUS    =: 31   ; -(R5):=R0
WCPC    =: 32   ; CPC:=R0
WCPS    =: 34   ; CPS:=R0
START::
        MOV     #PROG,R5
        MOV     (R5)+,R0
        MOV     (R5)+,R1
        MOV     (R5)+,R2
        MOV     (R5)+,R3
        MOV     (R5)+,R4
        MOV     (R5)+,R5
        CLR     -(SP)
        CLR     -(SP)
        CLR     -(SP)
        CLR     -(SP)
        FADD    SP
        CMP     (SP)+,(SP)+
        MOV     #740,-(SP)
        MOV     #173002,R1
        MOV     R1,-(SP)
        MOV     #PROG,R5
        MOV     #PLEN,R2
        RTI
PROG:   MFUS
        MOV     R0,(R1)+
        SOB     R2,PROG
        MOV     #160000,R1
        MOV     #10000,R2
        MOV     #10000+20000,R5
10$:    MOV     -(R1),R0
        MTUS
        SOB     R2,10$
        MOV     #NEXT,R0
        WCPC
        CLR     R0
        WCPS
        STEP
PLEN=.-PROG/2
NEXT:   HALT
        EMT     350
        .END    START

[Hunta]

Собственно его программа

Занимательно

- - - Добавлено - - -

Но при условии, что есть эмулятор FIS

- - - Добавлено - - -

И она работает так, как предполагается

[Vslav]

Для возврата из USER в HALT по RTI нужен не только установленный 8-й бит в сохраненном PSW, но и адрес возврата должен быть большим или равным 0160000.

Разве ВМ2 проверяет старшие биты адреса возврата при RTI?

[Alex_K]

Разве ВМ2 проверяет старшие биты адреса возврата при RTI?

Vslav, на вашем сайте документация по 1801ВМ2, которую когда-то выкладывал Titus. Страница 65, таблица 4.