Тема для всяких глупых вопросов

[ALKO]

Мой пример чем не люб?

Тоже съезжает вверх.

- - - Добавлено - - -

потом крайний столбец сдвинешь по вертикали и вставишь этот байт

Ибо нужно ещё ето.

- - - Добавлено - - -

[Bedazzle]

Тоже съезжает вверх.

Ну, я предупредил, что с головы пишу

Вот это проверил:

    org $8000

entry:
    ld a, 9
    ld (22528),a

    ld (22528+767),a


starter:
    halt

    ld hl, 22529-1
    ld de, 22528-1

    ld a, 24
scroll:
    inc hl   ; можно заменить на inc l
    inc de
    ex af, af'
    ld a, (de)

    DUP 31
        ldi
    EDUP

    ld (de), a

    ex af, af'
    dec a

    jp nz, scroll

    jp starter

    ret

[M80]

А так?

Так да. Быстрее этого вряд ли получится.)

[jerri]

Тоже съезжает вверх.

- - - Добавлено - - -


Ибо нужно ещё ето.

- - - Добавлено - - -

dup 31
ldi
edup
ld (de),a
inc hl inc de

[Oleg N. Cher]

jerri, удали EmuZWin.exe.manifest, тогда кнопки будут отображаться в винде 10 нормально.

[Bedazzle]

jerri, удали EmuZWin.exe.manifest

Скорее ALKO

- - - Добавлено - - -

Так да. Быстрее этого вряд ли получится.)

Ну разве что совсем чуточку, и освободим альт рег А:

    org $8000

entry:
    ld a, 9
    ld (22528),a
    ld (22528+767),a


starter:
    halt

    ld hl, 22529
    ld de, 22528

scroll:
    ld a, (de)

    DUP 31
        ldi
    EDUP

    ld (de), a

    inc l
    inc de

    ld a, $5B
    cp d
    jp nz, scroll

    jp starter

    ret

[M80]

Ну разве что совсем чуточку...

Ха! Всегда есть место для совершенства!) +

[ALKO]

Bedazzle, спасибо, пашет.
Но я пока не уверен, как там ляжет условие в конце, где ld a, $5B.
У меня буфер 40х24, так что 960 на 256 делится с остатком, и в один байт не укладывается.

[Bedazzle]

Но я пока не уверен, как там ляжет условие в конце, где ld a, $5B.
У меня буфер 40х24, так что 960 на 256 делится с остатком, и в один байт не укладывается.

Ну, тогда можно вернуться к версии с AF'

[Dart Alver]

Но я пока не уверен, как там ляжет условие в конце, где ld a, $5B.
У меня буфер 40х24, так что 960 на 256 делится с остатком, и в один байт не укладывается.

А прокручивать ты весь буфер будешь, или только видимую часть ? Насколько помню ты буфер вроде мутил тупо чтоб спрайты обрезать ))

    ; ...
    
     ld de,Boofer
     ld hl,Boofer+1
     ld bc,24*31    ; 24*(размер прокручиваемой зоны-1: т.е. количество LDI ),
                    ; т.е. 24*31 для видимой части, 24*39 для всего буфера
     
loop
     ld a,(de)

     DUP 31  ; если прокручивается только видимая часть или 'DUP 39' , если весь буфер
       ldi
     EDUP
     
     ld (de),a
     
     DUP 9  ; если крутится видимая часть или убрать обёртку 'DUP/EDUP' вокруг инков, если весь буфер
       inс hl
       inc de
     EDUP
     
      ld a,b
      or c
     jp nz,loop
     
    ; ...

- - - Добавлено - - -

Пожалуй если прокручивается видимая часть буфера, то лучше пожалуй заменить

     DUP 9 
       inс hl  ; 6
       inc de  ; 6
     EDUP      ; (6+6)*9 = 108 тактов , 18 байт

на :

      push bc     ; 11
      ld bc,9     ; 10
      add hl,bc   ; 11
      ex de,hl    ; 4
      add hl,bc   ; 11
      ex de,hl    ; 4
      pop bc      ; 10  = 61 такт , 9 байт
             ;

- - - Добавлено - - -

Да так, как флаг p/v кроме ldi никакая команда здесь не меняет,
то можно

      ld a,b
      or c
     jp nz,loop

заменить всего лишь на

    jp pe,loop