Вопрос по ассемблеру Z80

[0xDEAD]

Так ещё можно:

        ld de, 1000       ; будем делать 1000 итераций
	
	ld b,e            ; подготовка регистров
	dec de            ; подготовка регистров
	inc d             ; подготовка регистров
	ld hl,0           ; после выполнения цикла, в hl должно быть значение 1000
Loop:
	inc hl
 	djnz Loop
	dec d
	jp nz,Loop

О, вот тебе и раз - опоздал. Ну и ладно.

[Zidane]

В общем решил так:

LD BC,nn ;количество итераций, 2 байта
LD HL,nn ;число с которым выполняются операции
LOOP
LD A,n ;константа в регистр
; Код программы
DEC BC
LD A,B
OR C
JR NZ,LOOP

Если использовать CP C, то выполняется почему то 253 итерации. И все. А вот с OR пошло как надо. Всем спасибо )

[reddie]

А еще можно так =)) при условии, что итераций меньше 32768

LD DE,NN
....
DEC DE
BIT 7,D
JR Z,REPEAT

значение флага будет равно значению бита, т.е. когда бит 7=0 (число>=0 но меньше 32768) - сработает переход по Z
ну и счетчик надо заранее уменьшать на 1, поскольку при нулевом значении DE цикл все еще будет крутиться

сли использовать CP C, то выполняется почему то 253 итерации

да, нужно использовать именно OR - нулевой результат будет тогда, когда оба регистра равны нулю

[Bedazzle]

В общем решил так:

LD BC,nn ;количество итераций, 2 байта
LD HL,nn ;число с которым выполняются операции
LOOP
LD A,n ;константа в регистр
; Код программы
DEC BC
LD A,B
OR C
JR NZ,LOOP

Если использовать CP C, то выполняется почему то 253 итерации. И все. А вот с OR пошло как надо. Всем спасибо )

LD A,n не имеет смысла, т.к. чуть ниже идёт LD A,B

Ну и попробуем сравнить:

   ld bc, 1000
loop:
   dec bc         ; 6t
   ld a,b           ; 4t
   or c             ; 4t
   jr nz, loop    ; 12t
                      ; итого 26 тактов

или так

   ld bc, 1000
loop:
   djnz loop    ; 13/8t
   dec c           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 29 тактов (чуть меньше, т.к. последний виток быстрее переход)

или так

   ld bc, 1000
loop:
   dec c           ; 4t
   jr nz, loop    ; 12/7t
   dec b           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 32 такта (чуть меньше, т.к. последний виток быстрее переход)

и предложенное выше

   ld de, 1000
loop:
   dec de         ; 6t
   bit 7,d         ; 8t
   jr z, loop     ; 12t
                      ; итого 26 тактов

Первый вариант быстрее, и чуть короче, но использует регистр А.
Третий вариант медленнее второго, но зато не привязан к B, можно использовать два любых регистра.
Четвёртый не привязан к А, но имеет ограничение на 32765 значений.
Что лучше - выбирать нужно по конкретной задаче.

[Reobne]

   ld bc, 1000
loop:
   djnz loop    ; 13/8t
   dec c           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 29 тактов (чуть меньше, т.к. последний виток быстрее переход)

На самом деле 13+11/256. Потому что 255 из 256 раз djnz цикл заворачивает с затратой 13 тактов, и лишь один раз из 256 до jr дело доходит

ld bc, 1000
loop:
   dec c           ; 4t
   jr nz, loop    ; 12/7t
   dec b           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 32 такта (чуть меньше, т.к. последний виток быстрее переход)

Аналогично 16+11/256

[Bedazzle]

На самом деле 13+11/256. Потому что 255 из 256 раз djnz цикл заворачивает с затратой 13 тактов, и лишь один раз из 256 до jr дело доходит

Аналогично 16+11/256

Это если мы знаем, что у нас 1000 циклов, а если будет 50 или 100, то получится иная раскладка.

[Advertiser]

[Zidane]

LD A,n не имеет смысла, т.к. чуть ниже идёт LD A,B

Очень даже имеет, так как в начале программы используется константа которая не меняется. Собственно в моей программе туда грузим вполне себе конкретный байт цветности, а потом выгружаем его в ячейку памяти. Вообще, поскольку константа не меняется, можно было бы её напрямую грузить в вычисляемую ячейку памяти, но программа была уже написана и работала, так что... )

Но все равно благодарен всем присутствующим за помощь. Она потом используется. Возможно даже по назначению. Только OBS Надо настроить нормально, а то в последний раз кошмар что было. Но удалять уже жаль.

[Dart Alver]

или так

Код:

   ld bc, 1000
loop:
   djnz loop    ; 13/8t
   dec c           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 29 тактов (чуть меньше, т.к. последний виток быстрее переход)

Пример немного с ошибкой по числу итераций - нужно LD CB,1000 [+256] а не LD BC,1000 .
Ну а поскольку такой команды нет , то надо выкручиваться вручную или макросом )))
И учитываем что если младьший байт числа итераций не 0 , то старший нужно увеличить на 1

[Reobne]

а если будет 50

Ну да, я в среднем и приблизительно написал. Если мы знаем сколько конкретно циклов будет, то можем конкретно посчитать такты.

   ld bc, 1000
loop:
   djnz loop    ; 13/8t
   dec c           ; 4t
   jr nz, loop    ; 12/7t
                      ; итого 29 тактов (чуть меньше, т.к. последний виток быстрее переход)

Например 50 циклов. Считаем. 49 раз djnz завернёт за 13 тактов. Плюс один раз djnz 8t, dec 4t и jr 7t.
49*13+8+4+7=50*13-13+8+4+7=650+6=656
За цикл будет 656/50=1312/100=13,12
Всё равно 13 с мелочью. Но не 29.

[Bedazzle]

Ну да, я в среднем и приблизительно написал. Если мы знаем сколько конкретно циклов будет, то можем конкретно посчитать такты.

Согласен.
Кстати, если заменить JR на JP, можно ещё ускорить.

- - - Добавлено - - -

Пример немного с ошибкой по числу итераций

Да, правильно подмечено.