Ретро-ЯП Millfork для Atari, Apple II, ZX Spectrum, MSX, CP/M, NES, Game Boy и MS-DOS

[breeze]

Однако здравствуйте. Я понимаю, что яп ещё «в разработке», но то, что в макрос нельзя передать указатель на array, ну такоэ:

import stdio

array hello_world = "Hello ATARI!"

macro void print(array s) {
	putstr(s, s.length)
}

void main() {
	print(hello_world)

}

ERROR: Type `array` is not defined

Замечательно, судя по документации, в качестве аргумента может быть только 1 байт? o_O

macro void inc(byte b) {
    b += 1
}

Ясно, чуть выше нашел:

cannot contain variable or array declarations

[Shiny]

stdio не понимает претензий

[breeze]

stdio не понимает претензий

Я нашел откуда «ноги» названиям растут При желании можно наклепать свои вариации
Там вообще ооочень интересная ситуация с синтаксисом (по крайней мере в функциях), прям питоном повяло, когда оно начало ругаться, что не может скомпилировать потому что отступы нарушены XD

Я тут набросал вариант с инклудом для спрайтов. но был немного неприятно удивлён, что вертикальное позиционирование спрайта это ещё тот гемор >_< я даж так и не понял как его менять нужно, на DLI что ли?
Так же (если я правильно понял) ширина спрайта всегда 16 пикселей (x2), максимум что можно ещё ещё зажЫрнить (x4 и x8).

Ну и зато теперь стало ясно как раскрашивают спрайтами картинки, когда оно на тексте ползает видно как его цвет меняется:



Сырки:

import stdio
import sprites

array hello_world = "Hello ATARI!"

array(byte) sprite0 = [
	%00000000,
	%00111100,
	%01000010,
	%10000001,
	%10100101,
	%10000001,
	%10000001,
	%10000001,
	%10100101,
	%10011001,
	%10000001,
	%01000010,
	%00111100,
	%00000000
]

noinline asm void wait(byte register(a) f) {
  clc
  adc os_RTCLOK.b2
  .rt_check:
  cmp os_RTCLOK.b2
  bne .rt_check
  rts
}

void main() {
    putstr(hello_world, hello_world.length)
    new_line()
    putstrz("Hello world again"z)

    sprCreate(sprite0, sprite0.length, $CF)

    byte i 
    for i,48,to,200 {
	sprPos(i, 0)
	wait(1)
    }
}

const byte pmgmem=$80 //pmgmem*256 == place for sprites

void sprCreate(pointer _sprData, byte _sprSize, byte _sprColor) {
	pointer pmg0
	ubyte i
	poke($D407,pmgmem)//PMGBASE place in memory
	poke ($022F,%111110)//SDMCTL
	poke ($D01D,3)//GRACTL Enable PM display
	poke ($026F,1)//GPRIOR priority
	poke ($02C0,_sprColor)//$CF - PCOLR0 color of player 0
	poke ($D008,0)//SIZEP0 size of player 0: ;0 = normal, 1 = double, 3 = quadruple
// copy sprite data to defined place
	pmg0=word((pmgmem*256)+1024+30)
	for i,0,to,_sprSize-1 {
		pmg0[i]=_sprData[i]
	}
}

void sprPos(byte x, byte y) {
	poke ($D000,x)// $30 HPOSP0 horisontal place player 0
}

@Shiny буду признателен, если подскажешь как правильно позиционировать по вертикали


atari.zip

[Shiny]

[ @Shiny буду признателен, если подскажешь как правильно позиционировать по вертикали

Ты с приоритетом поиграл что ли?(:
Вертикальная позиция - адрес, куда ты записываешь данные

pmg0=word((pmgmem*256)+1024+30)

сменишь адрес на +31 и спрайт сместится вниз на 1 линию.

- - - Добавлено - - -

	sprPos(i, 0)
	wait(1)

лучше использовать wait() в начале, чтобы спрайт не мерцал.

[breeze]

Ты с приоритетом поиграл что ли?(:

Вроде нет.

Вертикальная позиция - адрес, куда ты записываешь данные

pmg0=word((pmgmem*256)+1024+30)

сменишь адрес на +31 и спрайт сместится вниз на 1 линию.

ооо! зер гÿт попробую.

лучше использовать wait() в начале, чтобы спрайт не мерцал.

Логично, бездумно дёрнул из чужого примера)

[Shiny]

На обычных цветах

poke ($02C0,$CA)//PCOLR0 color of player 0

нет наложений.
На atariage много чего понаписано насчет сложения цветов. Удобнее отказаться от GR.0 - в нем два playfield сразу без фона.

[andrews]

И
while true {}
в конце void main(), а то Altirr-у корежит.
А как теперь рожицу стрелками двигать по экрану?

[breeze]

На обычных цветах

poke ($02C0,$CA)//PCOLR0 color of player 0

нет наложений.
На atariage много чего понаписано насчет сложения цветов. Удобнее отказаться от GR.0 - в нем два playfield сразу без фона.

ооо! это уже интереснее



- - - Добавлено - - -

И
while true {}
в конце void main(), а то Altirr-у корежит.
А как теперь рожицу стрелками двигать по экрану?

Зачем? Оно после цикла в бейсик выходит. Если бейсика нет, вылетает в SelfTest.

Движений пока никаких нет. Это просто тест вывода спрайта.

[breeze]

Короче немного переделал вывод. Разбил на блок инициализации и блок отрисовки.
Добавил опрос джопстика и теперь рожу можно погонять по экрану.

sprites.mfk:

const byte pmgmem=$80 //pmgmem*256 == place for sprites


void sprInit() {
	poke($D407,pmgmem)//PMGBASE place in memory
	poke ($022F,%111110)//SDMCTL
	poke ($D01D,3)//GRACTL Enable PM display
	poke ($026F,1)//GPRIOR priority
	
	poke ($D008,0)//SIZEP0 size of player 0: ;0 = normal, 1 = double, 3 = quadruple
}


void sprShow(pointer _sprData, byte _sprSize, byte _sprColor, byte x, byte y) {
	pointer pmg0
	ubyte i


	poke ($02C0,_sprColor)//$CF - PCOLR0 color of player 0
	//poke ($02C0,$CA)//PCOLR0 color of player 0


	poke ($D000,x)// $30 HPOSP0 horisontal place player 0


	// copy sprite data to defined place
	pmg0=word((pmgmem*256)+1024+y)
	for i,0,to,_sprSize-1 {
		pmg0[i]=_sprData[i]
	}
}

test.mfk:

import stdio


import sprites


array hello_world = "Hello ATARI!"


array(byte) sprite0 = [
	%00000000,
	%00111100,
	%01000010,
	%10000001,
	%10100101,
	%10000001,
	%10000001,
	%10000001,
	%10100101,
	%10011001,
	%10000001,
	%01000010,
	%00111100,
	%00000000
]


noinline asm void wait(byte register(a) f) {
  clc
  adc os_RTCLOK.b2
  .rt_check:
  cmp os_RTCLOK.b2
  bne .rt_check
  rts
}


void main() {
	byte pX
	byte pY
	byte joy


	putstr(hello_world, hello_world.length)
	new_line()
	putstrz("Hello world again"z)
	new_line()
	sprInit()


//    byte i 
//    for i,48,to,200 {
//	wait(1)
//	sprCreate(sprite0, sprite0.length, $CF, i, 30)
//    }


	pX = 60
	pY = 30
	putstrz("PosX: "z)
	putword(pX)
        putstrz(" PosY: "z)
	putword(pY)
	sprShow(sprite0, sprite0.length, %11000000, pX, pY)


	while (true) {
		wait(1)
		joy = peek(632)
		if (joy == 11 || joy == 10 || joy == 9) {
			pX -= 1
		} else if (joy == 7 || joy == 6 || joy == 5) {
			pX += 1
		}
		if (joy == 14 || joy == 10 || joy == 6) {
			pY -= 1
		} else if (joy == 13 || joy == 9 || joy == 5) {
			pY += 1
		}
		if (joy != 15) {
			sprShow(sprite0, sprite0.length, %11000000, pX, pY)
		}


	}




}

[Shiny]

Любопытный подход (: Опрос джойстика можно использовать с помощью теста битов.

Кстати, тут определяется игрок 0, а всего 0-3(не считая снарядов(missile) 0-3, которые можно объединить в спрайт.