Процедура детекта TurboSound.

[Shiru]

Вот.

; TurboSound detected? Return A=0/1 (no/yes)

tsDetect
    ld hl,#fe00
    ld de,#ffbf
    ld bc,#fffd
    out (c),h
    out (c),l
    ld b,e
    out (c),c
    
    ld b,d
    out (c),b
    out (c),l
    ld b,e
    out (c),b
    
    ld b,d
    out (c),h
    out (c),l
    in a,(c)
    cp c
    jr nz,noTS
    
    out (c),d
    out (c),l
    in a,(c)
    cp e
    jr nz,noTS
    ld a,1
    ret
   	
noTS
    xor a
    ret

[Advertiser]

[Ronin]

может сначала 7й регистр заглушить ? на всякий случай. или прям на нем и тестировать (а не 0-ом).

[lvd]

может сначала 7й регистр заглушить ? на всякий случай. или прям на нем и тестировать (а не 0-ом).

Ну или можно предварительно сохранить тот регистр, на котором будем проверять наличие 2х девайсов. =)

[lvd]

Вот.
; TurboSound detected? Return A=0/1 (no/yes)

Ну можно так сделать:

1 - включить нулевой (дефолтный) девайс
2 - записать в него число1
3 - включить первый (доп.) девайс
4 - записать в него число2(!=число1)
5 - включить нулевой взад
6 - считать и вычесть число1
7 - вернуться

На выходе: ноль - 2 девайса, неноль - 1 девайс.

[Ronin]

Ну или можно предварительно сохранить тот регистр, на котором будем проверять наличие 2х девайсов. =)

это чтоб шума всякого не было.
проще #3f в 7й регистр кинуть обоим. только если #07 можно скажем в A запихать, #3F пихать некуда

На выходе: ноль - 2 девайса, неноль - 1 девайс.

а если ни одного ? то ноль вероятно.

[Shiru]

может сначала 7й регистр заглушить ? на всякий случай. или прям на нем и тестировать (а не 0-ом).

А смысл? Предполагается, что оба чипа заглушены на старте теста. Ну можно и на 7-ом - тогда первую строчку надо заменить на ld hl,#fe07

Ну можно так сделать:

Так тут практически так и сделано, только дополнительный шаг есть, чтобы при отсутствии чипов получить на выходе всё-таки 0 (нет чипов - нет и TS).

[PheeL]

Так тут практически так и сделано, только дополнительный шаг есть, чтобы при отсутствии чипов получить всё-таки 0.

Эм, а нафиг надо если всё-равно не будет слышно? Тут он чисто логически неоправдан как мне кажется. Имеется ввиду проверка на отсутствие чипов вообще.

[Shiru]

Эм, а нафиг надо если всё-равно не будет слышно? Тут он чисто логически неоправдан как мне кажется. Имеется ввиду проверка на отсутствие чипов вообще.

Да, она и имеется в виду. Код выше - что-то непонятно?

Выбираем 2-ой чип, пишем число N
Выбираем 1-ый чип, пишем число M
Выбираем 2-ой чип, читаем - если не N, чипа нет (ret 0)
Выбираем 1-ый чип, читаем - если не M, чипа нет (ret 0)
ret 1 (оба чипа есть)

[lvd]

Да, она и имеется в виду. Код выше - что-то непонятно?

Выбираем 2-ой чип, пишем число N
Выбираем 1-ый чип, пишем число M
Выбираем 2-ой чип, читаем - если не N, чипа нет (ret 0)
Выбираем 1-ый чип, читаем - если не M, чипа нет (ret 0)
ret 1 (оба чипа есть)

Гы, второй чип есть, а первого нету, надо же...

[lvd]

а если ни одного ? то ноль вероятно.

Ну тогда читай так: ноль - 2 девайса, не ноль - не два девайса. =)