Вид для печати
Отлично сделать и очень просто.Цитата:
Сообщение от Patron
Зачем? Редакторов у нас полно (в том числе с управлением 1:1 как в K52), нам важно утилитки вроде LINK, LIBR,CREF, MACRO. А если мы начнем делать эмуляторы терминала, да тогда уж и K52 выкинуть как убогий и сделать поддержку VT100 для KED итд итп - зачем тогда вообще огород городить - проще эмулятором пользоваться будет.Цитата:
Сообщение от Patron
В принципе - можно даже не морочиться с объединением EXE и DSK, а просто положить системный образ в качестве одного из файлов встроенной файловой системы EXE-файла эмулятора.
Да ни надо никаких образов. Просто эмулятор функционала RT-11. Причем половина функционала должна работать как NOP.Цитата:
Сообщение от Patron
Я сделаю вариант sav2exe, который будет максимально качественно превращать в exe любой sav-файл. Не думаю, что кто-то сделает любой другой вариант быстрее.Цитата:
Сообщение от form
А зачем любой файл превращать.Цитата:
Сообщение от Patron
Это выльется в создание еще одного варианта эмулятора который не даст никаких плюсов против уже существующих.
---------- Post added at 19:16 ---------- Previous post was at 19:15 ----------
Кроме того вариант который я описал системнонезависим.
Эмулятор всегда один - модульный API, просто у него появится ещё одна возможность.Цитата:
Сообщение от form
Вполне допускаю, что кто-то захочет реализовать и его - но это совершенно точно не я.Цитата:
Кроме того вариант который я описал системнонезависим.
Это который в РТК Микро должен был быть "транслятор графического ассемблера"?Цитата:
Сообщение от NovaStorm
Есть же порт macro11 под linux/win32?
http://www.dbit.com/pub/linux/macro11/README
http://retrocmp.com/tools/macro-11-on-windows
И там же написан большой список чего он не умеет насколько я помню :)Цитата:
Сообщение от shattered
Сам факт существования означает - что кто то очень хотел что бы было )Цитата:
Сообщение от form
А не умеет - может ещё научиться ? ) Только мне вот сложно вообразить как
это работать должно - без эмулятора процессора PDP-совместимого и чего-нибудь ещё? Без системной библиотеки и если там используются стандартные вызовы то какая версия SYSMAC ??? ) Не представляю как это работает под WIn )))
Так это вроде не секрет, что d-bit пытается сделать/собрать freeware заменители для DECовских утилит :)Цитата:
Сообщение от hobot
---------- Post added at 04:23 ---------- Previous post was at 04:20 ----------
Версия SYSMAC определяется файлом.
---------- Post added at 04:25 ---------- Previous post was at 04:23 ----------
Кстати посмотрел - с последнего раза когда я ее видел, прога многому научилась.
Так это же только кросс-ассемблер. Зачем ему эмулировать что-то?Цитата:
Сообщение от hobot
Я ничего не знаю об этом, но тем интереснее )Цитата:
Сообщение от form
Я не программист - поэтому наверное такой термин для меня не слишком явный )Цитата:
Сообщение от shattered
---------- Post added at 01:34 ---------- Previous post was at 01:30 ----------
Ну а этот кросс-ассемблер использует Макро-команды (ENABL LC,MCL ?) или только команды вроде BEQ MOV TST ? И если он использует скажем .CHAIN то что тогдаЦитата:
Сообщение от form
означает - определяется файлом? Ему надо какой-то из родных (на выбор) библиотек
подпихивать что ли? (я честно не представляю просто механизм такой). Не может же
МАКРО-11 висеть в воздухе без PDP-процессора, без системной библиотеки ?
Это не макро команды.Цитата:
Сообщение от hobot
И надо, пожалуй, затолкать эти исходники в github, для удобства разглядывания
Горе мне. - как написал однажды Patron )Цитата:
Сообщение от form
shattered, я чайник, конечно, но makefile?
Да и в нём что-то маловато описано, СС не ставится, а потом у меня вылазит куча "makefile:№№: *** missing separator. Stop."
а) Автор под win32 писал и б) это тоже допустимо
'missing separator' -- видимо, нужен GNU Make
---------- Post added at 15:14 ---------- Previous post was at 15:12 ----------
(я еще не пробовал собирать сам)
-f то я задал, пытался собрать под mingw, и make гнутый там должен быть...
А надо бы проверить, какой там make
Неужели nmake настолько криво совместим?
С небольшой правкой (stricmp -> strcasecmp) собирается и не под visual studio :-)
Почитал эту тему, столько всего полезного
шпоргалки\вопросы\ответы
а самое главное программы и исправления
(патчи). Поднимаю тему ! ) Очень информативная
и интересная! )
До кучи - может кому пригодится. Пример как делать поиск файлов в каталоге диска, используя только те средтва которые уже есть в системе. Используются функции IGTDIR и IGTENTиз системной библиотеки. Их описание можно найти на bitsavers или у меня в документации по системной библиотеке RT-11. Никаких наворотов-красивостей - только пример, рабочий :)Цитата:
Сообщение от hobot
Вызов функции IGTDIR из системмной библиотеки. Аналогичен форановскму IERR = IGTDIR(64,AREA,0,SEG,,DBLK,FILSPC). Если IERR (R0) не равен нулю - была ошибка.Код:MOV #ARGS1,R5
CALL IGTDIR
TST R0
BNE 20$
Аналогично фортрановскому IERR = IGTENT(AREA,ENTRY,,BLOCK). Если результат меньше 0, больше искать нечего. В противном случае в 7-словыный массив ENTRY получаем запись каталога о файле в стандартном RT-11 формате.Код:10$: MOV #ARGS2,R5
CALL IGTENT
TST R0
BLT 30$
Копируем данные в блок аргументов $EDMSG, печатаем, идем дальше...Код:MOV #ENTRY+2,R0
MOV #FMTARG,R1
CLR (R1)+
MOV (R0)+,(R1)+
MOV (R0)+,(R1)+
MOV (R0)+,(R1)+
CLR (R1)+
MOV (R0)+,(R1)+
MOV #BUFF,R0
MOV #FORMAT,R1
MOV #FMTARG,R2
CALL $EDMSG
CLRB @R0
.PRINT #BUFF
BR 10$
Обработка ошибок, выход.Код:20$: .PRINT #ERROR
30$: CLR R0
.EXIT
Собственно все. FILSPC содержит список файлов которые нужно искать, со всякими *, % (ну и как обычно, опущенное поле считается за *), не более 8 спецификаций через запятую. Другие подробности в RT-11 System Subroutine Library Manual. Программа для простоты использует RSXLIB, описание его здесь.Код:ARGS1: .WORD 7,SIZE,AREA,CHAN,SEG,-1,DBLK,FILSPC
SIZE: .WORD 64.
AREA: .BLKW 64.
CHAN: .WORD 0
SEG: .BLKW 512.
DBLK: .RAD50 /SY /
ARGS2: .WORD 5,AREA,ENTRY,-1,BLOCK
ENTRY: .BLKW 7
BLOCK: .BLKW
FMTARG: .BLKW 6
FORMAT: .ASCIZ /%11<%X%11>%M./
ERROR: .ASCIZ /IGTDIR FAILED/
FILSPC: .ASCIZ /.TXT,%%.SYS,UCL.*/
BUFF: .BLKB 40.
.END START
Код:.RU GTDIR
DD.SYS 5.
DU.SYS 11.
EQ.SYS 10.
LD.SYS 11.
LP.SYS 2.
LS.SYS 5.
MU.SYS 14.
NL.SYS 2.
SD.SYS 24.
SL.SYS 17.
SP.SYS 7.
VM.SYS 3.
XL.SYS 4.
UCL.SAV 16.
UCL.DAT 9.
CUSTOM.TXT 14.
V5NOTE.TXT 36.
.
Решил рассмотреть некоторые моменты для ясности. В качестве первого примера - разборки с командами SET которые прерывают обработку команды (например выполняют .CHAIN или .EXIT). На форуме уже есть несколько таких драйверов.
К примеру, драйвер поддерживает несколько команд SET (скажем [NO]OPT и VALUE) которые просто меняют какие-либо параметры драйвера и ON которая завершается по .EXIT (например для запуска системных команд). В этом случае, понятно, что команда вроде "SET XX ON,OPT" не дойдет до конца и звершится на разборе ON. Чтобы не вводить в заблуждение пользователя, будет полезно если драйвер предупредит об этом...
Данный пример при выполнении команды SET XX ON,NOOPT,VALUE=1 будет выводить предупреждениеКод:.DRSET ON,1,O.ON
;+
;ЗДЕСЬ R5 УКАЗЫВАЕТ НА СИМВОЛ КОМАНДНОЙ СТРОКИ, СЛЕДУЮЩИЙ ЗА ТЕКУЩЕЙ ОПЦИЕЙ.
;НАПРИМЕР ЕСЛИ ДЛЯ "SET XX ON,OPT" R5 УКАЗЫВАЕТ НА СИМВОЛ ",".
;СТРОКА ЗАПИСАНА В ОБРАТНОМ ПОРЯДКЕ.
;+
O.ON: TSTB -(R5) ;ПРОВЕРЯЕМ СЛЕДУЮЩИЙ СИМВОЛ
BEQ O.EXEC ;НУЛЕВОЙ БАЙТ - КОНЕЦ СТРОКИ
JSR R0,10$ ;ПЕЧАТАЕМ СООБЩЕНИЕ
.ASCII /?XX-W-ON must be last option in set command/<15><12>
.ASCIZ /?XX-W-Options ignored - /
.EVEN
;+
;В СТЕКЕ ЛЕЖИТ СОХРАНЕННОЕ СОДЕРЖИМОЕ R0. ДЛЯ ПРИЛИЧИЯ ЕГО МОЖНО
;ДОСТАТЬ, НО МОЖНО И ЗАБИТЬ - ВЕДЬ МЫ БУДЕМ ДЕЛАТЬ .EXIT
;
;ВО ВРЕМЯ ВЫПОЛНЕНИЯ КОМАНЛЫ SET В ПАМЯТЬ СЧИТЫВАЮТСЯ ДВА ПЕРВЫХ
;БЛОКА ДРАЙВЕРА. ПРИ УСПЕШНОМ ЗАВЕРШЕНИИ, МОНИТОР ЗАПИСЫВАЕТ ЭТИ ДВА
;БЛОКА ОБРАТНО В ФАЙЛ ДРАЙВЕРА. В НАШЕМ СЛУЧАЕ МЫ ЗАВЕРШАЕМ ОБРАБОТКУ
;МАКРОВЫЗОВОМ .EXIT, СООТВЕТСТВЕННО ДРАЙВЕР НЕ БУДЕТ ЗАПИСАН ОБРАТНО
;НА ДИСК И НИКТО НАМ НЕ МЕШАЕТ ИСПОЛЬЗОВАТЬ ОБЛАСТЬ ВТОРОГО БЛОКА
;В КАЧЕСТВЕ БУФЕРА.
;-
10$: .ADDR #1000,R1 ;ПОЛУЧАЕМ АДРЕС БУФЕРА
MOV R1,R3 ;СОХРАНЯЕМ ЕГО - ПРИГОДИТСЯ
20$: MOVB (R0)+,(R1)+ ;КОПИРУЕМ СООБЩЕНИЕ
BNE 20$ ;
DEC R1 ;УБИРАЕМ НУЛЕВОЙ БАЙТ
30$: MOVB -(R5),(R1)+ ;КОПИРУЕМ ОСТАТОК КОМАНДЫ SET
BNE 30$ ;
.PRINT R3 ;ПЕЧАТАЕМ СООБЩЕНИЕ
O.EXEC: ;ДЕЛАЕМ ЧТО НУЖНО
.EXIT ;ВЫХОД
Код:?XX-W-ON must be last option in set command
?XX-I-Options ignored - NOOPT,VALUE=1
---------- Post added at 22:05 ---------- Previous post was at 20:42 ----------
При написании драйвера следует помнить, что типы процессоров не ограничиваются одними ВМ1 и ВМ2. Особенно это актуально для ДВК.
Данный драйвер перехватывает прерывание 10, отлавливает команды с кодом 77 и печатает хашик.
Здесь сразу три ошибки. Для XM/ZM мониторов драйвер получит неизвестно что вместо кода команды для виртуальной программы (бит 10 в JSW установлен) или для программы, запущенной через VBGEXE. Код должен быть поправлен:Код:.DRDEF XX,333,0,0,0,0
.DRPTR FETCH=*NO*,LOAD=XXLOA,UNLOAD=XXUNL
.DRBEG XX
XXINT:: MOV @SP,-(SP) ;ПОЛУЧАЕМ ПРЕДПОЛОЖИТЕЛЬНЫЙ АДРЕС
SUB #2,@SP ;КОМАНДЫ
CMP #77,@(SP)+ ;ЕСЛИ КОД КОМАНДЫ НЕ 77
BNE 10$ ;ОТДАЕМ ПРЕРЫВАНИЕ
TSTB @#177564 ;ПЕЧАТАЕМ СИМВОЛ #
BPL .-4 ;
MOVB #'#,@#177566 ;
10$: SEC ;ВОССТАНАВЛИВАЕМ БИТ C
JMP @(PC)+ ;ОТДАЕМ В СИСТЕМУ
XXISR:: .BLKW
.DREND XX
.PSECT SETOVR
XXLOA:: MOV @R5,R5 ;ПОЛУЧАЕМ АДРЕС XXLQE
MOV @#10,XXISR-XXLQE(R5) ;СОХРАНЯЕМ СИСТЕМНЫЙ ОБРАБОТЧИК
ADD #XXINT-XXLQE,R5 ;УСТАНАВЛИВАЕМ НАШ
MOV R5,@#10 ;
RETURN ;ВОЗВРАТ
XXUNL:: MOV @R5,R5 ;ПОЛУЧАЕМ АДРЕС XXLQE
MOV XXISR-XXLQE(R5),@#10 ;ВОССТАНАВЛИВАЕМ ОБРАБОТЧИК
RETURN ;ВОЗВРАТ
.END
Вторая ошибка - тупое восстановление вектора при выгрузке драйвера. Если после нашего драйвера кто-то еще перехватил вектр 10, выгрузка может дать непредсказуемый эффект. Поэтому стоит проверить сначала можно ли делать выгрузку:Код:XXINT:: MOV @SP,-(SP)
SUB #2,@SP
.IF EQ MMG$T
CMP #77,@(SP)+
.IFF
MFPI @(SP)+
CMP #77,(SP)+
.ENDC
Третья ошибка относится к маловероятному (но вполне возможному) случаю когда между сохранением старого значения вектора и установкой нового кто-то успеет перехватить вектор. В FB/XM/ZM мониторах сиуация вполне возможная. Так что такие вещи стоит выполнять на приоритете 7 процессора.Код:XXUNL:: CLR R0 ;ПРИ ОШИБКЕ В R0 МОЖНО
;ПОМЕСТИТЬ АДРЕС СООБЩЕНИЯ
;0-НЕТ СПЕЦИАЛЬНОГО СООБЩЕНИЯ
MOV @R5,R5 ;ПОЛУЧАЕМ АДРЕС XXLQE
MOV R5,R4 ;ПОЛУЧАЕМ АДРЕС XXINT
ADD #XXINT-XXLQE,R4 ;
CMP R4,@#10 ;ПРОВЕРЯЕМ ISR
BNE 10$ ;
MOV XXISR-XXLQE(R5),@#10 ;ВОССТАНАВЛИВАЕМ
TST (PC)+ ;КУ
10$: SEC ;КЮ
RETURN ;
---------- Post added at 22:15 ---------- Previous post was at 22:05 ----------
Еще пара слов про XB/XM/ZB/ZM мониторы (а заодно и про TSX). В случае с драйвером, мы заранее знаем будет он работать в системе с MMU или без. Соответственно многое можно упростить. Например наличие MMU автоматически означает наличие EIS (можно не писать универсальные заменители MUL/DIV/SOB итд). Также наличие MMU гарантирует наличие PSW по адресу 1(77)77776. Команд же MFPS/MTPS вполне может не быть (11/34, Электроника 100/25)...
---------- Post added at 22:43 ---------- Previous post was at 22:15 ----------
Пара слов про драйверы, перехватывающие вектора 4 или 10. Если в момент входа в прерывание значение INTLVL >=0 в RMON, нет смысла что-то делать дальше - при отдаче такого прерывания в систему последовал бы ?MON-F-System halt (однако если драйвер используется чтобы сэмулировать команды процессора которые использует другой драйвер из под .DRAST...). Можно воспользоваться недокументированной фичей для такого случая (на примере прошлого драйвера):Примечание: в RT-11SJ без поддержки таймера нет INTLVL.Код:...
XXINT:: TST @(PC)+
INTLVL: .BLKW
BPL 10$
...
XXLOA:: MOV @R5,R5 ;ПОЛУЧАЕМ АДРЕС XXLQE
MOV $INPTR-XXLQE(R5),R0 ;ПОЛУЧАЕМ АДРЕС $INTEN
CMP (R0)+,(R0)+ ;ПОЛУЧАЕМ АДРЕС INTLVL
MOV R0,INTLVL-XXLQE(R5) ;СОХРАНЯЕМ В ДРАЙВЕРЕ
...
Пара слов о поддержке расширенных номеров устройств в RT-11 V5.5 и новее - вытаскивать эту инфу из документации непросто, а посему напишу здесь как все делается.Код:...
;+
;В ЭТОМ ПРИМЕРЕ ЕСЛИ В .CND ФАЙЛЕ ПРОПИСАНА ПОДДЕРЖКА РАСШИРЕННЫХ
;НОМЕРОВ УСТРОЙСТВ (0-77), МЫ ВКЛЮЧАЕМ ТАКУЮ ПОДДЕРЖКУ ДЛЯ ДРАЙВЕРА.
;ТАКАЯ ЗАВИСИМОСТЬ НЕ ЯВЛЯЕТСЯ ОБЯЗАТЕЛЬНОЙ - ДРАЙВЕР БЕЗ ПОДДЕРЖКИ
;РАСШИРЕННЫХ НОМЕРОВ МОЖЕТ РАБТАТЬ В СИСТЕМЕ С ПОДДЕРЖКОЙ И НАОБОРОТ.
;-
.IIF NDF UNI$64 UNI$64=0
;+
;ДЛЯ ПОДДЕРЖКИ РАСШИРЕННЫХ НОМЕРОВ УСТРОЙСТВ, В ДРАЙВЕРЕ ДОЛЖНО БЫТЬ
;ОПРЕДЕЛЕНО XX$N64=1 (ГДЕ XX - ИМЯ ДРАЙВЕРА).
;-
.IF NE UNI$64
XX$N64 = 1 ;ЕСТЬ ПОДДЕРЖКА
.IFF
XX$N64 = 0 ;НЕТ ПОДДЕРЖКИ
.ENDC
...
.IF NE XX$N64
;+
;В .DRDEF ДОЛЖНО БЫТЬ УКАЗАНО UNIT64=YES ДЛЯ ПОДДЕРЖКИ РАСШИРЕННЫХ
;НОМЕРОВ УСТРОЙСТВ. ПО УМОЛЧАНИЮ ОДНОБУКВЕННОЕ ИМЯ УСТРОЙСТВА СОВПАДАЕТ
;С ПЕРВОЙ БУКВОЙ ИМЕНИ. ЕСЛИ ТРЕБУЕТСЯ ДРУГАЯ БУКВА, НУЖНО
;ОПРЕДЕЛИТЬ XX$PN2=^RY (ГДЕ Y - НУЖНАЯ БУКВА).
;-
.DRDEF XX,367,FILST$!VARSZ$!SPFUN$,0,0,0,UNIT64=YES
.DRPTR FETCH=XXLOA,LOAD=XXLOA,RELEASE=XXUNL,UNLOAD=XXUNL
.IFF
.DRDEF XX,367,FILST$!VARSZ$!SPFUN$,0,0,0
.ENDC
...
MOVB Q$UNIT(R4),R1 ;ПОЛУЧАЕМ НОМЕР УСТРОЙСТВА
BIC #^C7,R1 ;УБИРАЕМ ЛИШНИЕ БИТЫ
.IF NE XX$N64
;+
;ДОПОЛНИТЕЛЬНЫЕ БИТЫ РАСШИРЕННОГО НОМЕРА УСТРОЙСТВ БЕРУТСЯ ИЗ
;Q.FUNC ЭЛЕМЕНА ОЧЕРЕДИ И ОПРЕДЕЛЯЮТСЯ ТАК:
; БИТ: 876543210
; TNNNFFFFF
;
;ЕСЛИ T=0, ЭТО READ, WRITE ИЛИ ФУНКЦИИ РАБОТЫ С ФАЙЛАМИ ДЛЯ SPECL$ УСТРОЙСТВ.
;В ЭТОМ СЛУЧАЕ NNN - СТАРШИЕ БИТЫ НОМЕРА УСТРОЙСТВА, FFFF - ФУНКЦИЯ (000-017)
;
;ЕСЛИ T=1, ЭТО SPFUN, В ЭТОМ СЛУЧАЕ NNN - НУЖНО ИНВЕРТИРОВАТЬ,
;FFFF - ФУНКЦИЯ (360-377)
;-
MOVB Q$FUNC(R4),R2 ;ПОЛУЧАЕМ СТАРШИЕ БИТЫ
BPL 10$ ;PL - OK
COM R2 ;ИНВЕРТИРУЕМ ДЛЯ SPFUN
10$: BIC #^C160,R2 ;УБИРАЕМ ЛИШНЕЕ
ASR R2 ;ДОБАВЛЯЕМ
BIS R2,R1 ;
.ENDC
...
;+
;ДЛЯ МОНИТОРА С ПОДДЕРЖКОЙ РАСШИРЕННЫХ УСТРОЙСТВ И ПРИВЯЗКИ
;УСТРОЙСТВА ТРЕБУЕТСЯ ЗАПОЛНИТЬ/ОЧИСТИТЬ НЕКОТОРЫЕ ТАБЛИЦЫ.
;-
.IF NE XX$N64
.PSECT SETOVR
$SYPTR = 54 ;УКАЗАТЕЛЬ НА RMON
$PNPTR = 404 ;АДРЕС ТАБЛИЦЫ $PNAME
$CNFG3 = 466 ;ТРЕТЬЕ СЛОВО КОНФИГУРАЦИИ СИСТЕМЫ
CF3.OW = 2000 ;В СИСТЕМЕ ЕСТЬ ТАБЛИЦА $OWNER
CF3.64 = 400 ;СИСТЕМА ПОДДЕРЖИВАЕТ РАСШИРЕННЫЕ
;НОМЕРА УСТРОЙСТВ
;+
;НА ВХОДЕ В ПОДПРОГРАММЫ ЗАГРУЗКИ/ВЫГРУЗКИ
;R2 = КОЛИЧЕСТВО СЛОТОВ ДЛЯ УСТРОЙСТВ (*2)
;R5 = УКАЗАТЕЛЬ НА $ENTRY ДРАЙВЕРА
;-
XXLOA:: CALL FIXOWN
BEQ 10$
ADD #XX$X64-XXLQE,@R1
10$: RETURN
XXUNL: CALL FIXOWN
BEQ 10$
CLR @R1
10$: RETURN
;+
;НА ВХОДЕ
;R2 = КОЛИЧЕСТВО СЛОТОВ ДЛЯ УСТРОЙСТВ (*2)
;R5 = УКАЗАТЕЛЬ НА $ENTRY ДРАЙВЕРА
;
;НА ВЫХОДЕ
;Z=1 - НИЧЕГО НЕ ТРЕБУЕТСЯ ДЕЛАТЬ
;-
FIXOWN: MOV @#$SYPTR,R1 ;ПОЛУЧАЕМ АДРЕС RMON
BIT #CF3.64,$CNFG3(R1) ;ЕСТЬ ПОДДЕРЖКА РАСШИРЕННЫХ НОМЕРОВ?
BEQ 10$ ;НЕТ
BIT #CF3.OW,$CNFG3(R1) ;ЕСТЬ ТАБЛИЦА $OWNER
BEQ 10$ ;НЕТ
MOV R2,R3
ASL R3
ASL R3
ADD R2,R3
MOV $PNPTR(R1),-(SP)
ADD R1,@SP
ADD R2,@SP
MOV R5,R1
SUB (SP)+,R1
ADD R5,R1
SUB R3,R1
CMP -(R1),-(R1)
MOV @R5,-(R1)
10$: RETURN
.ENDC
form, а какие есть варианты запуска COM файла из приложения?
через .CHAIN я понимаю - ничего не получится, надо наверное CSI команду
формировать-передавать в MON ? (возможно уже обсуждали, но я что то не нашёл, нашлась только шпора Patrona по обработке приложением входящего CSI в теме pascal/macro-11). Простой пример такой надобности -
к примеру в рамках сборника игр для эмулятора перед стартом игры - поднастроить УК-НЦ палитру или загрузить шрифт, а затем уже стартануть игру. В общем когда нужно цепочку команд выполнить, и есть ли шанс в процессе (наверное опять таки нету) избежать возможности прервать исполнение COM файла пользователем?
Запускается командой .EXIT в особом режиме. Пример есть в описании макробиблиотеки.Цитата:
Сообщение от hobot
Еще пара слов про драйверы... Фича: в инсталяционной процедуре допускается обращение к несуществующей памяти/несуществующему регистру, при этом бит C взводится в случае ошибки. Соответственно можно использовать TST для проверки наличия регистра.
Пример выполнения определенного кода при любом выходе из программы (.EXIT, CTRL/C, ?MON-F-Ошибка):Код:$E16LS ==: 316 ;СМЕЩЕНИЕ ДО ТАБЛИЦЫ EMT 340-357
$JOBNU ==: 322 ;ТЕКУЩИЙ НОМЕР ЗАДАНИЯ
E6.EXI =: 20 ;ХУК ДЛЯ .EXIT
.MCALL .PRINT ;СИСТЕМНЫЕ МАКРОСЫ
START:: MOV @#$SYPTR,R5 ;ПОЛУЧАЕМ АДРЕС RMON
ADD R5,JOBNU ;СОХРАНЯЕМ АДРЕС JOBNUM
ADD $E16LS(R5),R5 ;ПОЛУЧАЕМ АДРЕС ТАБЛИЦЫ EMT
MOV E6.EXI(R5),R0 ;ПОЛУЧАЕМ АДРЕС ПОДПРОГРАММЫ
ADD R5,R0 ;...ОБРАБОТКИ .EXIT
MOV R0,E6EXI ;СОХРАНЯЕМ
MOV #EHOOK,R0 ;УСТАНАВЛИВАЕМ ХУК
SUB R5,R0 ;...
MOV R0,E6.EXI(R5) ;...ДЛЯ .EXIT
JMP R0 ;КОМАНДА, ВЫЗЫВАЮЩАЯ ПАДЕНИЕ
EHOOK:: TST @(PC)+ ;ФОНОВОЕ ЗАДАНИЕ АКТИВНО?
JOBNU:: .WORD $JOBNU ;
BNE 10$ ;НЕТ
;+
;ЗДЕСЬ ПОМЕЩАЕМ ЛЮБОЙ КОД КОТОРЫЙ ДОЛЖЕН ВЫПОЛНЯТЬСЯ ПРИ ЛЮБОМ ВЫХОДЕ
;ИЗ ФОНОВОГО ЗАДАНИЯ. ДЛЯ .EXIT ИМЕЕТ ЗНАЧЕНИЕ РАВЕН R0 НУЛЮ ИЛИ НЕТ.
;ПОСКОЛЬКУ МЫ ЛОВИМ ТОЛЬКО СВОЙ ОСТАНОВ, ПРОСТО СЧИТАЕМ, ЧТО ЕМУ НЕ НУЖНО
;БЫТЬ РАВНЫМ НУЛЮ (НЕ ВЫПОЛНЯТЬ .HRESET ПО ВЫХОДУ).
;-
.PRINT #EXMSG ;ПЕЧАТАЕМ СООБЩЕНИЕ
MOV @#$SYPTR,R0 ;ПОЛУЧАЕМ АДРЕС RMON
ADD $E16LS(R0),R0 ;ПОЛУЧАЕМ АДРЕС ТАБЛИЦЫ EMT
MOV E6EXI,-(SP) ;УБИРАЕМ
SUB R0,@SP ;...ХУК
MOV (SP)+,E6.EXI(R0) ;...ДЛЯ .EXIT
10$: JMP @(PC)+ ;ВЫПОЛНЯЕМ .EXIT
E6EXI:: .BLKW ;
EXMSG: .ASCIZ <15><12>/*** BYE BYE ***/<15><12>
.END START
Код:.EX ATEXIT
?MON-F-Trap to 10 001042
*** BYE BYE ***
.
Мне по-другому пришлось заменить для VS2008:Цитата:
Сообщение от shattered
А так вообще MACRO11.exe собралось и работает, и походу тот же объектный файл даёт.Код:#define stricmp _stricmp
Ещё бы LINK под современную систему получить.
А можно глупый вопрос? Новые игры для УКНЦ кто-то делает сейчас или все что есть из игр это то что написано было во времена УКНЦ?
Похоже, что пока никто.Цитата:
Сообщение от DJs3000
Хотя, некоторые грозились, вплоть до SuperMario (благо, палитра позволяет).
Интересный способ применяется в ранних версиях Unix для получения указателя на структуру ( заголовок буфера ) из любого указателя на любой член структуры ( на текущую позицию в буфере ).
Для этого нужно, чтобы размер буфера и его выравнивание в памяти были кратны степени 2 ( например: буфера по 8 байтов, выровненные в памяти по границе 010 ) - тогда простое стирание соответствующего количества младших битов ( 07 ) у любого указателя на содержимое буфера даёт указатель на заголовок буфера.
Такой подход позволяет обслуживать связанные списки без хранения отдельных указателей на элементы списка. В тех случаях, когда нужен указатель на заголовок текущего элемента списка - достаточно любого указателя на его содержимое.
Жесть, ну вот как гуру обычно изьясняются публично не заботясь особенно о том что обычные люди, типа меня, читают форум и ничего понять не могут из этого? Неужели так сложно по человечески обьяснить? Ну как может быть связный список без связей?Цитата:
Сообщение от Patron
Если я правильно понял то суть вопроса в том, что обычно для вычисления адресса элемента массива нужно умножить длинну элемента массива на индекс элемента и прибавить к адресу начала массива. Эта задача может быть ускоренна если сами массивы распологать начиная с адрессов кратным степеням 2 и использовать длинну элемента массива тоже кратную степеням 2-ки, так как в этом случае операция умножения превращается "в сдвиг в лево". Кроме того из любого указателя на адрес внутри любого элемента можно будет легко вычислить адрес начала елемента наложив на него маску (соответствующую длинне 1 элемента массива) операцией AND.
bigral, а мне вот интересно 010 и 07 - в сообщении Patrona, это восьмиричные
числа?
Список со связями, но нигде в программе нет ни одного отдельного указателя ни на один из заголовков элементов списка ( только указатели на хранимое в списке содержимое ). Когда надо добавить или исключить элемент списка - у любого из указателей на содержимое нужного элемента обнуляются младшие биты и он превращается в указатель на заголовок этого элемента списка.Цитата:
Сообщение от bigral
Чтиво очень интересное, но с виду тут нехватает модулей LNKEM и LNKLB1 для полноты картины. Можете посмотреть, есть ли они там поблизости? возможно это не исходники а просто объектные модули.Цитата:
Сообщение от form
В архиве.Цитата:
Сообщение от nzeemin