Практическое программирование в среде RT-11 на ассемблере.

[Korchagin]

Не, текст не форматируется по нормальному. И в эмуле ДВК не пашет, кстати. Ошибку записи выдает.

- - - Добавлено - - -

А вопрос для меня тоже интересный - ПЗУху РФ3 с адресом 140000 вычитать треба, вставив ее в панельку МC1201.02, и в файл закинуть содержимое.

[Advertiser]

[Alex_K]

А вопрос для меня тоже интересный - ПЗУху РФ3 с адресом 140000 вычитать треба, вставив ее в панельку МC1201.02, и в файл закинуть содержимое.

        .TITLE  RDROM
        .IDENT  /V01.00/
        .MCALL  .ENTER,.WRITW,.CLOSE,.PURGE,.PRINT,.EXIT
START:  .ENTER  #AREA,#0,#FILNAM,#16.,#0
        BCC     1$
        .PRINT  #ERRENT
        BR      3$
1$:     .WRITW  #AREA,#0,#140000,#10000,#0,#0
        BCC     2$
        .PURGE  #0
        .PRINT  #ERRWRI
        BR      3$
2$:     .CLOSE  #0
3$:     .EXIT


AREA:   .BLKW   5
FILNAM: .RAD50  /DK 140000ROM/
ERRENT: .ASCIZ  /?RDROM-F-.ENTER error/
ERRWRI: .ASCIZ  /?RDROM-F-.WRITW error/
        .END    START

[form]

.WRITW #AREA,#0,#140000,#10000,#0,#0

Только стоит отметить, что это будет работать только в SJ мониторе и ни в каком другом...

[Alex_K]

Только стоит отметить, что это будет работать только в SJ мониторе и ни в каком другом...

Неужто и в FB-мониторе не будет работать?

[form]

Неужто и в FB-мониторе не будет работать?

Даже в SB не будет (впрочем это по сути и есть однозадачный FB). Там выполняется проверка адреса буфера - он не может быть выше программной области.

[Alex_K]

Даже в SB не будет (впрочем это по сути и есть однозадачный FB). Там выполняется проверка адреса буфера - он не может быть выше программной области.

Ну можно немного модернизировать:

        .TITLE  RDROM
        .IDENT  /V01.00/
        .MCALL  .SETTO,.ENTER,.WRITW,.CLOSE,.PURGE,.PRINT,.EXIT
START:  .SETTO  #BUFFER+20000
        CMP     R0,#BUFFER+20000
        BHIS    1$
        .PRINT   #NOMEM
        .EXIT
1$:     MOV     #BUFFER,R0
        MOV     #140000,R1
        MOV     #10000,R2
2$:     MOV     (R1)+,(R0)+
        SOB     R2,2$
       .ENTER  #AREA,#0,#FILNAM,#16.,#0
        BCC     3$
        .PRINT  #ERRENT
        BR      5$
3$:     .WRITW  #AREA,#0,#BUFFER,#10000,#0,#0
        BCC     4$
        .PURGE  #0
        .PRINT  #ERRWRI
        BR      5$
4$:     .CLOSE  #0
5$:     .EXIT

AREA:   .BLKW   5
FILNAM: .RAD50  /DK 140000ROM/
NOMEM:  .ASCIZ  /?RDROM-F-Insufficient memory/
ERRENT: .ASCIZ  /?RDROM-F-.ENTER error/
ERRWRI: .ASCIZ  /?RDROM-F-.WRITW error/
        .EVEN
BUFFER:
         .END    START

[form]

Ну можно немного модернизировать

Тллко аргумент остался #140000