Самодельный компьютер на Z80 и не только

**Ewgeny7** · 09.04.2016, 22:36

И GSM до кучи к Т9?

Программы можно писать как на самом компике, так и на ПЦ. И скидывать оттуда по USART. Поэтому с комфортным написаннием программ проблем нету.
Вот двустрочный дисплей по 16 символов в Бейсике - это жесть! Но ничего, работать можно, если сильно хочется

**Advertiser** · 09.04.2016, 22:36

HardWareMan · 10.04.2016, 08:49

Как это жесть? Калькуляторы были же. Хотя я не помню, сколько там было строк и символов в строке. Зато получается довольно таки мощный калькулятор + программируемый контроллер, который не требует обязательного использования ПК.

PS: МЭЛТ MT-20S4A, 4 строки по 20 знакомест. Хватит всем. (с)

**KeKc** · 10.04.2016, 09:13

Про подключение жк к z80 http://www.melt.com.ru/index.php?opt...ost&replyto=73

HardWareMan · 10.04.2016, 11:08

Я на своей ферме (фотки которой на предыдущих страницах) сделал так:

Код:

// LCD дисплей
output  LCD_E,                                                 // Строб данных LCD
output  LCD_RW,                                                // Выбор направления данных LCD
output  LCD_RS,                                                // Выбор регистра управления и данных LCD

***

assign  LCD_RW = !nRD;                                         // Направление данных LCD
assign  LCD_RS = A[0];                                         // Выбор регистра управления или данных LCD
assign  LCD_E = !(nRD & nWR) & !nIORQ & !A[7] & !A[6] & !A[5]; // Строб записи в LCD

И все отлично работает на командах IN/OUT. На скорости 4МГц.

- - - Добавлено - - -

А вот примеры:

Код:

; LCD экран (00-1F)
LCD_CMD      .equ 00H         ; Порт команд LCD
LCD_DT       .equ 01H         ; Порт данных LCD



; Инит экранчика (проходной инклуд)
Boot_LCD_Wt0:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt0 ; Не готов - крутимся
             mvi a,3Ch        ; Настройка LCD
             out (LCD_CMD)    ;
Boot_LCD_Wt1:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt1 ; Не готов - крутимся
             mvi a,0Ch        ; Настройка LCD
             out (LCD_CMD)    ;
Boot_LCD_Wt2:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt2 ; Не готов - крутимся
             mvi a,01h        ; Настройка LCD
             out (LCD_CMD)    ;
Boot_LCD_Wt3:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt3 ; Не готов - крутимся
             mvi a,06h        ; Настройка LCD
             out (LCD_CMD)    ;
; Печать приветствия
Boot_LCD_Wt4:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt4 ; Не готов - крутимся
             mvi a,80h        ; Адрес первой строки
             out (LCD_CMD)    ;
             lxi h,Title_Text ; Адрес приветствия
             mvi b,10h        ; 16 символов
Boot_LCD_Lp0:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Lp0 ; Не готов - крутимся
             mov a,m          ; Берем символ
             out (LCD_DT)     ; Толкаем на экран
             inx h            ; Следующтий символ
             dcr b            ; Минус счетчика
             jnz Boot_LCD_Lp0 ; Крутимся
Boot_LCD_Wt5:in  (LCD_CMD)    ; Считываем статус LCD
             ani 80h          ; Выделяем бит готовности
             jnz Boot_LCD_Wt5 ; Не готов - крутимся

Ну и атомарный вывод символа:

Код:

; Вывод символа из [A]
Print_LCD_Sym:push psw           ; Сохраним [A]
Print_LCD_Wt: in   (LCD_CMD)     ; Считываем статус LCD
              ani  80h           ; Выделяем бит готовности
              jnz  Print_LCD_Wt  ; Не готов - крутимся
              pop  psw           ; Восстановим [A]
              cpi  80h           ; Это команда?
              jc   Print_LCD_Sp  ; Нет - идем на вывод буквы
              out  (LCD_CMD)     ; Посылаем команду в LCD
              ret                ; Выходим
Print_LCD_Sp: cpi  20h           ; Это управляющие символы?
              jc   Print_LCD_Ctr ; Да - идем на управление
              out  (LCD_DT)      ; Посылаем символ в LCD
              ret                ; Выходим
Print_LCD_Ctr:cpi  08h           ; Влево?
              jz   Print_LCD_Lf  ; Да - исполняем
              cpi  18h           ; Вправо?
              jz   Print_LCD_Rg  ; Да - исполняем
              cpi  19h           ; Вверх?
              jz   Print_LCD_Up  ; Да - исполняем
              cpi  1Ah           ; Вниз?
              jz   Print_LCD_Dn  ; Да - исполняем
              cpi  0Dh           ; В начало строки?
              jz   Print_LCD_Cr  ; Да - исполняем
              cpi  0Ah           ; Следующая строка?
              jz   Print_LCD_Dn  ; Да - исполняем
              cpi  1Fh           ; Стирание экрана?
              jz   Print_LCD_Cl  ; Да - исполняем
              ret                ; Выходим
Print_LCD_Lf: in   (LCD_CMD)     ; Считываем позицию
              dcr  a             ; Уменьшаем ее
              ori  80h           ; Добавляем команду
              jmp  Print_LCD_Ex  ; Выходим
Print_LCD_Rg: in   (LCD_CMD)     ; Считываем позицию
              inr  a             ; Увеличиваем ее
              ori  80h           ; Добавляем команду
              jmp  Print_LCD_Ex  ; Выходим
Print_LCD_Up: in   (LCD_CMD)     ; Считываем позицию
              sui  40h           ; Вычитаем размер строки
              ori  80h           ; Добавляем команду
              jmp  Print_LCD_Ex  ; Выходим
Print_LCD_Dn: in   (LCD_CMD)     ; Считываем позицию
              adi  40h           ; Прибавляем размер строки
              ori  80h           ; Добавляем команду
              jmp  Print_LCD_Ex  ; Выходим
Print_LCD_Cr: in   (LCD_CMD)     ; Считываем позицию
              ani  0C0h          ; Сбрасываем на начало строки
              ori  80h           ; Добавляем команду
              jmp  Print_LCD_Ex  ; Выходим
Print_LCD_Cl: mvi  a,01h         ; Команда очистки экрана
Print_LCD_Ex: out  (LCD_CMD)     ; Пошлем команду в LCD
              ret                ; Выход

**Ewgeny7** · 10.04.2016, 11:23

Сообщение от HardWareMan

Как это жесть? Калькуляторы были же.

Электроника МК85. У нее вообще одна строка для бейсика.
И это жесть не менее, чем две строки

Не надо думать, что это удобно.
Из четырехстрочников у меня есть графический 128*64 G1213N00, но он без подсветки.
И жду из китаев некий LCD12864, он похож на дисплей из первого поста темы от Кекса.

**ALS** · 10.04.2016, 14:13

Еще есть интересный дисплей тех годов - LM234 (HLM-9301).
Построен, как графический, правда, каждый 6-й столбец у него не работает.
Но для текстового режима - вполне.

Скрытый текст

[свернуть]

**rw6hrm** · 10.04.2016, 22:33

http://www.nostalcomp.cz/savia.php вот вам ещё одноплатка класса ЮТа, но на Z80. Опять же, со свободным знакогенератором на семисегментниках...

А это как пример корпуса

нет, не Савии, а "карманного компьютера на Z80"

**Ewgeny7** · 14.04.2016, 13:25

Поросла паутиной тема.
Чуть протру тряпочкой - запилил I2C на порту С 580ВВ55А.
Микросхема EEPROM 24LC16 пишется/читается.
Но - мелковата она. Поищу пожирнее, дабы было с чего загружаться после включения.
Простыню *****кода оставлю здесь, дабы было хоть каким-то примером.

Скрытый текст

Код:

;PortC - #E2
;SCL - PortC.6 out
;SDAI - PortC.7 out
;SDAO - PORTC.0 in
;resistor 1.0k between SDAO & SDAI

I2C_INIT:           LD A,#93
			OUT (#E3),A
                        RET

I2C_START:	LD A,#C0
			OUT (#E2),A
			NOP
			LD A,#40
			OUT (#E2),A
			NOP
			XOR A
			OUT (#E2),A
			RET	
			
I2C_STOP:	        LD A,#40
			OUT (#E2),A
			NOP
			LD A,#C0
			OUT (#E2),A
			NOP
			RET					
						
I2C_ADDR:	        PUSH AF
			CALL I2C_START
			POP AF
			CALL I2C_SEND8
			CP 1
			RET Z
			SCF
			RET
			
I2C_SEND8:	        PUSH BC
			LD B,8
SND1:		RLC A
			LD C,A
			JR C,SND2
			LD A,0
			OUT (#E2),A
			LD A,#40
			OUT (#E2),A
			LD A,0
			OUT (#E2),A
			JR SND3
SND2:		LD A,#80
			OUT (#E2),A
			LD A,#C0
			OUT (#E2),A
			LD A,#80
			OUT (#E2),A
SND3:		LD A,C
			DJNZ SND1
			LD A,#C0
			OUT (#E2),A
			IN A,(#E2) 
			LD C,A
			LD A,#80
			OUT (#E2),A
			XOR A
			OUT (#E2),A
			LD A,C
			AND 1
			POP BC
			RET						
			
I2C_READ8:	        PUSH BC
			LD B,8
			LD A,#80
			OUT (#E2),A
			XOR A
RED1:		        RLA
			LD C,A
			LD A,#C0
			OUT (#E2),A
			IN A,(#E2)
			PUSH AF
			LD A,#80
			OUT (#E2),A
			POP AF
			AND 1
			OR C
			DJNZ RED1
			POP BC
			RET				

I2C_ACK:	        XOR A
			OUT (#E2),A		
			LD A,#40 
			OUT (#E2),A
			XOR A
			OUT (#E2),A	
			RET
			
I2C_NACK:	        LD A,#80
			OUT (#E2),A			
			LD A,#C0 
			OUT (#E2),A
			XOR A
			OUT (#E2),A	
			RET

[свернуть]

**Totem** · 15.04.2016, 18:19

Сообщение от Ewgeny7

Поросла паутиной тема.
Чуть протру тряпочкой - запилил I2C на порту С 580ВВ55А.
Микросхема EEPROM 24LC16 пишется/читается.
Но - мелковата она. Поищу пожирнее, дабы было с чего загружаться после включения.
Простыню *****кода оставлю здесь, дабы было хоть каким-то примером.

Скрытый текст

Код:

;PortC - #E2
;SCL - PortC.6 out
;SDAI - PortC.7 out
;SDAO - PORTC.0 in
;resistor 1.0k between SDAO & SDAI

I2C_INIT:           LD A,#93
			OUT (#E3),A
                        RET

I2C_START:	LD A,#C0
			OUT (#E2),A
			NOP
			LD A,#40
			OUT (#E2),A
			NOP
			XOR A
			OUT (#E2),A
			RET	
			
I2C_STOP:	        LD A,#40
			OUT (#E2),A
			NOP
			LD A,#C0
			OUT (#E2),A
			NOP
			RET					
						
I2C_ADDR:	        PUSH AF
			CALL I2C_START
			POP AF
			CALL I2C_SEND8
			CP 1
			RET Z
			SCF
			RET
			
I2C_SEND8:	        PUSH BC
			LD B,8
SND1:		RLC A
			LD C,A
			JR C,SND2
			LD A,0
			OUT (#E2),A
			LD A,#40
			OUT (#E2),A
			LD A,0
			OUT (#E2),A
			JR SND3
SND2:		LD A,#80
			OUT (#E2),A
			LD A,#C0
			OUT (#E2),A
			LD A,#80
			OUT (#E2),A
SND3:		LD A,C
			DJNZ SND1
			LD A,#C0
			OUT (#E2),A
			IN A,(#E2) 
			LD C,A
			LD A,#80
			OUT (#E2),A
			XOR A
			OUT (#E2),A
			LD A,C
			AND 1
			POP BC
			RET						
			
I2C_READ8:	        PUSH BC
			LD B,8
			LD A,#80
			OUT (#E2),A
			XOR A
RED1:		        RLA
			LD C,A
			LD A,#C0
			OUT (#E2),A
			IN A,(#E2)
			PUSH AF
			LD A,#80
			OUT (#E2),A
			POP AF
			AND 1
			OR C
			DJNZ RED1
			POP BC
			RET				

I2C_ACK:	        XOR A
			OUT (#E2),A		
			LD A,#40 
			OUT (#E2),A
			XOR A
			OUT (#E2),A	
			RET
			
I2C_NACK:	        LD A,#80
			OUT (#E2),A			
			LD A,#C0 
			OUT (#E2),A
			XOR A
			OUT (#E2),A	
			RET

[свернуть]

Они говорят, что мы извращенцы.
http://www.fizyka.umk.pl/~daras/mtm/...%20Minimal.mp4

**Ewgeny7** · 15.04.2016, 18:59

Сообщение от Totem

Они говорят, что мы извращенцы.

Корпус - классный.
Но на этом и хватит

А я уже автозагрузку и старт с EEPROM 24С16 прилепил. Теперь Скайнет не боится пропадания напряжения

Осталось часики на DS1307 прилепить, и будет вообще всё.
Сейчас Монитор занимает уже 2 килобайта, 10 директив.

ZXPRESS •	ZXART •
ZXTUNES •	ZX Spectrum Old Demos •
Virtual TR-DOS •	World of Spectrum •

User Tag List

Тема: Самодельный компьютер на Z80 и не только

Опции темы

Отображение

Скрытый текст

Скрытый текст

Скрытый текст

Информация о теме

Пользователи, просматривающие эту тему

Похожие темы

Самодельный станок для намотки ТВЗ

Самодельный телевизор

Самодельный kickstart под ЛУТ :D

Лучший самодельный компьютер

Самодельный принтер

Ваши права