ЭТЮДЫ

[drbars]

Другая задачка: рисуем букву атрибутами (8х8 знакомест)

Никаких PUSH POP !!!

; ATTR symbol print by Dr.Bars (29 bytes)
; HL = ATTR_ADR (#5800)
; A = Letter_code
; E = Color_code (#57)

ATTR_SYM:
	EXX
	ADD A,A
	LD L,A
	LD H,#0F
	ADD HL,HL
	ADD HL,HL
	LD B,#08
L2	LD A,(HL)
	EXX
	LD BC,#0818
L1	RLA
	LD D,A
	SBC A,A
	AND E
	LD (HL),A
	LD A,D
	INC L
	DJNZ L1
	ADD HL,BC
	EXX
	INC L
	DJNZ L2
	RET

Вариант 2 (изменяемый цвет фона):

Юзается push/pop

PRINT:
	LD HL,#5800
	LD A,#7F
	LD D,#57-#07
	LD E,#07

; ATTR symbol print by Dr.Bars (30 bytes)
; HL = ATTR_ADR (#5800)
; A = Letter_code
; D = Color_code - Background_code
; E = Background_code

ATTR_SYM:
	ADD A,A
	EXX
	LD L,A
	LD H,#0F
	ADD HL,HL
	ADD HL,HL
	LD B,#08
L2	LD A,(HL)
	EXX
	LD BC,#0818
L1	RLA
	PUSH AF
	SBC A,A
	AND D
	ADD A,E
	LD (HL),A
	POP AF
	INC L
	DJNZ L1
	ADD HL,BC
	EXX
	INC L
	DJNZ L2
	RET

---------- Post added at 00:25 ---------- Previous post was at 00:16 ----------

P.S моя процедурка вывода спрайта никому не интересна?

Она ведь чуть медленее табличного варианта по скорости.

[Advertiser]

[introspec]

P.S моя процедурка вывода спрайта никому не интересна?

Она ведь чуть медленее табличного варианта по скорости.

Интересна, просто она непростая, а времени нет. Скачал сразу после выхода, обязательно прочту, когда чуть разгружусь.

[drbars]

Интересна, просто она непростая, а времени нет. Скачал сразу после выхода, обязательно прочту, когда чуть разгружусь.

Писал для диззика, но в итоге реализовал табличный способ... более универсальный и компактный в быстрой памяти.