Еще один Орион на ПЛИС

[andreil]

Ради пробы собрал в Протеусе схему для симуляции и обкатки GAL'ок.
Результаты неутешительные для схемы на рассыпухе - при использовании счётчиков 74S163 (как самых быстрых в библиотеке) и GAL с задержкой 15ns (что равносильно 2-м логическим элементам серии 74ACT) по таймингам идём уже впритык (внимание на восходящий фронт сигнала сброса, он идёт по линии А1, А0 - тактирование 25МГц):

Так что логику для счётчиков по X имеет смысл полностью впихнуть в GAL'ку для оптимизации скорости, а так же для упрощения платы - будет 1 корпус вместо штук 5 (даже при GAL в DIP, а логике в SOIC, уже имеем преимущество).

Схема в симуляторе

[свернуть]

[andreil]

А вот и прошивка для первой GAL'ки, обкатанная в Протеусе:

Name     orion_gal_test ;PartNo   00 ;
Date     05.05.2018 ;
Revision 01 ;
Designer andreil ;
Company   ;
Assembly ;
Location  ;
Device   g22v10;


PIN  [1,2,3,4,5,6,7,8,9,10] = [x0..9];
PIN  11  = sr16; 
PIN  13  = wen;


PIN  23  = xresn;
PIN  22  = ben;
PIN  21  = bh3;
PIN  20  = bh5;
PIN  19  = bh;
PIN  18  = xle;
PIN  17  = hs3;
PIN  16  = hs5;
PIN  15  = hs;


xresn    = !(x9 & x8 & x4 & x3 & x2 & x1 & x0);
ben = !(x2 & x1 & x0);
bh3 = !x9 & ((!x8 & x7) # (!x7 & (x6 # x5 # x4 # x3)) # (x8 & !x6 & !x5 & !x4 & !x3));
bh5 = (!x9 & (x8 # x7 # x6 # x5 # x4 # x3)) # (x9 & !x3 & !(x8 # x7 # x6 # x5 # x4));
bh = (!sr16 & bh3) # (sr16 & bh5);
xle = ((!sr16 & !x6) # (sr16 & x6)) & (x9 & !x8 & x7 & x5 & !x4 & !x3 & x2 & x1 & x0);
hs3 = x9 & !x8 & !x7 & ((x6 & !x5) # (x5 & (!x3 # !x4)) # (!x6 & x4 & x3));
hs5 = x9 & !x8 & ((!x7 & x6 & ((x4 & x3) # x5)) # (x7 & !x6 & (!x5 # !x4 # !x3)));
hs = wen $ ((!sr16 & hs3) # (sr16 & hs5));

Формирует все необходимые инмпульсы для видео по горизонтали. Схема - под спойлером выше.
По логике - решил обойтись без триггеров, поскольку с ними надо для каждого свой клок иметь. А так - куча логики, отрабатывающей строго по таймингам (проверял по логическому анализатору).
Буду писать аналогичную для горизонтали.

PS: Для макетки купил 10 GAL'ок, буду собирать программатор

- - - Добавлено - - -

А вот и прошивка для GAL по вертикали:

Name     orion_gal_y ;PartNo   00 ;
Date     05.05.2018 ;
Revision 01 ;
Designer andreil ;
Company   ;
Assembly ;
Location  ;
Device   g22v10;


PIN  [1,2,3,4,5,6,7,8,9,10] = [y0..9];
PIN  11  = wen; 
PIN  13  = bh;


PIN  23  = yresn;
PIN  22  = bl;
PIN  21  = vs;


yresn = !((!wen & y9 & y3 & y2) # (wen & y8 & y7 & y6));
bl = bh & !y8 & !y9;
vs = !((!y9 & y8 & !y7 & y6 & y4) & ((!wen & (y5 & y3 & !y2 & y1)) # (wen & (!y5 & !y3 & y2 & (y1 $ y0)))));

Здесь логики почти нет, но в схемном варианте требуется минимум 5 корпусов (половинка триггера берется из логики горизонтали).
Итого, на весь синхрогенератор получили 8 корпусов - 6 счётчиков и 2 GAL.

[OrionExt]

Вот это давно пора. И смд в лес. Должно на 2-х платках 100х100 (бутер) все поместиться от видео-части. Конечно, речь идет только об Орион -128.

[andreil]

Вот это давно пора. И смд в лес. Должно на 2-х платках 100х100 (бутер) все поместиться от видео-части. Конечно, речь идет только об Орион -128.

Совсем от SMD не уйти - память и кварцы как минимум. Ну и резисторы с конденсаторами проще в таком исполнении.

- - - Добавлено - - -

Единственная проблема - программатор для GAL. Нашел на ардуине проект для прошивки 22V10, попробую адаптировать на STM32. Будет сразу с USB программатор, прикидывающийся COM-портом (или HID устройством, если разберусь).

[OrionExt]

Я достаточно давно не был в теме. Когда стал вопрос, что брать для запрограммировать. Питань не було. MiniPro. Штука не без тучи глюков и с такими возможностями, но за такие денге маст хэв.

[andreil]

Я достаточно давно не был в теме. Когда стал вопрос, что брать для запрограммировать. Питань не було. MiniPro. Штука не без тучи глюков и с такими возможностями, но за такие денге маст хэв.

$53 пока что земноводное не даст заплатить
Да и GAL'ки ещё с месяц будут идти...

А пока суть да дело надо на них попереносить мелкую логику и добить-таки диспетчеризацию памяти...

Кстати, счётчики у меня "под боком" только в SOIC'ах есть в наличии. в DIP'ах только 74AC и в 2 раза дороже
Да они даже на алике стоят по $.5 за корпус...

[Advertiser]

[andreil]

В ходе "упаковки" логики в GAL очень сильно переработал выходной видеокаскад - теперь там одна GAL и пачка регистров. Ну и 1 корпус 4*2AND для формирования смеси цветов. Всю логику переключения видеорежимов и выходные мультиплексоры впихнул в 1 GAL'ку - посмотрим, насколько оно ещё влезет потом, может надо будет оптимизировать ещё потом.
Регистры остались только для защелкивания видеоданных (4 ИР33) и сдвиговые регистры видеоданных (4 ИР10).
Дальше надо будет по таймингам смотреть, какие сигналы и как "вытягивать" - с GAL это попроще будет и более фиксированные рамки получатся.

[L Juriy]

andreil, Немного офтоп. Есть содержимое РЕ3, можно как то , без особых затрат перевести ее в GAL?
Если можно , то примером подробным для профанов.

[TomaTLAB]

MiniPro

Ага, а 22V10, 20V8 оно шьет? Дулю с маком.
Только 16V8 получается. Говорят когда то шило (через задницу, правда), потом там что-то окончательно испортили в процессе улучшений.

[andreil]

andreil, Немного офтоп. Есть содержимое РЕ3, можно как то , без особых затрат перевести ее в GAL?
Если можно , то примером подробным для профанов.

Можно, но для этого надо её дамп снять. Потом по дампу прогнать оптимизатором, что бы минимизировать функцию для каждого выхода..
Дам снимать просто - снимаем состояние выходов при всех возможных комбинациях входов (32 состояния).

- - - Добавлено - - -

Ага, а 22V10, 20V8 оно шьет? Дулю с маком.
Только 16V8 получается. Говорят когда то шило (через задницу, правда), потом там что-то окончательно испортили в процессе улучшений.

Ну, значит будем варганить свой программатор.

А между делом уже "нарисовалась" прошивка для GAL формирователя видеосигнала:

Name     gal_vmux ;PartNo   00 ;
Date     06.05.2018 ;
Revision 01 ;
Designer andreil ;
Company  None ;
Assembly None ;
Location  ;
Device   g22v10;


PIN  [1..5] = [vm0..4];
PIN  6  = BL_n;
PIN  7  = p1;
PIN  8  = p2;
PIN  9  = p3;
PIN  10 = p4;
PIN  [11,13..19]  = [ps0..7];
PIN  20 = R;
PIN  21 = G;
PIN  22 = B;
PIN  23 = I;


I = BL_n & (((!vm4 & vm1) & ((p1 & ps3) # (!p1 & ps7)))/* pseudocolors mode */
	# (vm4 & p2));	
R = BL_n & (((!vm4 & !vm1) & ((p2 & p1) # (!p2 & (p1 & vm0))))/* standart mode */
	# ((!vm4 & vm1) & ((p1 & ps2) # (!p1 & ps6)))	/* pseudocolors mode */
	# (vm4 & p3));	
G = BL_n & (((!vm4 & !vm1) & (!p2 & (p1 & !vm0)))		/* standart mode */
	# ((!vm4 & vm1) & ((p1 & ps1) # (!p1 & ps5)))	/* pseudocolors mode */
	# (vm4 & p1));
B = BL_n & (((!vm4 & !vm1) & ((p2 & !p1) # (!p2 & (p1 & vm0))))/* standart mode */
	# ((!vm4 & vm1) & ((p1 & ps0) # (!p1 & ps4)))	/* pseudocolors mode */
	# (vm4 & p4));

По сигналам:

• vm0..4 - видеорежим, напрямую с регистра;
• BL_n - инверсный сигнал гашения экрана;
• p1, p2, p3, p4 - сигналы с выхода сдвиговых регистров;
• ps0..7 - сигналы с регистров псевдоцветных режимов;
• R, G, B, I - собственно выходные данные, далее преобразуются в аналоговые RGB.

Логику работы реализовал по схеме видеовыхода от Орион-Power v3.10.

- - - Добавлено - - -

Данную прошивку для стандартного режима (монохром, зелёный) проверил на ПЛИС. Остальное позже будет проверяться.

- - - Добавлено - - -

А сейчас буду рисовать черновик схемы "обновлённого" Ориона...