Программирование

**ivagor** · 08.07.2022, 13:11

Есть у меня старый потоковый распаковщик для zx7, у которого настраивается размер буфера (от 256 байт и больше). Но у него 2 недостатка - он очень медленный и это zx7, который резко потерял актуальность после появления zx0/zx1/zx2/zx5. Поэтому я его не выкладывал и теперь оптимизировать и выкладывать смысла нет. На базе zx0 можно сделать подобную штуку (при условии упаковки salvadorом), надо будет заняться, если кто-нибудь не сделает раньше.
zx7mini хорошая для своего времени штука, но там есть недостатки. Если устраивает небольшая степень сжатия, зато будет маленький буфер и сравнительно простой распаковщик (т.е. все чем был интересен zx7mini), то рекомендую взять здесь saukav.exe, это обобщенный zx7, который опциями можно превратить в подобие zx7mini, только лучше.

**Advertiser** · 08.07.2022, 13:11

**parallelno** · 08.07.2022, 13:24

Время подождать есть. А zx7mini умеет писать в буфер экрана на нужные для картинки адреса?

**svofski** · 08.07.2022, 13:38

Сообщение от parallelno

Время подождать есть. А zx7mini умеет писать в буфер экрана на нужные для картинки адреса?

Думаю, что если картинка не расположена в памяти без разрывов, то есть например занимает только часть экрана, потребуются модификации. Но там распаковщик очень простой. Кстати, я его переводил на Си однажды. С другой стороны, если это заставка и можно потерпеть, что неиспользуемая часть экрана затирается нулями, может быть лучше так прямо и упаковать монолитом -- упакованные нули не займут очень много места, а проще -- это всегда проще.

**parallelno** · 08.07.2022, 22:25

О, отлично! Когда напишу свой rle с разрывами сравню скорость распаковки и сжатие и напишу сравнение.

**parallelno** · 25.07.2022, 00:54

Почему когда я опрашиваю клавиши после установки цвета бордюра и вертикального скролинга кодом ниже, цвет бордюра не устанавливается корректно?

Код:

	LXI H,palette_sprites+15	; ЗАПИСЬ ПАЛИТРЫ.
	LXI D,$100F
INIT1:	MOV A,E
	OUT 02
	MOV A,M
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	DCX H
	OUT $0c
	DCR E
	OUT $0c
	DCR D
	OUT $0c
	JNZ INIT1
NWRPAL:	
	MVI A,$88
	OUT 00
	mvi a, 1	; УСТАНОВКА ЦВЕТА БОРДЮРА.
	ANI $0F
	OUT 02
	mvi a, 255	; УСТАНОВКА ВЕРТИКАЛЬНОГО ПОЛОЖЕНИЯ ЭКРАНА.
	OUT 03	

	MVI A,$8A	; ПРОВЕРКА НАЖАТИЯ НА ЛЮБУЮ КЛАВИШУ 
	OUT 00		; МАТРИЦЫ КЛАВИАТУРЫ 8*8 (КРОМЕ УС,СС,РУС/ЛАТ).
	XRA A
	OUT 03
	IN 2
	STA anyKeyPressed
	MVI A,$FE	; ПРОВЕРКА НАЖАТИЯ НА КЛАВИШИ ИГРОВОГО РЯДА.
	OUT 03
	IN 02
	STA keyCode

но когда я опращиваю клавиши до бордюра и скроллинга, то все равботает как нужно?

Код:

	LXI H,palette_sprites+15	; ЗАПИСЬ ПАЛИТРЫ.
	LXI D,$100F
INIT1:	MOV A,E
	OUT 02
	MOV A,M
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	DCX H
	OUT $0c
	DCR E
	OUT $0c
	DCR D
	OUT $0c
	JNZ INIT1
NWRPAL:	
	MVI A,$8A	; ПРОВЕРКА НАЖАТИЯ НА ЛЮБУЮ КЛАВИШУ 
	OUT 00		; МАТРИЦЫ КЛАВИАТУРЫ 8*8 (КРОМЕ УС,СС,РУС/ЛАТ).
	XRA A
	OUT 03
	IN 2
	STA anyKeyPressed
	MVI A,$FE	; ПРОВЕРКА НАЖАТИЯ НА КЛАВИШИ ИГРОВОГО РЯДА.
	OUT 03
	IN 02
	STA keyCode
	
	MVI A,$88
	OUT 00
	mvi a, 1	; УСТАНОВКА ЦВЕТА БОРДЮРА.
	ANI $0F
	OUT 02
	mvi a, 255	; УСТАНОВКА ВЕРТИКАЛЬНОГО ПОЛОЖЕНИЯ ЭКРАНА.
	OUT 03

проверял в Emu80 и VV

- - - Добавлено - - -

Вот тестовая программа для Pretty Asm

Код:

    .project helv06c.rom
    .tape v06c-rom

			.org	$100
StartInit:
	DI
	; dismount a quasi-disk
	XRA		A
	out		$10
	; set entry points of a restart, and an interruption
	MVI		A, 0C3h
	STA		0
	STA		38h
	LXI		H, StartInit
	SHLD 	        1
	LXI		H, Interruption1
	SHLD	        38h + 1
	; stack init
	LXI		SP, 8000h
	EI
	HLT
	; clear the screen
	CALL	CLEAR
Start:  JMP     Start


CLEAR:	DI
	PUSH H		; СОХРАНИТЬ ИСПОЛЬЗУЕМЫЕ РЕГИСТРЫ.
	PUSH B
	PUSH D
	PUSH PSW
	LXI H,0000H	; ПОДГОТОВИТЬ HL ДЛЯ ВЗЯТИЯ ЗНАЧЕНИЯ SP.
	DAD SP		; ВЗЯТЬ ЗНАЧЕНИЕ SP ПУТЕМ СЛОЖЕНИЯ С HL.
	LXI SP,0000H	; НАЧАТЬ СТИРАНИЕ С АДРЕСА 0FFFFH.
	LXI D,0000H	; В DE - ЗНАЧЕНИЕ, КОТОРЫМ БУДЕТ СТЕРТ ЭКРАН.
	LXI B,0800H	; В BC - СЧЕТЧИК.
CLEAR1:	PUSH D		; НАЧАТЬ СТИРАТЬ ЭКРАН ПУТЕМ "ОПУСКАНИЯ" СТЕКА.
	PUSH D		; ВЫПОЛНИТЬ 8 ОПЕРАЦИЙ "В ЛОБ" ДЛЯ СКОРОСТИ.
	PUSH D
	PUSH D
	PUSH D
	PUSH D
	PUSH D
	PUSH D
	DCX B		; УМЕНЬШИТЬ СЧЕТЧИК И 
	MOV A,B		; ПРОВЕРИТЬ ЕГО.
	ORA C		; КОНЕЦ СЧЕТА?
	JNZ CLEAR1	; ЕСЛИ НЕТ - ПРОДОЛЖАТЬ СТИРАНИЕ.
	SPHL		; ВЕРНУТЬ ПРЕЖНЕЕ ЗНАЧЕНИЕ SP И
	POP PSW		; ВСЕХ РЕГИСТРОВ.
	POP D
	POP B
	POP H
	EI
	RET
	
anyKeyPressed:          .db 0
keyCode:          .db 0

palette_sprites:
			.DB 01001010b, 00000001b, 01011100b, 00011010b, 
			.DB 11100100b, 11111101b, 01110111b, 01011111b, 
			.DB 01000010b, 01001011b, 01001100b, 11111111b, 
			.DB 11111111b, 11101011b, 00001010b, 01011011b, 
;----------------------------------------------------------------
; Common interruption sub

Interruption1:
	PUSH	PSW
	PUSH	B
	PUSH	D
	PUSH	H

			; common interruption logic
	LXI H,palette_sprites+15	; ЗАПИСЬ ПАЛИТРЫ.
	LXI D,$100F
INIT1:	MOV A,E
	OUT 02
	MOV A,M
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	OUT $0c
	DCX H
	OUT $0c
	DCR E
	OUT $0c
	DCR D
	OUT $0c
	JNZ INIT1


	MVI A,$88
	OUT 00
	mvi a, 1	; УСТАНОВКА ЦВЕТА БОРДЮРА.
	ANI $0F
	OUT 02
	mvi a, 255	; УСТАНОВКА ВЕРТИКАЛЬНОГО ПОЛОЖЕНИЯ ЭКРАНА.
	OUT 03		

	MVI A,$8A	; ПРОВЕРКА НАЖАТИЯ НА ЛЮБУЮ КЛАВИШУ 
	OUT 00		; МАТРИЦЫ КЛАВИАТУРЫ 8*8 (КРОМЕ УС,СС,РУС/ЛАТ).
	XRA A
	OUT 03
	IN 2
	STA anyKeyPressed
	MVI A,$FE	; ПРОВЕРКА НАЖАТИЯ НА КЛАВИШИ ИГРОВОГО РЯДА.
	OUT 03
	IN 02
	STA keyCode

			; end common interruption logic
	POP		H
	POP		D
	POP		B
	POP		PSW
	EI
	RET	
    end

**svofski** · 25.07.2022, 01:35

Из даташита 8255:
"All of the output registers, including the status flip-flops, will be reset whenever the mode is changed"

Код цвета бордюра -- это не отдельный регистр, а прямо выход 8255. Поэтому бордюр надо записывать после опроса клавиатуры.

**parallelno** · 25.07.2022, 02:10

Прикольно. Спасибо. А есть подробная информация по работе с портами?

**svofski** · 25.07.2022, 03:26

Я обычно заглядываю в Техническое описание и в даташиты. Но чаще всего можно списать домашку откуда-нибудь.

**parallelno** · 25.07.2022, 04:37

О, спасибо большое. Добавлю в первый пост

- - - Добавлено - - -

Списать то можно, но иногда получается как у меня. Несколько часов поиска несуществующего бага

)

- - - Добавлено - - -

Нашел вот такую инфу в технической документации:
https://github.com/svofski/vector06c...al_Description

Программа, работающая по прерыванию, производит программирование ВВ55
на режим, позволяющий опросить клавиатуру. Поэтому перед возвратом из
подпрограммы необходимо обратно восстановить дисплейный режим и значения
портов, определяющих номер верхней строки, цвет рамки, режим 256*256 или
512*256 и т.п. Также необходимо разрешить прерывание,

но в секретах не востанавливается дисплейный режим.

Код:

...
        LDA  IndRus      ;взять признак включения индикатора "РУС/LAT"
        MOV  B,A         ;временно поместить в регистр "B"
        LDA  Rele        ;взять признак включения реле из ячейки "Rele" и
        ORA  B           ;об'единить с признаком включения индикатора "РУС/LAT"
        OUT  01          ;вывести сигналы управления индикатором и реле в порт 01
        POP  PSW         ;вернуть все регистры из стека
...

Насколько это критично? и нужно ли всегда программировать порт 01 как в примере выше?

**ivagor** · 25.07.2022, 06:35

Сообщение от parallelno

но в секретах не востанавливается дисплейный режим.

Код:

        MVI  A,88h       ;установить режимы портов 02-вывод, 03-вывод
        OUT  00          ;мл. 4 бита порта 01 - вывод, старшие 4 бита - ввод
        LDA  Border      ;взять цвет бордюра ячейки "Border" (матем. код) и
        OUT  02          ;установить цвет бордюра на 4-х младших битах порта 02
        LDA  Scroll      ;взять из ячейки "Scroll"вертикальное положение экрана
        OUT  03          ;и установить в порт 03
        LDA  IndRus      ;взять признак включения индикатора "РУС/LAT"
        MOV  B,A         ;временно поместить в регистр "B"
        LDA  Rele        ;взять признак включения реле из ячейки "Rele" и
        ORA  B           ;об'единить с признаком включения индикатора "РУС/LAT"
        OUT  01          ;вывести сигналы управления индикатором и реле в порт 01
        POP  PSW         ;вернуть все регистры из стека

ZXPRESS •	ZXART •
ZXTUNES •	ZX Spectrum Old Demos •
Virtual TR-DOS •	World of Spectrum •

User Tag List

Тема: Программирование

Опции темы

Отображение

Этот пользователь поблагодарил svofski за это полезное сообщение:

Этот пользователь поблагодарил svofski за это полезное сообщение:

Этот пользователь поблагодарил svofski за это полезное сообщение:

Информация о теме

Пользователи, просматривающие эту тему

Похожие темы

Программирование на ассемблере

Программирование на ассемблере

Программирование графики MSX

Программирование NES

Программирование на пентеве.

Ваши права